I_MAINTORDEROPERPLANNINGVALUES
Maint. Order Operation Planning Values
I_MAINTORDEROPERPLANNINGVALUES is a CDS View in S/4HANA. Maint. Order Operation Planning Values. It contains 16 fields. 12 CDS views read from this table.
CDS Views using this table (12)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_RSHMaintSchedExistingOp | view | inner | COMPOSITE | Existing Operations not part of Schedule |
| I_RSHMaintSchedSmltdOp | view | inner | COMPOSITE | Maint Scheduling Simulation Operations |
| P_MaintOrdOpPlngRemainingWork | view_entity | from | CONSUMPTION | Maint. Ord. Op. Plng. wth Remaining Work |
| P_RSHDueOperForKPIDetails | view | inner | CONSUMPTION | Due Order Operation KPI Details |
| P_RSHExOpsForScheduling | view | inner | CONSUMPTION | In process and Dispatched operations for scheduling |
| P_RSHOperationDurationInSecond | view | inner | CONSUMPTION | Maintenance Operations with Durations in Seconds |
| P_RSHOperationsForKPI | view | inner | CONSUMPTION | Operations and Sub Operations for overview page |
| P_RSHOperationsForKPIDetails | view | inner | CONSUMPTION | Order KPI Details |
| P_RSHOperationsForUtilization | view | inner | CONSUMPTION | Operations and Sub Operations for utilization |
| P_RSHOperationsPerWorkcenter | view | inner | CONSUMPTION | Operations on Workcenters for certain time frame |
| P_RSHOpsForUtilization | view | inner | CONSUMPTION | Operations and Sub Operations for utilization |
| P_RSHPastOperForKPIDetails | view | inner | CONSUMPTION | Past Order Operation KPI Details |
Fields (16)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| OpActualExecutionEndDate | OpActualExecutionEndDate | 1 | |
| OpActualExecutionEndTime | OpActualExecutionEndTime | 1 | |
| OpActualExecutionStartDate | OpActualExecutionStartDate | 1 | |
| OpActualExecutionStartTime | OpActualExecutionStartTime | 1 | |
| OperationDuration | OperationDuration | 1 | |
| OperationDurationUnit | OperationDurationUnit | 1 | |
| OperationPlannedWork | OperationPlannedWork | 4 | |
| OperationPlannedWorkUnit | OperationPlannedWorkUnit | 4 | |
| OpErlstSchedldExecEndDte | OpErlstSchedldExecEndDte | 1 | |
| OpErlstSchedldExecEndTme | OpErlstSchedldExecEndTme | 1 | |
| OpErlstSchedldExecStrtDte | OpErlstSchedldExecStrtDte | 1 | |
| OpErlstSchedldExecStrtTme | OpErlstSchedldExecStrtTme | 1 | |
| OpLtstSchedldExecEndDte | OpLtstSchedldExecEndDte | 1 | |
| OpLtstSchedldExecEndTme | OpLtstSchedldExecEndTme | 1 | |
| OpLtstSchedldExecStrtDte | OpLtstSchedldExecStrtDte | 1 | |
| OpLtstSchedldExecStrtTme | OpLtstSchedldExecStrtTme | 1 |
@VDM.viewType: #BASIC
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true}
@AbapCatalog.sqlViewName: 'IMTORDOPPLV'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Maint. Order Operation Planning Values'
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #XL
@AbapCatalog.preserveKey
define view I_MaintOrderOperPlanningValues
as select from afvv
association [0..1] to I_MaintenanceOrderOperation as _MaintenanceOrderOperation on _MaintenanceOrderOperation.MaintOrderRoutingNumber = $projection.MaintOrderRoutingNumber
and _MaintenanceOrderOperation.MaintOrderOperationCounter = $projection.MaintOrderOperationCounter
association [0..1] to I_UnitOfMeasure as _PlannedWorkUnitOfMeasure on $projection.OperationPlannedWorkUnit = _PlannedWorkUnitOfMeasure.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _DurationUnitOfMeasure on $projection.OperationDurationUnit = _DurationUnitOfMeasure.UnitOfMeasure
association [0..1] to I_UnitOfMeasure as _OperationQtyUnitOfMeasure on $projection.OperationQuantityUnit = _OperationQtyUnitOfMeasure.UnitOfMeasure
{
key afvv.aufpl as MaintOrderRoutingNumber,
key afvv.aplzl as MaintOrderOperationCounter,
@Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
@DefaultAggregation: #NONE
afvv.arbei as OperationPlannedWork,
@ObjectModel.foreignKey.association: '_PlannedWorkUnitOfMeasure'
@Semantics.unitOfMeasure:true
afvv.arbeh as OperationPlannedWorkUnit,
@Semantics.quantity.unitOfMeasure: 'OperationDurationUnit'
@DefaultAggregation: #NONE
afvv.dauno as OperationDuration,
@ObjectModel.foreignKey.association: '_DurationUnitOfMeasure'
@Semantics.unitOfMeasure:true
afvv.daune as OperationDurationUnit,
@Semantics.quantity.unitOfMeasure: 'OperationQuantityUnit'
@DefaultAggregation: #NONE
cast (afvv.mgvrg as cx_losvg) as OperationQuantity,
@ObjectModel.foreignKey.association: '_OperationQtyUnitOfMeasure'
@Semantics.unitOfMeasure: true
cast (afvv.meinh as meins) as OperationQuantityUnit,
afvv.plifz as OpPlndDeliveryDurationInDays,
afvv.fsavd as OpErlstSchedldExecStrtDte,
afvv.fsavz as OpErlstSchedldExecStrtTme,
afvv.fsedd as OpErlstSchedldExecEndDte,
afvv.fsedz as OpErlstSchedldExecEndTme,
afvv.ssavd as OpLtstSchedldExecStrtDte,
afvv.ssavz as OpLtstSchedldExecStrtTme,
afvv.ssedd as OpLtstSchedldExecEndDte,
afvv.ssedz as OpLtstSchedldExecEndTme,
afvv.isdd as OpActualExecutionStartDate,
afvv.isdz as OpActualExecutionStartTime,
afvv.iedd as OpActualExecutionEndDate,
afvv.iedz as OpActualExecutionEndTime,
@Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
afvv.ofmnw as ForecastedWorkQty,
@Semantics.quantity.unitOfMeasure: 'OperationPlannedWorkUnit'
@DefaultAggregation: #NONE
afvv.ismnw as ConfirmationTotalQuantity,
// n3141459
// Fix: FLTP to Decimal Conversion with rounding
cast( round(fltp_to_dec(afvv.bearz as abap.dec(21,14)), 1) as abap.dec(7,1)) as OpPlannedProcessingDurn,
afvv.beaze as OpPlannedProcessingDurnUnit,
cast( afvv.pufgp as ps_s4_ppuff_gesm preserving type ) as TotalFloatForForecastedDates,
cast( afvv.pufgs as puffr_gesm preserving type ) as TotalFloatForBasicDates,
afvv.einsa as OpBscStartDateConstraintType,
afvv.ntanf as ConstraintDateForBscStartDate,
afvv.ntanz as ConstraintTimeForBscStartTime,
afvv.einse as OpBscEndDateConstraintType,
afvv.ntend as ConstraintDateForBscFinishDate,
afvv.ntenz as ConstraintTimeForBscFinishTime,
cast(afvv.puffr as puffr_frei preserving type ) as BasicDatesFreeFloat,
afvv.aufkt as MaintOrdOperationExecutionRate,
afvv.pedd as ActyConfFcstdEndDate,
afvv.pedz as ActyConfFcstdEndTime,
_PlannedWorkUnitOfMeasure,
_DurationUnitOfMeasure,
_OperationQtyUnitOfMeasure,
_MaintenanceOrderOperation
}