I_MAINTORDERHISTTECHOBJ
Maintenance Order History w/ Techn. Obj.
I_MAINTORDERHISTTECHOBJ is a CDS View in S/4HANA. Maintenance Order History w/ Techn. Obj.. It contains 49 fields. 1 CDS views read from this table.
CDS Views using this table (1)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_MaintOrderTechObjCube | view | union_all | COMPOSITE | Maintenance Order With Tech Object - Cube |
Fields (49)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| _Assembly | _Assembly | 1 | |
| _BillOfOperationsGroup | _BillOfOperationsGroup | 1 | |
| _BillOfOperationsType | _BillOfOperationsType | 1 | |
| _Equipment | _Equipment | 1 | |
| _MaintenanceActivityType | _MaintenanceActivityType | 1 | |
| _MaintenanceItem | _MaintenanceItem | 1 | |
| _MaintenanceNotification | _MaintenanceNotification | 1 | |
| _MaintenanceOrderType | _MaintenanceOrderType | 1 | |
| _MaintenancePlan | _MaintenancePlan | 1 | |
| _MaintenancePlannerGroup | _MaintenancePlannerGroup | 1 | |
| _MaintenancePlanningPlant | _MaintenancePlanningPlant | 1 | |
| _MainWorkCenter | _MainWorkCenter | 1 | |
| ActualStartDate | ActualStartDate | 1 | |
| Assembly | Assembly | 1 | |
| BillOfOperations | TaskListGroup | 1 | |
| BillOfOperationsType | TaskListType | 1 | |
| BillOfOperationsVariant | TaskListGroupCounter | 1 | |
| ConfirmedEndDate | ConfirmedEndDate | 1 | |
| CreatedByUser | CreatedByUser | 1 | |
| CreationDate | CreationDate | 1 | |
| Equipment | Equipment | 1 | |
| IsMarkedForDeletion | IsMarkedForDeletion | 1 | |
| LastChangeDate | LastChangeDate | 1 | |
| LastChangedByUser | LastChangedByUser | 1 | |
| LeadingOrder | LeadingOrder | 1 | |
| MaintenanceActivityType | MaintenanceActivityType | 1 | |
| MaintenanceItem | MaintenanceItem | 1 | |
| MaintenanceNotification | MaintenanceNotification | 1 | |
| MaintenanceOrderDesc | MaintenanceOrderDesc | 1 | |
| MaintenanceOrderInternalID | MaintenanceOrderInternalID | 1 | |
| MaintenanceOrderPlanningCode | MaintenanceOrderPlanningCode | 1 | |
| MaintenanceOrderType | MaintenanceOrderType | 1 | |
| MaintenancePlan | MaintenancePlan | 1 | |
| MaintenancePlannerGroup | MaintenancePlannerGroup | 1 | |
| MaintenancePlanningPlant | MaintenancePlanningPlant | 1 | |
| MaintenanceProcessingPhase | MaintenanceProcessingPhase | 1 | |
| MaintenanceRevision | MaintenanceRevision | 1 | |
| MaintOrdBasicEndDate | PlannedEndDate | 1 | |
| MaintOrdBasicStartDate | PlannedStartDate | 1 | |
| MaintOrderReferenceDate | MaintOrderReferenceDate | 1 | |
| MaintOrdPersonResponsible | MaintOrdPersonResponsible | 1 | |
| MaintPriority | MaintPriority | 1 | |
| MaintPriorityType | MaintPriorityType | 1 | |
| OperationSystemCondition | OperationSystemCondition | 1 | |
| SerialNumber | SerialNumber | 1 | |
| TechnicalObject | TechnicalObject | 1 | |
| TechObjIsEquipOrFuncnlLoc | TechObjIsEquipOrFuncnlLoc | 1 | |
| WorkCenterInternalID | MainWorkCenterInternalID | 1 | |
| WorkCenterTypeCode | WorkCenterTypeCode | 1 |
@EndUserText.label: 'Maintenance Order History w/ Techn. Obj.'
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'IMNTORDHISTECOBJ'
@ObjectModel.representativeKey: 'MaintenanceOrder'
@ObjectModel.semanticKey: [ 'MaintenanceOrder' ]
@ObjectModel.compositionRoot: true
@ObjectModel: {
createEnabled: false,
updateEnabled: false,
deleteEnabled: false
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
// #BASIC View which also incorporates I_TechnicalObject (used for generating BOPF infrastructure)
define view I_MaintOrderHistTechObj
as select from I_MaintenanceOrderHistory
association [0..*] to I_MaintOrderOperTechObj as _MaintenanceOrderOperation on $projection.MaintenanceOrder = _MaintenanceOrderOperation.MaintenanceOrder
association [0..1] to I_TechnicalObject as _TechnicalObject on _TechnicalObject.TechnicalObject = $projection.TechnicalObject
and _TechnicalObject.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
association [0..1] to I_TechObjIsEquipOrFuncnlLoc as _TechObjIsEquipOrFuncnlLoc on _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
association [0..1] to I_Equipment as _Equipment on $projection.Equipment = _Equipment.Equipment
{
@ObjectModel.text.element: [ 'MaintenanceOrderDesc' ]
key I_MaintenanceOrderHistory.MaintenanceOrder,
@ObjectModel.foreignKey.association: '_TechnicalObject'
case when I_MaintenanceOrderHistory._Equipment.Equipment != '' then
cast( I_MaintenanceOrderHistory._Equipment.Equipment as eams_tec_obj )
when I_MaintenanceOrderHistory._Equipment.Equipment = '' and
I_MaintenanceOrderHistory._LocationAccountAssignment.FunctionalLocation != '' then
cast( I_MaintenanceOrderHistory._LocationAccountAssignment.FunctionalLocation as eams_tec_obj )
else cast('' as eams_tec_obj ) end as TechnicalObject,
@ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
case when I_MaintenanceOrderHistory._Equipment.Equipment != '' then
cast ( 'EAMS_EQUI' as eams_tec_obj_type_value)
when I_MaintenanceOrderHistory._Equipment.Equipment = '' and
I_MaintenanceOrderHistory._LocationAccountAssignment.FunctionalLocation != '' then
cast ( 'EAMS_FL' as eams_tec_obj_type_value)
else cast('' as eams_tec_obj_type_value ) end as TechObjIsEquipOrFuncnlLoc,
/* Fields */
I_MaintenanceOrderHistory.CreatedByUser,
I_MaintenanceOrderHistory.CreationDate,
I_MaintenanceOrderHistory.LastChangedByUser,
I_MaintenanceOrderHistory.LastChangeDate,
I_MaintenanceOrderHistory.IsMarkedForDeletion,
I_MaintenanceOrderHistory.MaintPriorityType,
I_MaintenanceOrderHistory.MaintPriority,
I_MaintenanceOrderHistory.MaintenanceProcessingPhase,
I_MaintenanceOrderHistory.MaintObjectLocAcctAssgmtNmbr,
I_MaintenanceOrderHistory.MaintenanceNotification,
I_MaintenanceOrderHistory.LeadingOrder,
I_MaintenanceOrderHistory._Equipment.Equipment as Equipment,
I_MaintenanceOrderHistory.MaintenanceItem,
I_MaintenanceOrderHistory.Assembly,
I_MaintenanceOrderHistory.SerialNumber,
I_MaintenanceOrderHistory.MaintenancePlanningPlant,
I_MaintenanceOrderHistory.MaintenancePlannerGroup,
I_MaintenanceOrderHistory.MaintenanceRevision,
I_MaintenanceOrderHistory.MaintenancePlan,
//TODO: AUFPL is missing in HIKO
//ZI_MaintenanceOrderHistory.MaintOrderRoutingNumber,
I_MaintenanceOrderHistory.MaintenanceOrderType,
I_MaintenanceOrderHistory.MaintenanceOrderCategory,
I_MaintenanceOrderHistory.MaintenanceOrderDesc,
I_MaintenanceOrderHistory.MaintOrdBasicStartDate,
I_MaintenanceOrderHistory.MaintOrdBasicEndDate,
I_MaintenanceOrderHistory.ActualStartDate,
I_MaintenanceOrderHistory.ConfirmedEndDate,
I_MaintenanceOrderHistory.MaintenanceOrderInternalID,
I_MaintenanceOrderHistory.BillOfOperationsType,
I_MaintenanceOrderHistory.BillOfOperations,
I_MaintenanceOrderHistory.BillOfOperationsVariant,
I_MaintenanceOrderHistory.WorkCenterInternalID,
I_MaintenanceOrderHistory.WorkCenterTypeCode,
I_MaintenanceOrderHistory.Plant,
I_MaintenanceOrderHistory._MainWorkCenter.WorkCenter as MaintOrdMainWorkCenter,
I_MaintenanceOrderHistory._MainWorkCenter.Plant as MaintOrdMainWorkCenterPlant,
// I_MaintenanceOrderHistory.MainWorkCenter,
// I_MaintenanceOrderHistory.MainWorkCenterPlant,
I_MaintenanceOrderHistory.BusinessArea,
_MaintenancePartner[1: PartnerFunction = 'VW'].Partner as MaintOrdPersonResponsible,
//_MaintenancePartner[1: PartnerFunction = 'VW'].PartnerName as MaintOrdPersonResponsibleName,
I_MaintenanceOrderHistory.MaintOrderReferenceDate,
I_MaintenanceOrderHistory.MaintenanceOrderPlanningCode,
I_MaintenanceOrderHistory.OperationSystemCondition,
//TODO: ADPSP is missing in HIKO
//I_MaintenanceOrderHistory.ReferenceElement,
I_MaintenanceOrderHistory.MaintenanceActivityType,
/* Fields required by DCL (authorization) */
I_MaintenanceOrderHistory.ControllingArea,
//TODO: KOSTV is missing in HIKO
//I_MaintenanceOrderHistory.ResponsibleCostCenter,
I_MaintenanceOrderHistory._Equipment.AuthorizationGroup,
I_MaintenanceOrderHistory._LocationAccountAssignment.MaintenancePlant,
/* Associations */
_Equipment,
I_MaintenanceOrderHistory._LocationAccountAssignment,
I_MaintenanceOrderHistory._MaintenanceNotification,
I_MaintenanceOrderHistory._MaintenanceOrderCategory,
I_MaintenanceOrderHistory._MaintenanceOrderType,
I_MaintenanceOrderHistory._MaintenanceOrderComponent,
@ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
_MaintenanceOrderOperation,
I_MaintenanceOrderHistory._MaintenanceOrderPhase,
I_MaintenanceOrderHistory._MaintenancePlan,
I_MaintenanceOrderHistory._MaintenancePriority,
I_MaintenanceOrderHistory._MaintenancePriorityType,
//TODO: AUFK and AFKO don't contain data for historical orders
//I_MaintenanceOrderHistory._Order,
I_MaintenanceOrderHistory._StatusObject,
_TechnicalObject,
_TechObjIsEquipOrFuncnlLoc,
_Plant,
_MainWorkCenter,
_BillOfOperationsType,
_BillOfOperationsGroup,
//_WorkCenter,
I_MaintenanceOrderHistory._BusinessArea,
I_MaintenanceOrderHistory._StatusObjectStatus,
I_MaintenanceOrderHistory._MaintenancePlannerGroup,
I_MaintenanceOrderHistory._MaintenancePlanningPlant,
I_MaintenanceOrderHistory._MaintenanceActivityType,
I_MaintenanceOrderHistory._Assembly,
I_MaintenanceOrderHistory._OperationSystemCondition,
I_MaintenanceOrderHistory._MaintenanceItem
}