I_MDCHGPROCTEMPLATESTEPUNION

CDS View

MD Change Process Template Step Union

I_MDCHGPROCTEMPLATESTEPUNION is a CDS View in S/4HANA. MD Change Process Template Step Union. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_MDChangeProcessTemplateStep view_entity from MD Chg Proc Template Step 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'MD Change Process Template Step Union'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
  serviceQuality: #X,
  sizeCategory: #S,
  dataClass: #MIXED
}
define view entity I_MDChgProcTemplateStepUnion
  as select from I_MDChgProcTmplStepRAPBsdExtd as _RAPBasedExtended
    inner join   I_MDChangeProcessTypeUnion    as _Type on _RAPBasedExtended.MDChgProcessTypeID = _Type.MDChgProcessTypeID
  association [1..1] to I_MDChangeProcessTypeUnion as _MDChgProcessType on $projection.MDChgProcessTypeID = _MDChgProcessType.MDChgProcessTypeID
{
  key _RAPBasedExtended.MDChgProcessTypeID,
  key _RAPBasedExtended.MDChgProcessStep,
      _RAPBasedExtended.MDChgProcessStepSequenceValue,
      _RAPBasedExtended.MDChgProcessTypeStepDesc,
      _RAPBasedExtended.MDChgProcessStepAdapterDesc,
      _RAPBasedExtended.MDChgProcessStepAdapterConfign,
      _RAPBasedExtended.MDChgProcessStepChkPointIsActv,
      _RAPBasedExtended.MDChgProcessStepActionControl,
      _RAPBasedExtended.MDChgProcessSrceObjectTypeCode,
      _RAPBasedExtended.MDChgProcessStepAuthznGroup,
      _MDChgProcessType
}
union select from         I_MDChgProcTmplStepRAPBased   as _RAPBased
  inner join              I_MDChangeProcessTypeUnion    as _Type             on _RAPBased.MDChgProcessTypeID = _Type.MDChgProcessTypeID
  left outer to many join I_MDChgProcTmplStepRAPBsdExtd as _RAPBasedExtended on _RAPBasedExtended.MDChgProcessTypeID = _Type.MDChgProcessTypeID
association [1..1] to I_MDChangeProcessTypeUnion as _MDChgProcessType on $projection.MDChgProcessTypeID = _MDChgProcessType.MDChgProcessTypeID
{
  key _RAPBased.MDChgProcessTypeID,
  key _RAPBased.MDChgProcessStep,
      _RAPBased.MDChgProcessStepSequenceValue,
      _RAPBased.MDChgProcessTypeStepDesc,
      _RAPBased.MDChgProcessStepAdapterDesc,
      _RAPBased.MDChgProcessStepAdapterConfign,
      _RAPBased.MDChgProcessStepChkPointIsActv,
      _RAPBased.MDChgProcessStepActionControl,
      _RAPBased.MDChgProcessSrceObjectTypeCode,
      _RAPBased.MDChgProcessStepAuthznGroup,
      _MDChgProcessType
}
where
  _RAPBasedExtended.MDChgProcessTypeID is null

union select from        I_MDChangeProcessTemplateStep as _Classic
  inner join             I_MDChangeProcessTypeUnion    as _Type             on _Classic.MDChgProcessTypeID = _Type.MDChgProcessTypeID
  left outer to one join I_MDChgProcTmplStepRAPBsdExtd as _RAPBasedExtended on _Classic.MDChgProcessTypeID = _RAPBasedExtended.MDChgProcessTypeID
  left outer to one join I_MDChgProcTmplStepRAPBased   as _RAPBased         on _Classic.MDChgProcessTypeID = _RAPBased.MDChgProcessTypeID
association [1..1] to I_MDChangeProcessTypeUnion as _MDChgProcessType on $projection.MDChgProcessTypeID = _MDChgProcessType.MDChgProcessTypeID
{
  key _Classic.MDChgProcessTypeID,
  key _Classic.MDChgProcessStep,
      _Classic.MDChgProcessStepSequenceValue,
      _Classic.MDChgProcessTypeStepDesc,
      _Classic.MDChgProcessStepAdapterDesc,
      _Classic.MDChgProcessStepAdapterConfign,
      _Classic.MDChgProcessStepChkPointIsActv,
      _Classic.MDChgProcessStepActionControl,
      _Classic.MDChgProcessSrceObjectTypeCode,
      _Classic.MDChgProcessStepAuthznGroup,
      _MDChgProcessType
}
where
      _RAPBasedExtended.MDChgProcessTypeID is null
  and _RAPBased.MDChgProcessTypeID         is null

Learn More