I_MAINTOBJLISTINBDELIVITMCOMP

CDS View

Maint Object List in Inb Del Item Comp

I_MAINTOBJLISTINBDELIVITMCOMP is a CDS View in S/4HANA. Maint Object List in Inb Del Item Comp. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_MaintObjectListCollection view_entity union_all COMPOSITE Maintenance Object List Collection 
@AccessControl: { authorizationCheck: #MANDATORY,
                  personalData.blocking: #NOT_REQUIRED }

@VDM.viewType: #BASIC

@ObjectModel.usageType: {
        dataClass:      #TRANSACTIONAL,
        serviceQuality: #A,
        sizeCategory:   #L }
@ObjectModel.supportedCapabilities: [
  #SQL_DATA_SOURCE,
  #CDS_MODELING_DATA_SOURCE,
  #CDS_MODELING_ASSOCIATION_TARGET
]

@EndUserText.label: 'Maint Object List in Inb Del Item Comp'
define view entity I_MaintObjListInbDelivItmComp
  as select from ser11

  association [1..*] to I_MaintenanceObjectListItem as _MaintenanceObjectListItem on  $projection.MaintenanceObjectList = _MaintenanceObjectListItem.MaintenanceObjectList
  association [0..1] to I_DeliveryDocument          as _DeliveryDocument          on  $projection.DeliveryDocument = _DeliveryDocument.DeliveryDocument
  association [0..1] to I_DeliveryDocumentItem      as _DeliveryDocumentItem      on  $projection.DeliveryDocument     = _DeliveryDocumentItem.DeliveryDocument
                                                                                  and $projection.DeliveryDocumentItem = _DeliveryDocumentItem.DeliveryDocumentItem
{

  key obknr     as MaintenanceObjectList,
      @ObjectModel.foreignKey.association: '_DeliveryDocument'
      lief_nr   as DeliveryDocument,
      @ObjectModel.foreignKey.association: '_DeliveryDocumentItem'
      posnr     as DeliveryDocumentItem,
      component as SubcontrgCompOfInbDelivItem,
      datum     as SerialNumberAssignmentDate,
      uzeit     as SerialNumberAssignmentTime,
      anzsn     as NumberOfSerialNumbers,
      vbtyp     as SDDocumentCategory,
      bwart     as GoodsMovementType,

      _MaintenanceObjectListItem,
      _DeliveryDocument,
      _DeliveryDocumentItem
}

Learn More