I_MRPCONTROLLER

CDS View

MRP Controller

I_MRPCONTROLLER is a CDS View in S/4HANA. MRP Controller. It contains 12 fields. 14 CDS views read from this table.

Used by 14 CDS view(s) 12 fields

CDS Views using this table (14)

ViewTypeJoinVDMDescription
/VSCEW/CC_MRPResponsible_VH view_entity from MRP Controller VH
C_MfgOrderObjPgContacts view_entity inner CONSUMPTION Mfg Order Object Page Contacts
C_MM_MRPCtrlrsValueHelp view from CONSUMPTION MRP Controllers Value Help
C_MRPController view_entity from CONSUMPTION MRP Controller
C_ProdnVersMRPControllerVH view from CONSUMPTION MRP Controller
C_ProductMRPControllerVH view from CONSUMPTION Plant MRP Controller Value Help
C_SlsDocFlfmtMfgOrderContacts view inner CONSUMPTION Sales Doc Fulfillment: MFG Order Contacts
I_InventoryMRPControllerVH view_entity from BASIC Inventory MRP Controller
I_MfgOrderMRPControllerStdVH view_entity from COMPOSITE MRP Controller
I_MfgOrderMRPControllerVH view from COMPOSITE MRP Controller Value Help
I_MRPControllerVH view_entity from COMPOSITE MRP Controller
I_ProductionSupplyMRPCtrlrVH view from BASIC MRP Controller
I_ProductMRPControllerVH view from BASIC Product MRP Controller Value Help
P_Plant_Fs view left_outer BASIC Priavte Factsheet - Plant

Fields (12)

KeyField CDS FieldsUsed in Views
KEY MRPController MRPController 8
KEY Plant Plant 8
_BusinessArea _BusinessArea 1
_Plant _Plant 1
_PurchasingGroup _PurchasingGroup 1
_User _User 1
BusinessArea BusinessArea 1
MRPControllerName MRPControllerName 9
MRPControllerPhoneNumber MRPControllerPhoneNumber 6
ProfitCenter ProfitCenter 1
PurchasingGroup PurchasingGroup 1
UserID UserID 5 
@AbapCatalog.sqlViewName: 'IPPMRPCONTROLLER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.buffering: {status: #ACTIVE, type: #GENERIC, numberOfKeyFields: 001}
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.privilegedAssociations: ['_User']
@Analytics.dataCategory: #DIMENSION
@Analytics.dataExtraction.enabled: true
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@Consumption.ranked: true
@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, #CDS_MODELING_DATA_SOURCE, #SQL_DATA_SOURCE, #SEARCHABLE_ENTITY, #EXTRACTION_DATA_SOURCE]
@ObjectModel.representativeKey: 'MRPController'
@ObjectModel.sapObjectNodeType.name: 'MRPController'
@ObjectModel.semanticKey: ['Plant', 'MRPController']
@ObjectModel.usageType: {serviceQuality: #A, sizeCategory: #S, dataClass: #CUSTOMIZING}
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@VDM.viewType: #BASIC
@Search.searchable: true
@EndUserText.label: 'MRP Controller'

/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ]  } */
define view I_MRPController
  as select from t024d as t024d
  association [1..1] to I_Plant            as _Plant            on $projection.Plant = _Plant.Plant
  association [0..1] to I_PurchasingGroup  as _PurchasingGroup  on $projection.PurchasingGroup = _PurchasingGroup.PurchasingGroup
  association [0..1] to I_BusinessArea     as _BusinessArea     on $projection.BusinessArea = _BusinessArea.BusinessArea
  association [0..1] to I_User             as _User             on $projection.UserID = _User.UserID

  association [1..1] to I_Plant            as _PlantText        on $projection.Plant = _PlantText.Plant
  association [0..*] to I_BusinessAreaText as _BusinessAreaText on $projection.BusinessArea = _BusinessAreaText.BusinessArea  
{
      // Key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_PlantStdVH', element: 'Plant' } } ]
      @ObjectModel.foreignKey.association: '_Plant'
      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
  key t024d.werks                                    as Plant,
      @ObjectModel.text.element: ['MRPControllerName']
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
  key cast(t024d.dispo as pph_dispo preserving type) as MRPController,

      // Attributes

      @Search: {defaultSearchElement: true, ranking: #LOW, fuzzinessThreshold: 0.8}
      @Semantics.text: true
      cast(t024d.dsnam as pph_dsnam preserving type) as MRPControllerName,
      cast(t024d.dstel as pph_dstel preserving type) as MRPControllerPhoneNumber,
      @ObjectModel.foreignKey.association: '_PurchasingGroup'   
      t024d.ekgrp                                    as PurchasingGroup,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessAreaStdVH', element: 'BusinessArea' } } ]
      @ObjectModel.foreignKey.association: '_BusinessArea'
      @ObjectModel.text.association: '_BusinessAreaText'
      t024d.gsber                                    as BusinessArea,
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_ProfitCenterStdVH', element: 'ProfitCenter' } } ]
      t024d.prctr                                    as ProfitCenter,
      case t024d.usrtyp
        when 'US'
          then t024d.usrkey
          else ''
      end as UserID,

      // Associations

      _Plant,
      _PurchasingGroup,
      _BusinessArea,
      _User,
      
      // Text relations

      _PlantText,
      _BusinessAreaText
};

Learn More