I_MAINTORDCONFIRMATIONLONGTEXT

CDS View

Maintenance Order Conf Long Text

I_MAINTORDCONFIRMATIONLONGTEXT is a CDS View in S/4HANA. Maintenance Order Conf Long Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_MaintOrderConfLongTextTP view_entity from COMPOSITE Maintenance Order Confirmation Long text 
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Maintenance Order Conf Long Text'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@ObjectModel.representativeKey: 'OrderConfirmation'
define view entity I_MaintOrdConfirmationLongText
  as select from I_TextObjectPlainLongText
    inner join   afru_text on afru_text.tdname = I_TextObjectPlainLongText.TextObjectKey

  association [1..1] to I_MaintenanceOrderConfirmation as _MaintenanceOrderConf on  _MaintenanceOrderConf.MaintOrderConf          = $projection.ConfirmationGroup
                                                                                and _MaintenanceOrderConf.MaintOrderConfCntrValue = $projection.OrderConfirmation
  association [0..1] to I_Language                     as _Language             on  _Language.Language = $projection.Language
{
      @ObjectModel.foreignKey.association: '_MaintenanceOrderConf._ConfirmationGroup'
  key afru_text.rueck                         as ConfirmationGroup,
  key afru_text.rmzhl                         as OrderConfirmation,
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key I_TextObjectPlainLongText.Language,
      afru_text.tdname                        as TextObjectKey,
      I_TextObjectPlainLongText.PlainLongText as PlainLongText,
      I_TextObjectPlainLongText.TextObjectCategory,
      _MaintenanceOrderConf.MaintenanceOrder,
      _Language,
      _MaintenanceOrderConf

}
where
      I_TextObjectPlainLongText.TextObjectCategory = 'AUFK'
  and I_TextObjectPlainLongText.TextObjectType     = 'RMEL'
  and _MaintenanceOrderConf.MaintenanceOrder <> ''

Learn More