I_MATERIALSAMPLEDRAWING

CDS View

Material Sample Drawing

I_MATERIALSAMPLEDRAWING is a CDS View in S/4HANA. Material Sample Drawing. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_MaterialSampleDetails view left_outer COMPOSITE CDS View for Material Sample Details
SHSM_QPRN view from Material Sample Drawing 
@AbapCatalog.sqlViewName: 'IMATLSMPLDRW'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #BASIC
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
@EndUserText.label: 'Material Sample Drawing'
@ObjectModel.representativeKey: 'MaterialSampleDrawing'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #M, dataClass: #TRANSACTIONAL }
define view I_MaterialSampleDrawing as select from qprn 
    //Association to other QM nodes

    association [0..1] to I_InspectionLot as _InspectionLot
      on $projection.InspectionLot = _InspectionLot.InspectionLot
    association [0..*] to I_MaterialSample as _MaterialSample
      on $projection.MaterialSampleDrawing = _MaterialSample.MaterialSampleDrawing
    //Associations to views of other applications

    association [1..1] to I_Plant as _Plant
      on $projection.Plant = _Plant.Plant
    association [1..1] to I_Material as _Material
      on $projection.Material = _Material.Material
    association [0..1] to I_Customer as _Customer  
      on  $projection.Customer = _Customer.Customer
    association [0..1] to I_Supplier as _Supplier  
      on  $projection.Supplier = _Supplier.Supplier
    association [0..1] to I_Supplier as _Manufacturer  
      on  $projection.Manufacturer = _Manufacturer.Supplier
    association [0..1] to I_MatlQualityAuthGroup as _MatlQualityAuthGroup
      on $projection.MatlQualityAuthorizationGroup = _MatlQualityAuthGroup.MatlQualityAuthorizationGroup
   //Extension - Extension should not be used, because of Guideline

    association [1..1] to E_MaterialSampleDrawing as _Extension         
        on $projection.MaterialSampleDrawing               = _Extension.MaterialSampleDrawing
{
    key cast( qprn.pn_nr as vdm_qpznr preserving type )  as MaterialSampleDrawing,
    @ObjectModel.foreignKey.association: '_InspectionLot'
    qprn.plos as InspectionLot,
    @ObjectModel.foreignKey.association: '_Material'
    qprn.matnr as Material,
    @ObjectModel.foreignKey.association: '_Plant'
    qprn.werks as Plant,
    qprn.charg as Batch,
    @Consumption.hidden: true
    qprn.cvp_xblck                                       as IsBusinessPurposeCompleted,
    @ObjectModel.foreignKey.association: '_Customer'
    qprn.kunnr as Customer,
    @ObjectModel.foreignKey.association: '_Supplier'
    qprn.lifnr as Supplier,
    @ObjectModel.foreignKey.association: '_Manufacturer'
    qprn.hrstl as Manufacturer,
    @ObjectModel.foreignKey.association: '_MatlQualityAuthGroup'
    cast( qprn.qmatauth as vdm_qmatauth preserving type ) as MatlQualityAuthorizationGroup,
    qprn.qmnum as StabilityStudy,
    @Semantics.user.createdBy: true
    qprn.anlna as CreatedByUser,
    @Semantics.businessDate.createdAt: true
    qprn.anldt as CreationDate,
    @Semantics.time: true
    qprn.anlzt as CreationTime,
    qprn.frgna as MaterialSampleReleasedBy,
    qprn.frgdt as MaterialSampleReleaseDate,
    qprn.frgzt as MaterialSampleReleaseTime,
    
    //Associations

    _InspectionLot,
    _Plant,
    _Material,
    _Customer,
    _Supplier,
    _Manufacturer,
    _MaterialSample,
    _MatlQualityAuthGroup
}

Learn More