I_MDCHGPROCESSSTATUSSTATECODE

CDS View

MD Change Process Status State Code

I_MDCHGPROCESSSTATUSSTATECODE is a CDS View in S/4HANA. MD Change Process Status State Code. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
P_MDChangeProcessStatusState view from CONSUMPTION Helper view for process state 
@AbapCatalog.sqlViewName: 'IMDCHGPROCSTATEC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #BASIC
@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, sizeCategory: #M, serviceQuality: #C }
@EndUserText.label: 'MD Change Process Status State Code'
define view I_MDChgProcessStatusStateCode
  as select from I_MasterDataChangeProcess
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] }*/
  association [0..1] to I_MDChgProcessStep        as _CurrentStep     on  _CurrentStep.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
                                                                      and _CurrentStep.MDChgProcessStep            = $projection.MDChgProcessCurrentStepNumber
  association [0..1] to I_MDChangeProcessIsIdle   as _ProcessIsIdle   on  _ProcessIsIdle.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
  association [0..1] to P_MDChangeProcessLastStep as _ProcessLastStep on  _ProcessLastStep.MasterDataChangeProcessUUID = $projection.MasterDataChangeProcessUUID
{
  key MasterDataChangeProcessUUID,
      MDChgProcessSrceObjectTypeCode,
      MasterDataChangeProcess,
      MDChgProcessCurrentStepNumber,
      MDChgProcessStatus,
      MDChgProcessChkPointIsActive,
      @ObjectModel.readOnly: true
      cast(   case when MDChgProcessIsErased = 'X' then '014'
                   when MDChgProcessStatus = 'S' then '006'
                   when MDChgProcessStatus = 'F' then '005'
                   when MDChgProcessStatus = 'P' then '013'
                   when MDChgProcessStatus = 'R' then '011'
                   when MDChgProcessStatus = 'W' then '012'
                   else
                   case when _CurrentStep.MDChgProcessStepStatus = '4'
                        then case when MDChgProcessChkPointIsActive is not initial then '001'
                                  when MDChgProcessCurrentStepNumber = _ProcessLastStep.MDChgProcessLastStepNumber then '010'
                                  else '008'
                             end
                        when _CurrentStep.MDChgProcessStepStatus = '1' then '002'
                        when _CurrentStep.MDChgProcessStepStatus = '2' then '003'
                        when _CurrentStep.MDChgProcessStepStatus = '3' then '004'
                        when _CurrentStep.MDChgProcessStepStatus = '5' then '007'
                        else case when _ProcessIsIdle.MDChgProcessIsIdle is initial
                                       and MDChgProcessCurrentStepNumber is initial then '009'
                                  when MDChgProcessChkPointIsActive is not initial then '001'
                                  else '008'
                             end
                   end
              end as mdc_process_status_state_code
      )                              as MDChgProcessStatusStateCode,
      MDChgProcessTypeID,
      MDChgProcessGoal
}

Learn More