I_MFGBOOSEQUENCECHANGESTATE

CDS View

Manufacturing Bill of Operations Sequence Change State

I_MFGBOOSEQUENCECHANGESTATE is a CDS View in S/4HANA. Manufacturing Bill of Operations Sequence Change State. It contains 32 fields. 12 CDS views read from this table.

Used by 12 CDS view(s) 32 fields

CDS Views using this table (12)

ViewTypeJoinVDMDescription
/VSCEW/C_NSC_Sequence view_entity inner Neutral Supply Chain Sequence
I_MasterRecipeActivity view_entity from COMPOSITE Master Recipe Activity(Opr,Phs,SecRes) Details
I_ProdnRtgOpCompAllocToOp view_entity inner COMPOSITE Prodn Rtg Comp Alloc to Operation
I_ProdnRtgOperationToSequence view_entity inner COMPOSITE Prodn Rtg Operation to Sequence
I_ProdnRtgOpInspCharcsToOp view_entity inner COMPOSITE Prodn Rtg Inspection Charcs to Operation
I_ProdnRtgOpPRTAssgmtToOp view_entity inner COMPOSITE Prodn Rtg PRT Assgmt to Operation
I_ProdnRtgSequenceToHeader view_entity from COMPOSITE Prodn Routing Sequence to Header
I_ProdnRtgSequenceTP view_entity from TRANSACTIONAL Transaction View for Production Routing Sequence
I_ProdnRtgSubordOpToOperation view_entity inner COMPOSITE Prodn Rtg Subperation to Operation
I_RoutingSequence view from BASIC Routing Sequence Details
I_TaskListSequence view_entity from COMPOSITE Task List Sequence
R_ProdnRoutingSequenceTP_2 view_entity from TRANSACTIONAL Production Routing Sequence

Fields (32)

KeyField CDS FieldsUsed in Views
KEY BillOfOperationsGroup BillOfOperationsGroup,ProductionRoutingGroup 4
KEY BillOfOperationsSequence BillOfOperationsSequence,ProductionRoutingSequence,Sequence 5
KEY BillOfOperationsType BillOfOperationsType 2
KEY BillOfOperationsVariant BillOfOperationsVariant,ProductionRouting 4
KEY BOOSqncInternalVersionCounter BOOSqncInternalVersionCounter,ProductionRoutingSqncIntVers 3
_BillOfOperations _BillOfOperations 2
_BillOfOperationsGroup _BillOfOperationsGroup 2
_BillOfOperationsRefSequence _BillOfOperationsRefSequence 1
_BillOfOperationsSequence _BillOfOperationsSequence 2
_BillOfOperationsType _BillOfOperationsType 2
_BOOOperationsBranchOperation _BOOOperationsBranchOperation 1
_BOOOperationsReturnOperation _BOOOperationsReturnOperation 1
_ChangeMaster _ChangeMaster 2
_SequenceCategory _SequenceCategory 2
BillOfOperationsRefSequence BillOfOperationsRefSequence 3
BillOfOperationsUnit BillOfOperationsUnit,Unit 2
BOOSqncBranchOpInternalID BOOSqncBranchOpInternalID 3
BOOSqncReturnOpInternalID BOOSqncReturnOpInternalID 3
ChangeNumber ChangeNumber 2
CreatedByUser CreatedByUser 2
CreationDate CreationDate 2
IsDeleted IsDeleted 2
IsImplicitlyDeleted IsImplicitlyDeleted 2
LastChangeDate LastChangeDate 2
LastChangedByUser LastChangedByUser 2
MaximumLotSizeQuantity MaximumLotSizeQuantity 3
MinimumLotSizeQuantity MinimumLotSizeQuantity 3
SequenceCategory Category,SequenceCategory 3
SequenceSchedulingAlignment SequenceSchedulingAlignment 1
SequenceText SequenceText,Text 3
ValidityEndDate ValidityEndDate 1
ValidityStartDate ValidityStartDate 1 
@AbapCatalog.sqlViewName: 'IMFGBOOSEQNCCHST'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@Analytics.dataCategory: #DIMENSION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@Metadata.allowExtensions: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE,#EXTRACTION_DATA_SOURCE]
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.representativeKey: 'BOOSqncInternalVersionCounter'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #MASTER }
@Analytics.dataExtraction.enabled: true
@ObjectModel.sapObjectNodeType.name: 'ProductionRoutingSequence'
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@EndUserText.label: 'Manufacturing Bill of Operations Sequence Change State'

