I_MAINTNOTIFITEMTECHOBJ

CDS View

Maint. Notification Item /w Tech. Obj.

I_MAINTNOTIFITEMTECHOBJ is a CDS View in S/4HANA. Maint. Notification Item /w Tech. Obj.. It contains 10 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 10 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_MaintNotificationItemData view from COMPOSITE Maintenance Notification Item Data
I_MaintNotificationItemTP view from TRANSACTIONAL Maint. Notification Item /w Tech. Obj.

Fields (10)

KeyField CDS FieldsUsed in Views
KEY MaintenanceNotification MaintenanceNotification 1
KEY MaintenanceNotificationItem MaintenanceNotificationItem,MaintNotificationItemForEdit 1
IsDeleted IsDeleted 1
MaintNotifDamageCodeCatalog MaintNotifDamageCodeCatalog 1
MaintNotifDamageCodeGroup MaintNotifDamageCodeGroup 1
MaintNotificationDamageCode MaintNotificationDamageCode 1
MaintNotifItemText MaintNotifItemText 1
MaintNotifObjPrtCode MaintNotifObjPrtCode 1
MaintNotifObjPrtCodeCatalog MaintNotifObjPrtCodeCatalog 1
MaintNotifObjPrtCodeGroup MaintNotifObjPrtCodeGroup 1 
@EndUserText.label: 'Maint. Notification Item /w Tech. Obj.' //same as DDL description

--@Analytics: { dataCategory: #DIMENSION }
@VDM.viewType: #COMPOSITE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AbapCatalog.sqlViewName: 'INOTIFITTECHOBJ'

@ObjectModel.representativeKey: 'MaintenanceNotificationItem'
@ObjectModel.semanticKey:  [ 'MaintenanceNotificationItem','MaintenanceNotification' ]


@ClientHandling.algorithm: #SESSION_VARIABLE 
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L


define view I_MaintNotifItemTechObj
  as select from I_MaintenanceNotificationItem
  association [0..*] to I_MaintNotifCauseTechObj   as _MaintNotifCauseTechObj   on  $projection.MaintenanceNotification     = _MaintNotifCauseTechObj.MaintenanceNotification
                                                                                and $projection.MaintenanceNotificationItem = _MaintNotifCauseTechObj.MaintenanceNotificationItem
  association [1..1] to I_MaintNotificationTechObj as _MaintNotificationTechObj on  $projection.MaintenanceNotification = _MaintNotificationTechObj.MaintenanceNotification
  association [0..1] to I_LinearAssetManagementData as _LinearAssetManagementData on  $projection.ObjectKey = _LinearAssetManagementData.LinearDataObjectKey
                                                                                  and _LinearAssetManagementData.LinearDataObjectType = 'QN'
{

      @ObjectModel.text.element:  [ 'MaintNotifItemText' ]
  key I_MaintenanceNotificationItem.MaintenanceNotificationItem,
      @ObjectModel.foreignKey.association: '_MaintenanceNotification'
  key I_MaintenanceNotificationItem.MaintenanceNotification,

      @Semantics.text: true
      I_MaintenanceNotificationItem.MaintNotifItemText,

      @ObjectModel.foreignKey.association: '_MaintNotifDamageCodeCatalog'
      I_MaintenanceNotificationItem.MaintNotifDamageCodeCatalog,
      @ObjectModel.foreignKey.association: '_MaintNotificationDamageCode'
      I_MaintenanceNotificationItem.MaintNotificationDamageCode,
      @ObjectModel.foreignKey.association: '_MaintNotifDamageCodeGroup'
      I_MaintenanceNotificationItem.MaintNotifDamageCodeGroup,

      @ObjectModel.foreignKey.association: '_MaintNotifObjPrtCode'
      I_MaintenanceNotificationItem.MaintNotifObjPrtCode,
      @ObjectModel.foreignKey.association: '_MaintNotifObjPrtCodeGroup'
      I_MaintenanceNotificationItem.MaintNotifObjPrtCodeGroup,
      @ObjectModel.foreignKey.association: '_MaintNotifObjPrtCodeCatalog'
      I_MaintenanceNotificationItem.MaintNotifObjPrtCodeCatalog,
      
      @ObjectModel.foreignKey.association: '_DefectClass'
      I_MaintenanceNotificationItem.DefectClass,
    
      @ObjectModel.foreignKey.association: '_Assembly'
      I_MaintenanceNotificationItem.Assembly,
      I_MaintenanceNotificationItem.ObjectKey,
            
      I_MaintenanceNotificationItem.NumberOfDefects, 
      I_MaintenanceNotificationItem.LastChangeDateTime,        
      
      @ObjectModel.foreignKey.association: '_IsDeleted'
      I_MaintenanceNotificationItem.IsDeleted,


      /* Associations */
      _MaintNotificationTechObj, // #COMPOSITE Maintenance Notification including Technical Object

      I_MaintenanceNotificationItem._IsDeleted,
      I_MaintenanceNotificationItem._MaintenanceNotification, // #BASIC Maintenance Notification

      _MaintNotifCauseTechObj,
      _LinearAssetManagementData,
      I_MaintenanceNotificationItem._MaintenanceNotificationTask,
      I_MaintenanceNotificationItem._MaintNotifDamageCodeCatalog,
      I_MaintenanceNotificationItem._MaintNotifDamageCodeGroup,
      I_MaintenanceNotificationItem._MaintNotificationActivity,
      I_MaintenanceNotificationItem._MaintNotificationDamageCode,
      I_MaintenanceNotificationItem._MaintNotifObjPrtCode,
      I_MaintenanceNotificationItem._MaintNotifObjPrtCodeCatalog,
      I_MaintenanceNotificationItem._MaintNotifObjPrtCodeGroup,
      I_MaintenanceNotificationItem._Assembly,
      I_MaintenanceNotificationItem._DefectClass
}

Learn More