I_OPACTYINSTANCECOMPONENT

@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XL, dataClass: #MIXED}
@VDM.viewType: #BASIC
@EndUserText.label: 'Component of an Operation Activity Instance'
define view entity I_OpActyInstanceComponent
  as select from           I_OpActyComponentAssignment as OpActyComponentAssignment
    inner join             resb                        as resb  on  resb.rsnum = OpActyComponentAssignment.Reservation
                                                                and resb.rspos = OpActyComponentAssignment.ReservationItem
                                                                and resb.rsart = OpActyComponentAssignment.RecordType
    left outer to one join tcs03                       as tcs03 on tcs03.agb29 = '29'

  association [1..1] to I_ReservationDocumentHeader   as _Reservation                 on  $projection.Reservation = _Reservation.Reservation
  association [1..1] to I_ReservationDocumentItem     as _ReservationItem             on  $projection.Reservation     = _ReservationItem.Reservation
                                                                                      and $projection.ReservationItem = _ReservationItem.ReservationItem
                                                                                      and $projection.RecordType      = _ReservationItem.RecordType
  association [0..1] to I_ReservationDocRecordType    as _ReservationDocRecordType    on  $projection.RecordType = _ReservationDocRecordType.RecordType
  association [1..1] to I_ManufacturingOrder          as _ManufacturingOrder          on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
  association [1..1] to I_MfgOrderOperationBasic      as _MfgOrderOperation           on  $projection.OrderInternalBillOfOperations = _MfgOrderOperation.OrderInternalBillOfOperations
                                                                                      and $projection.OrderIntBillOfOperationsItem  = _MfgOrderOperation.OrderIntBillOfOperationsItem
  association [1..1] to I_OrderInternalID             as _OrderInternalID             on  $projection.OrderInternalBillOfOperations = _OrderInternalID.OrderInternalID
  association [1..1] to I_Material                    as _Material                    on  $projection.Material = _Material.Material
  association [1..1] to I_Product                     as _Product                     on  $projection.Material = _Product.Product
  association [1..1] to I_Plant                       as _Plant                       on  $projection.Plant = _Plant.Plant
  association [1..1] to I_ProductPlantBasic           as _ProductPlantBasic           on  $projection.Material = _ProductPlantBasic.Product
                                                                                      and $projection.Plant    = _ProductPlantBasic.Plant
  association [0..1] to I_StorageLocation             as _StorageLocation             on  $projection.Plant           = _StorageLocation.Plant
                                                                                      and $projection.StorageLocation = _StorageLocation.StorageLocation
  association [0..1] to I_Batch                       as _Batch                       on  $projection.Plant    = _Batch.Plant
                                                                                      and $projection.Material = _Batch.Material
                                                                                      and $projection.Batch    = _Batch.Batch
  association [0..1] to I_BillOfMaterialItemCategory  as _BOMItemCategory             on  $projection.BOMItemCategory = _BOMItemCategory.BillOfMaterialItemCategory
  association [1..1] to I_UnitOfMeasure               as _BaseUnit                    on  $projection.BaseUnit = _BaseUnit.UnitOfMeasure
  association [1..1] to I_UnitOfMeasure               as _EntryUnit                   on  $projection.EntryUnit = _EntryUnit.UnitOfMeasure
  association [1..1] to I_DebitCreditCode             as _DebitCreditCode             on  $projection.DebitCreditCode = _DebitCreditCode.DebitCreditCode
  association [0..1] to I_MatlCompDiscontinuationType as _MatlCompDiscontinuationType on  $projection.MatlCompDiscontinuationType = _MatlCompDiscontinuationType.MatlCompDiscontinuationType