define view I_MfgBOOSequenceChangeState
  as select from I_BOOSequenceChangeState      as plfl

  association [1..1] to I_MfgBillOfOperations          as _BillOfOperations             on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant
  association [1..1] to I_MfgBillOfOperationsSequence  as _BillOfOperationsSequence     on  $projection.BillOfOperationsType     = _BillOfOperationsSequence.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup    = _BillOfOperationsSequence.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant  = _BillOfOperationsSequence.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsSequence = _BillOfOperationsSequence.BillOfOperationsSequence
  association [1..1] to I_MfgBillOfOperationsSequence  as _BillOfOperationsRefSequence  on  $projection.BillOfOperationsType        = _BillOfOperationsRefSequence.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _BillOfOperationsRefSequence.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant     = _BillOfOperationsRefSequence.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsRefSequence = _BillOfOperationsRefSequence.BillOfOperationsSequence

  association [0..1] to I_MfgBillOfOperationsOperation as _BOOOperationsBranchOperation on  $projection.BillOfOperationsType        = _BOOOperationsBranchOperation.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _BOOOperationsBranchOperation.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant     = _BOOOperationsBranchOperation.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsRefSequence = _BOOOperationsBranchOperation.BillOfOperationsSequence
                                                                                        and $projection.BOOSqncBranchOpInternalID   = _BOOOperationsBranchOperation.BOOOperationInternalID
  association [0..1] to I_MfgBillOfOperationsOperation as _BOOOperationsReturnOperation on  $projection.BillOfOperationsType        = _BOOOperationsReturnOperation.BillOfOperationsType
                                                                                        and $projection.BillOfOperationsGroup       = _BOOOperationsReturnOperation.BillOfOperationsGroup
                                                                                        and $projection.BillOfOperationsVariant     = _BOOOperationsReturnOperation.BillOfOperationsVariant
                                                                                        and $projection.BillOfOperationsRefSequence = _BOOOperationsReturnOperation.BillOfOperationsSequence
                                                                                        and $projection.BOOSqncReturnOpInternalID   = _BOOOperationsReturnOperation.BOOOperationInternalID
  association [1..1] to I_SequenceCategory             as _SequenceCategory             on  $projection.SequenceCategory = _SequenceCategory.SequenceCategory

{
      // Key

      @ObjectModel.foreignKey.association: '_BillOfOperationsType'
  key plfl.BillOfOperationsType,
      @ObjectModel.foreignKey.association: '_BillOfOperationsGroup'
  key plfl.BillOfOperationsGroup,
      @ObjectModel.foreignKey.association: '_BillOfOperations'
  key plfl.BillOfOperationsVariant,
      @ObjectModel.foreignKey.association: '_BillOfOperationsSequence'
  key plfl.BillOfOperationsSequence,
      @ObjectModel.text.element: 'SequenceText'
  key plfl.BOOSqncInternalVersionCounter,

      // Attributes

      plfl.IsDeleted,
      plfl.IsImplicitlyDeleted,

      // Administrative Data

      @ObjectModel.foreignKey.association: '_ChangeMaster'
      plfl.ChangeNumber,
      @Semantics.businessDate.from: true
      plfl.ValidityStartDate,
      @Semantics.businessDate.to: true
      plfl. ValidityEndDate,
      @Semantics.systemDate.createdAt: true
      plfl.CreationDate,
      plfl.CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      plfl.LastChangeDate,
      plfl.LastChangedByUser,

      // Sequence Details

      -- Sequence
      @Semantics.text: true
      plfl.SequenceText,
      @ObjectModel.foreignKey.association: '_SequenceCategory'
      plfl.BillOfOperationsSequenceCat as SequenceCategory,
      @ObjectModel.foreignKey.association: '_SequenceSchedulingAlignment'
      plfl.SequenceSchedulingAlignment,
      -- Reference
      @ObjectModel.foreignKey.association: '_BillOfOperationsRefSequence'
      plfl.BillOfOperationsRefSequence,
      @ObjectModel.foreignKey.association: '_BOOOperationsBranchOperation'
      plfl.BOOSqncBranchOpInternalID,
      @ObjectModel.foreignKey.association: '_BOOOperationsReturnOperation'
      plfl.BOOSqncReturnOpInternalID,
      -- Alternative Sequence
      //as of now the correct UoM cannot be determined in CDS views. Field needs to be kept for compatibility reasons.

      @Consumption.hidden: true
      BillOfOperationsUnit,
      @DefaultAggregation: #MIN
      plfl.MinimumLotSizeQuantity,
      @DefaultAggregation: #MAX      
      plfl.MaximumLotSizeQuantity,

      // Associations

      _BillOfOperations,
      _BillOfOperationsGroup,
      _BillOfOperationsRefSequence,
      _BillOfOperationsSequence,
      _BillOfOperationsType,
      _BOOOperationsBranchOperation,
      _BOOOperationsReturnOperation,
      _ChangeMaster,
      _SequenceCategory,
      _SequenceSchedulingAlignment
}
where plfl.BillOfOperationsType = '2'  // Recipe

   or plfl.BillOfOperationsType = 'N'  // Standard routing

   or plfl.BillOfOperationsType = 'S'; // Reference operation set

Learn More