I_MRPPLANTCONTROLPARAMETER

CDS View

MRP Plant Control Parameters

I_MRPPLANTCONTROLPARAMETER is a CDS View in S/4HANA. MRP Plant Control Parameters. 3 CDS views read from this table.

Used by 3 CDS view(s)

CDS Views using this table (3)

ViewTypeJoinVDMDescription
I_DDHistlBufStkTimeSeries view_entity inner COMPOSITE Stock for Product
P_LastFallBackLeadTime view_entity left_outer CONSUMPTION Demand Driven Product Lead Time From Material Master
P_ProductIndivLeadTime view_entity left_outer COMPOSITE Demand Driven Product Indiv Lead Time 
@AbapCatalog.entityBuffer.definitionAllowed: true
@AccessControl.authorizationCheck: #NOT_REQUIRED
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@Analytics.technicalName: 'IMRPPLNTCTRLPAR'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'MRPPlant'
@ObjectModel.sapObjectNodeType.name: 'Plant'
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_ASSOCIATION_TARGET, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE, #SQL_DATA_SOURCE]
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@EndUserText.label: 'MRP Plant Control Parameters'
// CDS view entity for the plant-based MRP control parameters

// For MRP-group-based control parameters (T438M) refer to I_MRPGroupControlParameter


define view entity I_MRPPlantControlParameter
  as select from t399d

  association [1..1] to I_Plant                as _MRPPlant            on  $projection.MRPPlant = _MRPPlant.Plant
  association [0..1] to I_Plant                as _ReferencePlant      on  $projection.ReferencePlant = _ReferencePlant.Plant  
  association [0..1] to I_MRPController        as _MRPController       on  $projection.MRPPlant      = _MRPController.Plant
                                                                       and $projection.MRPController = _MRPController.MRPController
  association [0..1] to I_MRPPlanningPeriod    as _MRPPlanningCalendar on  $projection.MRPPlant            = _MRPPlanningCalendar.MRPPlant
                                                                       and $projection.MRPPlanningCalendar = _MRPPlanningCalendar.MRPPlanningCalendar  
  association [0..1] to I_OrderType            as _OrderType           on  $projection.OrderType = _OrderType.OrderType
  association [0..1] to I_OrderType            as _ProcessOrderType    on  $projection.ProcessOrderType = _ProcessOrderType.OrderType
{
      // Key

  key cast(werks as werks_d preserving type)   as MRPPlant,

      // Control parameter

--    @ObjectModel.foreignKey.association: '_MRPPlanningCalendar'      
      cast(mrrpp as mrppp  preserving type)    as MRPPlanningCalendar,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_MRPControllerVH', element: 'MRPController' } } ]
      cast(fedis as pph_dispo preserving type) as MRPController,
      cast(cslid as stlid preserving type)     as BOMPrioritizedVersion,
      @ObjectModel.foreignKey.association: '_ReferencePlant'
      cast(refwk as refwk preserving type)     as ReferencePlant,
      @ObjectModel.foreignKey.association: '_OrderType'
      cast(auart as aufart preserving type)    as OrderType,
      @ObjectModel.foreignKey.association: '_ProcessOrderType'      
      cast(auar2 as auar2 preserving type)     as ProcessOrderType,
      cast(umthz as vdm_umthz preserving type) as ReschedulingHorizonInWorkdays,
      cast(plahz as vdm_plahz preserving type) as PlanningHorizonInWorkdays,
      lifkz                                    as ScheduleLinesCreationCode,
      cast(prreg as bmg_prreg preserving type) as ATPCheckingRule,
      kzumb                                    as StkInTransfIsAvailForPlng,
      vertr                                    as StartDateInThePastIsAllowed,
      anzls                                    as PlannedMaterialListIsCreated,
      dbepl                                    as MRPIsActiveForMRPAreasAtPlant,
      xfan1                                    as BlockedStockIsIncludedInMRP,
      cast(nfvbc as vdm_nfvbc preserving type) as RestrictedBatchStockIsIncluded,
      cast(bztek as vdm_bztek preserving type) as PurchasingProcessingDuration,
      
      // Associations

      _MRPPlant,
      _ReferencePlant,
      _MRPController,
      _MRPPlanningCalendar,
      _OrderType,
      _ProcessOrderType
};

Learn More