I_MATLPROCUREMENTPROFILE

CDS View

Material Procurement Profile

I_MATLPROCUREMENTPROFILE is a CDS View in S/4HANA. Material Procurement Profile. It contains 1 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 1 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
/VSCEW/A_Product view_entity left_outer Product
C_ProdPlntProcmtProfileVH view from CONSUMPTION VH for Special Procurement Profile
I_ProductProcmtProfile view from BASIC Product Procurement Profile
I_ProductProcmtProfileVH view from BASIC Product Procurement Profile VH
P_LastFallBackLeadTime view_entity left_outer CONSUMPTION Demand Driven Product Lead Time From Material Master
P_ProductMasterLeadTime view left_outer CONSUMPTION Lead Time Details from Product Master

Fields (1)

KeyField CDS FieldsUsed in Views
MaterialProcurementExtType MaterialProcurementExtType 1 
@AbapCatalog.sqlViewName: 'IMATLPROCMPRFL'
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.representativeKey: 'MaterialProcurementProfile'
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'Material Procurement Profile'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_MatlProcurementProfile
  as select from t460a as prfl
  association [1..1] to I_Plant                       as _Plant                        on  $projection.Plant = _Plant.Plant
  association [0..1] to I_Plant                       as _SupplyingOrProductionPlant   on  $projection.SupplyingOrProductionPlant = _SupplyingOrProductionPlant.Plant  
  association [0..1] to I_Plant                       as _IssuingPlant                 on  $projection.IssuingPlant = _IssuingPlant.Plant  
  association [0..*] to I_MatlProcurementProfileText  as _Text                         on  $projection.MaterialProcurementProfile  = _Text.MaterialProcurementProfile
                                                                                       and $projection.Plant                       = _Text.Plant
  association [1..1] to I_MatlProcurementCategory     as _MaterialProcurementCategory  on  $projection.MaterialProcurementCategory = _MaterialProcurementCategory.MaterialProcurementCategory
  association [0..*] to I_MatlProcurementExternalType as _MaterialProcurementExtType   on  $projection.MaterialProcurementExtType  = _MaterialProcurementExtType.MaterialProcurementExtType
  association [0..1] to I_MatlProcurementExternalType as _MaterialProcurementExtType_2 on  $projection.MaterialProcurementExtType  = _MaterialProcurementExtType_2.MaterialProcurementExtType
                                                                                       and $projection.Language                    = _MaterialProcurementExtType_2.Language
  association [0..1] to I_MatlProcmtExternalType      as _MaterialProcurementExtType_3 on  $projection.MaterialProcurementExtType  = _MaterialProcurementExtType_3.MaterialProcurementExtType

{
      // Key

      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      @ObjectModel.text.association: '_Text'
  key cast(prfl.sobsl as pph_sobsl preserving type) as MaterialProcurementProfile,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_Plant'
  key prfl.werks                                    as Plant,

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MatlProcurementCategory', element: 'MaterialProcurementCategory' } } ]
      @ObjectModel.foreignKey.association: '_MaterialProcurementCategory'
      cast(prfl.beskz as pph_beskz preserving type) as MaterialProcurementCategory,
      @ObjectModel.foreignKey.association: '_MaterialProcurementExtType_3'
      cast(prfl.sobes as pph_esobs preserving type) as MaterialProcurementExtType,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_SupplyingOrProductionPlant'      
      cast(prfl.wrk02 as vdm_wrk02 preserving type) as SupplyingOrProductionPlant,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_IssuingPlant'      
      prfl.rewrk                                    as IssuingPlant,

      // for successor assoc. only

      @Consumption.hidden: true
      $session.system_language                      as Language,

      // Attributes

      prfl.clcor as MaterialIsDirectlyProduced,
      prfl.dirpr as MaterialIsDirectlyProcured,
      prfl.dumps as IsPhantomItem,
      prfl.rewfg as IsWithdrawnFrmAlternativePlant,
      prfl.umldb as MRPStockTransfSelectionControl,
      prfl.mlscr as MatlIsRlvtForMultiLvlSubcontrg,

      // Associations

      _Plant,
      _IssuingPlant,
      _SupplyingOrProductionPlant,
      _MaterialProcurementCategory,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_MaterialProcurementExtType_3'
      _MaterialProcurementExtType,
      @API.element.releaseState: #DEPRECATED
      @API.element.successor: '_MaterialProcurementExtType_3'
      _MaterialProcurementExtType_2,
      _MaterialProcurementExtType_3,
      _Text
};

Learn More