I_MANUFACTURINGORDERSTATUS

CDS View

Manufacturing Order Status

I_MANUFACTURINGORDERSTATUS is a CDS View in S/4HANA. Manufacturing Order Status. It contains 1 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 1 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ManufacturingOrderStatusText view_entity from COMPOSITE Manufacturing Order Status - Text

Fields (1)

KeyField CDS FieldsUsed in Views
KEY ManufacturingOrder ManufacturingOrder 1 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_StatusObject']
@Analytics.dataCategory: #FACT
--@Analytics.dataExtraction.enabled: true
@Analytics.technicalName: 'IMFGORDERSTATUS'
@Consumption.ranked: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #NONE
@ObjectModel.supportedCapabilities: [#CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY]
@ObjectModel.usageType: {serviceQuality: #C, sizeCategory: #XXL, dataClass: #MIXED}
@Search.searchable: true
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #COMPOSITE
@EndUserText.label: 'Manufacturing Order Status'
-- CDS view for all system and user status of a manufacturing order

define view entity I_ManufacturingOrderStatus
    as select from I_OrderBasic         as aufk
       inner join  I_StatusObjectStatus as jest on jest.StatusObject = aufk.ObjectInternalID

    association [1..1] to I_MfgOrderCategory   as _MfgOrderCategory   on  $projection.ManufacturingOrderCategory = _MfgOrderCategory.ManufacturingOrderCategory
 -- to root/parent
    association [1..1] to I_ManufacturingOrder as _ManufacturingOrder on  $projection.ManufacturingOrder = _ManufacturingOrder.ManufacturingOrder
--  to child
    association [0..*] to I_ManufacturingOrderStatusText as _Text     on  $projection.ManufacturingOrder = _Text.ManufacturingOrder
                                                                      and $projection.StatusCode         = _Text.StatusCode
{
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MfgOrderStdVH', element: 'ManufacturingOrder' } } ]
      @ObjectModel.text.association: '_Text'
  key cast(aufk.OrderID as manufacturingorder preserving type)          as ManufacturingOrder,
      @ObjectModel.foreignKey.association: '_StatusCode'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key jest.StatusCode,
 
      @ObjectModel.foreignKey.association: '_StatusObject'
      cast(jest.StatusObject as j_objnr preserving type)                as StatusObject,
      @ObjectModel.foreignKey.association: '_StatusProfile'
      jest.StatusProfile,
      cast(jest.IsUserStatus   as vdm_j_isuserstatus   preserving type) as IsUserStatus,
      cast(jest.StatusIsActive as vdm_j_statusisactive preserving type) as StatusIsActive,
      @Semantics.booleanIndicator 
      jest.StatusIsInactive,

      @ObjectModel.foreignKey.association: '_MfgOrderCategory'
      aufk.OrderCategory as ManufacturingOrderCategory,

      // Associations

      @ObjectModel.association.type: [#TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT]
      _ManufacturingOrder,
--    @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Text,
      _MfgOrderCategory,
      jest._StatusObject,
      jest._StatusCode,
      jest._StatusProfile
}
where aufk.OrderCategory = '10'
   or aufk.OrderCategory = '40';

Learn More