{
      @ObjectModel.foreignKey.association: '_OpActyNtwkInstance'
  key OpActyComponentAssignment.OpActyNtwkInstance,
      @ObjectModel.foreignKey.association: '_OperationActivityInstance'
  key OpActyComponentAssignment.OpActyNtwkElement,
      @ObjectModel.foreignKey.association: '_ReservationHeader'
  key OpActyComponentAssignment.Reservation,
  key OpActyComponentAssignment.ReservationItem,
  key OpActyComponentAssignment.RecordType,
      OpActyComponentAssignment.MfgOrderComponentUsageQuantity,
      OpActyComponentAssignment.MfgOrderComponentUsageNetQty,
      OpActyComponentAssignment.AssemblySequenceNumber,
      OpActyComponentAssignment.BOOOpBOMItemInternalID,
      OpActyComponentAssignment.LogicalComponent,
      OpActyComponentAssignment.ComponentAssemblyType,
      OpActyComponentAssignment.RelatedReservation,
      OpActyComponentAssignment.RelatedReservationItem,
      OpActyComponentAssignment.RelatedRecordType,
      OpActyComponentAssignment.RelatedOpActyNtwkInstance,
      OpActyComponentAssignment.RelatedOpActyNtwkElement,
      OpActyComponentAssignment.MatlCompInstceAssyIsRequired,
      OpActyComponentAssignment.PlannedInventoryUsabilityCode,
      OpActyComponentAssignment.LeadingReservation,
      OpActyComponentAssignment.LeadingReservationItem,
      OpActyComponentAssignment.LeadingReservationRecordType,
      OpActyComponentAssignment.LeadingOpActyNtwkInstance,
      OpActyComponentAssignment.LeadingOpActyNtwkElement,
      OpActyComponentAssignment.MfgRefStrucBOMLeafAssgmtUUID,
      OpActyComponentAssignment.MfgRefStructureItemDetailUUID,
      OpActyComponentAssignment.MfgRefStrucItmDetIsContextual,
      resb.aufnr                                              as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_OrderInternalID'
      cast(resb.aufpl as pph_aufpl preserving type)           as OrderInternalBillOfOperations,
      @ObjectModel.foreignKey.association: '_MfgOrderOperation'
      cast(resb.aplzl as operationinternalid preserving type) as OrderIntBillOfOperationsItem,
      @ObjectModel.foreignKey.association: '_Material'
      resb.matnr                                              as Material,
      @ObjectModel.foreignKey.association: '_Plant'
      resb.werks                                              as Plant,
      resb.lgort                                              as StorageLocation,
      resb.meins                                              as BaseUnit,
      @ObjectModel.foreignKey.association: '_Batch'
      resb.charg                                              as Batch,
      @Semantics.quantity.unitOfMeasure: 'BaseUnit'
      resb.bdmng                                              as RequiredQuantity,
      resb.erfme                                              as EntryUnit,
      @Semantics.quantity.unitOfMeasure: 'EntryUnit'
      cast(resb.erfmg as pph_erfmg preserving type)           as GoodsMovementEntryQty,
      resb.kzear                                              as ReservationIsFinallyIssued,
      resb.fmeng                                              as QuantityIsFixed,
      cast(resb.xloek as pph_xloek preserving type)           as MatlCompIsMarkedForDeletion,
      resb.xfehl                                              as MaterialComponentIsMissing,
      resb.schgt                                              as IsBulkMaterialComponent,
      resb.rgekz                                              as MatlCompIsMarkedForBackflush,
      resb.txtps                                              as MatlCompIsTextItem,
      cast(resb.no_disp as vdm_no_disp preserving type)       as MaterialPlanningRelevance,
      resb.kfpos                                              as MatlCompIsConfigurable,
      @ObjectModel.foreignKey.association: '_DebitCreditCode'
      cast(resb.shkzg as pph_shkzg preserving type)           as DebitCreditCode,
      resb.xwaok                                              as GoodsMovementIsAllowed,
      @ObjectModel.foreignKey.association: '_MatlCompDiscontinuationType'
      resb.kzaus                                              as MatlCompDiscontinuationType,
      resb.techs                                              as EffectivityParameterVariant,
      resb.baugr                                              as Assembly,

      // Variable-size comp. data

      resb.rohps                                              as MaterialCompIsVariableSized,
      cast(case
             when resb.rohps = 'X' then tcs03.roame
             else resb.rohps
      end as vdm_roame)                                       as VariableSizeItemUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeItemUnit'
      cast(resb.roanz as pph_roanz preserving type)           as VariableSizeItemQuantity,
      cast(resb.rokme as pph_rokme preserving type)           as VariableSizeComponentUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeComponentUnit'
      cast(resb.romen as pph_romen preserving type)           as VariableSizeComponentQuantity,
      resb.romei                                              as VariableSizeDimensionUnit,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      resb.roms1                                              as VariableSizeDimension1,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      resb.roms2                                              as VariableSizeDimension2,
      @Semantics.quantity.unitOfMeasure: 'VariableSizeDimensionUnit'
      resb.roms3                                              as VariableSizeDimension3,
      resb.rform                                              as FormulaKey,

      // Assignments BOM

      cast(resb.stlty as pph_stlty preserving type)           as BillOfMaterialCategory,
      cast(resb.stlnr as pph_stnum preserving type)           as BillOfMaterialInternalID,
      resb.stlal                                              as BillOfMaterialVariant,
      cast(resb.stlkn as pph_stlkn preserving type)           as BOMItem,
      resb.bom_versn                                          as BillOfMaterialVersion,
      resb.stpoz                                              as BOMItemInternalChangeCount,
      resb.stvkn                                              as InheritedBOMItemNode,
      cast(resb.postp as pph_postp preserving type)           as BOMItemCategory,
      @ObjectModel.text.element: ['BOMItemDescription']
      cast(resb.posnr as vdm_sposn preserving type)           as BillOfMaterialItemNumber,
      @Semantics.text: true
      resb.potx1                                              as BOMItemDescription,
      @Semantics.text: true
      resb.potx2                                              as BOMItemText2,

      OpActyComponentAssignment._OpActyNtwkInstance,
      OpActyComponentAssignment._OpActyNtwkInstanceBasic,
      OpActyComponentAssignment._OperationActivityInstance,
      OpActyComponentAssignment._ReservationHeader,
      OpActyComponentAssignment._ReltdOpActyCompAssignment,
      OpActyComponentAssignment._PlannedInventoryUsblyCode,
      OpActyComponentAssignment._BOMItmMfgRefStrucItmAssgmt,
      OpActyComponentAssignment._MfgRefStrucItemWithDetails,
      OpActyComponentAssignment._MfgRefHierItemWithDetails,
      _Reservation,
      _ReservationItem,
      _ReservationDocRecordType,
      _ManufacturingOrder,
      _MfgOrderOperation,
      _OrderInternalID,
      _Product,
      _Material,
      _ProductPlantBasic,
      _Plant,
      _StorageLocation,
      _Batch,
      _BOMItemCategory,
      _BaseUnit,
      _EntryUnit,
      _DebitCreditCode,
      _MatlCompDiscontinuationType
}