I_MAINTENANCEORDERCONFTP
Maintenance Order Confirmation
I_MAINTENANCEORDERCONFTP is a CDS View in S/4HANA. Maintenance Order Confirmation. It contains 57 fields. 4 CDS views read from this table.
CDS Views using this table (4)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_MaintOrdConfForCreateTP | view | from | CONSUMPTION | Consumption View for Maintenance Order Confirmation Create |
| C_MaintOrderConfirmationTP | view | from | CONSUMPTION | Maintenance Order Confirmation |
| C_ObjPgMaintOrderConfirmation | view | from | CONSUMPTION | Maintenance Order Confirmation |
| I_MaintOrdConfMessageTP | view_entity | from | TRANSACTIONAL | Basic View for Maintenance Order Confirmation Messages |
Fields (57)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | MaintOrderConf | MaintOrderConf | 4 |
| KEY | MaintOrderConfCntrValue | MaintOrderConfCntrValue | 4 |
| _EnteredByUser | _EnteredByUser | 1 | |
| _IsFinalConfirmation | _IsFinalConfirmation | 1 | |
| _IsReversal | _IsReversal | 1 | |
| _IsReversed | _IsReversed | 1 | |
| _LongTextExists | _LongTextExists | 1 | |
| _NoFurtherWorkQuantityIsExpd | _NoFurtherWorkQuantityIsExpd | 1 | |
| _OpenReservationsIsCleared | _OpenReservationsIsCleared | 1 | |
| _PersonnelName | _PersonnelName | 1 | |
| _VarianceReason | _VarianceReason | 1 | |
| AccountingIndicatorCode | AccountingIndicatorCode | 1 | |
| ActivityType | ActivityType | 2 | |
| ActualDuration | ActualDuration | 1 | |
| ActualDurationUnit | ActualDurationUnit | 1 | |
| ActualWorkExternalQuantityUnit | ActualWorkExternalQuantityUnit | 1 | |
| ActualWorkQtyInExternalUnit | ActualWorkQtyInExternalUnit | 1 | |
| ActualWorkQuantity | ActualWorkQuantity | 3 | |
| ActualWorkQuantityUnit | ActualWorkQuantityUnit | 3 | |
| ActyConfFcstdEndDate | ActyConfFcstdEndDate | 2 | |
| ActyConfFcstdEndTime | ActyConfFcstdEndTime | 2 | |
| AddressTimeZone | AddressTimeZone | 2 | |
| ConfirmationText | ConfirmationText | 2 | |
| EmployeeWageType | EmployeeWageType | 1 | |
| EnteredByUser | EnteredByUser | 1 | |
| FactoryCalendar | FactoryCalendar | 1 | |
| IsFinalConfirmation | IsFinalConfirmation | 3 | |
| IsReversal | IsReversal | 1 | |
| IsReversed | IsReversed | 1 | |
| Language | Language | 1 | |
| LastChangedByUser | LastChangedByUser | 1 | |
| LongTextExists | LongTextExists | 1 | |
| MaintenanceOrder | MaintenanceOrder | 3 | |
| MaintenanceOrderOperation | MaintenanceOrderOperation | 3 | |
| MaintenanceOrderSubOperation | MaintenanceOrderSubOperation | 2 | |
| MaintOrderConfCntrValueForEdit | MaintOrderConfCntrValueForEdit | 3 | |
| MaintOrderConfForEdit | MaintOrderConfForEdit | 3 | |
| MaintOrderOperationCounter | MaintOrderOperationCounter | 1 | |
| MaintOrderOperationInternalID | MaintOrderOperationInternalID | 1 | |
| NoFurtherWorkQuantityIsExpd | NoFurtherWorkQuantityIsExpd | 2 | |
| OpenReservationsIsCleared | OpenReservationsIsCleared | 2 | |
| OperationConfirmedEndDate | OperationConfirmedEndDate | 2 | |
| OperationConfirmedEndTime | OperationConfirmedEndTime | 2 | |
| OperationConfirmedStartDate | OperationConfirmedStartDate | 2 | |
| OperationConfirmedStartTime | OperationConfirmedStartTime | 2 | |
| OperationDescription | OperationDescription | 1 | |
| PersonnelNumber | OperationPersonResponsible,PersonnelNumber | 3 | |
| Plant | Plant | 3 | |
| PlantTimeZone | PlantTimeZone | 1 | |
| PostingDate | PostingDate | 3 | |
| RemainingWorkExtQuantityUnit | RemainingWorkExtQuantityUnit | 1 | |
| RemainingWorkQtyInExternalUnit | RemainingWorkQtyInExternalUnit | 1 | |
| RemainingWorkQuantity | RemainingWorkQuantity | 3 | |
| RemainingWorkQuantityUnit | RemainingWorkQuantityUnit | 3 | |
| VarianceReasonCode | VarianceReasonCode | 2 | |
| WorkCenter | WorkCenter | 1 | |
| WorkCenterInternalID | WorkCenterInternalID | 1 |
@AbapCatalog.sqlViewName: 'IMAINTORDCONFTP'
@EndUserText.label: 'Maintenance Order Confirmation'
@ObjectModel.compositionRoot: true
@ObjectModel.transactionalProcessingEnabled: true
@ObjectModel.writeDraftPersistence: 'MAINTORDCONF_D'
@ObjectModel.draftEnabled:true
@VDM.viewType: #TRANSACTIONAL
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true
@ObjectModel.semanticKey: [ 'MaintOrderConf', 'MaintOrderConfCntrValue' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
define view I_MaintenanceOrderConfTP
as select from I_MaintenanceOrderConfirmation as Document
association [0..*] to I_MaintOrdConfGoodsMovementTP as _MaintOrdConfGoodsMovementTP on _MaintOrdConfGoodsMovementTP.MaintOrderConf = $projection.MaintOrderConf
and _MaintOrdConfGoodsMovementTP.MaintOrderConfCntrValue = $projection.MaintOrderConfCntrValue
association [0..1] to I_WorkCenter as _ActualWorkCenter on _ActualWorkCenter.WorkCenterInternalID = $projection.WorkCenterInternalID
and _ActualWorkCenter.WorkCenterTypeCode = 'A'
association [0..1] to I_Indicator as _IsReversed on _IsReversed.IndicatorValue = $projection.IsReversed
association [0..1] to I_Indicator as _IsReversal on _IsReversal.IndicatorValue = $projection.IsReversal
association [0..1] to I_Indicator as _IsFinalConfirmation on _IsFinalConfirmation.IndicatorValue = $projection.IsFinalConfirmation
association [0..1] to I_Indicator as _OpenReservationsIsCleared on _OpenReservationsIsCleared.IndicatorValue = $projection.OpenReservationsIsCleared
association [0..1] to I_Indicator as _NoFurtherWorkQuantityIsExpd on _NoFurtherWorkQuantityIsExpd.IndicatorValue = $projection.NoFurtherWorkQuantityIsExpd
association [0..1] to I_Indicator as _LongTextExists on _LongTextExists.IndicatorValue = $projection.LongTextExists
--association [0..1] to I_MaintenanceOrder as _MaintenanceOrder on _MaintenanceOrder.MaintenanceOrder = $projection.MaintenanceOrder
association [0..1] to I_User as _EnteredByUser on _EnteredByUser.UserID = $projection.EnteredByUser
association [0..1] to I_User as _LastChangeByUser on _LastChangeByUser.UserID = $projection.LastChangedByUser
association [0..1] to I_VarianceReason as _VarianceReason on $projection.Plant = _VarianceReason.Plant
and $projection.VarianceReasonCode = _VarianceReason.VarianceReasonCode
association [0..1] to I_Language as _Language on _Language.Language = $projection.Language
association [1..*] to I_MaintOrdConfMessageTP as _MaintOrdConfMessageTP on
// _MaintOrdConfMessageTP.MaintenanceOrder = $projection.MaintenanceOrder
// and _MaintOrdConfMessageTP.MaintenanceOrderOperation = $projection.MaintenanceOrderOperation
_MaintOrdConfMessageTP.MaintOrderConf = $projection.MaintOrderConf
and _MaintOrdConfMessageTP.MaintOrderConfCntrValue = $projection.MaintOrderConfCntrValue
-- Extensions, do not expose as association:
association [0..1] to E_MaintenanceOrder as _MaintenanceOrderExtension on $projection.MaintenanceOrder = _MaintenanceOrderExtension.MaintenanceOrder
association [0..1] to E_MaintenanceOrderConfirmation as _MaintOrdConfExtension on Document.MaintOrderConf = _MaintOrdConfExtension.MaintOrderConf
and Document.MaintOrderConfCntrValue = _MaintOrdConfExtension.MaintOrderConfCntrValue
{
key Document.MaintOrderConf,
key Document.MaintOrderConfCntrValue,
Document.MaintOrderConf as MaintOrderConfForEdit,
Document.MaintOrderConfCntrValue as MaintOrderConfCntrValueForEdit,
Document.MaintOrderConfirmationEntryDte,
Document.MaintOrderOperationCounter,
Document.EnteredByUser,
Document.LastChangeDate,
Document.LastChangedByUser,
Document.PostingDate,
Document.WorkCenterInternalID,
Document.ConfirmationText,
Document.Language,
Document.LongTextExists,
Document.ActualWorkQuantity,
Document.ActualWorkQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'ActualWorkExternalQuantityUnit'
cast( 0 as ismnw_2 ) as ActualWorkQtyInExternalUnit,
ActualWorkExternalQuantityUnit,
Document.ActivityType,
Document.ActualDuration,
Document.ActualDurationUnit,
Document.EmployeeWageType,
Document.ConfirmationYieldQuantity,
Document.ConfirmationScrapQuantity,
Document.ConfirmationUnit,
Document.VarianceReasonCode,
Document.PersonnelNumber,
Document.OperationConfirmedStartDate,
Document.OperationConfirmedStartTime,
@Semantics.dateTime: true
Document.MaintOrdOpWrkExecStartDateTime,
Document.OperationConfirmedEndDate,
Document.OperationConfirmedEndTime,
@Semantics.dateTime: true
Document.MaintOrdOpWrkExecEndDateTime,
Document.ActyConfFcstdEndDate,
Document.ActyConfFcstdEndTime,
@Semantics.dateTime: true
Document.MaintOrdOpFcstdEndDateTime,
@Semantics.timeZone: true
Document.AddressTimeZone,
@Semantics.timeZone: true
Document.UserEnteredTimeZone,
@Semantics.timeZone: true
Document.PlantTimeZone,
Document.IsFinalConfirmation,
Document.OpenReservationsIsCleared,
Document.MaintenanceOrder,
Document._MaintenanceOrder.MaintenanceOrderDesc,
Document.MaintenanceOrderOperation,
Document._MaintenanceOrderOperation.OperationDescription,
Document.MaintenanceOrderSubOperation,
Document.RemainingWorkQuantity,
Document.RemainingWorkQuantityUnit,
@Semantics.quantity.unitOfMeasure: 'RemainingWorkExtQuantityUnit'
cast( 0 as remnw_2 ) as RemainingWorkQtyInExternalUnit,
RemainingWorkExtQuantityUnit,
Document.NoFurtherWorkQuantityIsExpd,
Document.IsReversed,
Document.IsReversal,
// Document.CancldMaintOrderConfCntrValue,
Document.ConfirmationReworkQuantity,
Document.MaintOrderConfirmationEntryTme,
Document.AccountingIndicatorCode,
Document.EnteredByExternalUser,
Document.ConfirmationExternalEntryDate,
Document.ConfirmationExternalEntryTime,
Document.Plant,
Document.FactoryCalendar,
Document.MaintOrderOperationInternalID,
Document._ActualWorkCenter.WorkCenter,
//cast('' as abap.char( 300 )) as SystemMessageText,
cast ('' as abap.char( 10 )) as MaintOrderConfUploadRowNumber,
//cast ('' as abap.char( 10 )) as NumberOfRecords,
cast ('' as pm_source_appl ) as MaintOrdConfSourceApplication,
cast ( hextobin('00000000000000000000000000000000') as sysuuid_x16 preserving type ) as MaintOrdConfUploadUUID,
cast ( '' as symsgty ) as MaintOrderConfUploadMsgType,
cast (0 as abap.int1) as MaintOrdConfUploadMsgCritlty,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_MaintOrdConfGoodsMovementTP,
_Plant,
_ActualWorkCenter,
Document._MaintenanceOrder,
_EnteredByUser,
_LastChangeByUser,
_LongTextExists,
_IsReversed,
_IsReversal,
_IsFinalConfirmation,
_OpenReservationsIsCleared,
_NoFurtherWorkQuantityIsExpd,
_ActualWorkExtQuantityUnit,
_RemainingWorkExtQuantityUnit,
_VarianceReason,
Document._PersonnelName,
_Language,
@ObjectModel.association.type: [ #TO_COMPOSITION_CHILD ]
_MaintOrdConfMessageTP
}