I_LOCATIONBASIC
Location
I_LOCATIONBASIC is a CDS View in S/4HANA. Location. It contains 17 fields. 16 CDS views read from this table.
CDS Views using this table (16)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| /SCMTMS/VE_LOCAD | view_entity | from | BOPF: Location Selected Address Details | |
| /SCMTMS/VE_LOCAI | view_entity | from | BOPF: Location Alternative ID | |
| /SCMTMS/VE_LocQuByPhysAdd | view_entity | from | BOPF: Location Query By Physical Address | |
| /SCMTMS/VE_LOCRT | view_entity | from | BOPF: Location Root | |
| /SCMTMS/VE_LocTimeInfShipFr | view_entity | from | BOPF: Helper for Locatn. Outb. Time Inf. | |
| /SCMTMS/VE_LocTimeInfShipTo | view_entity | from | BOPF: Helper for Locatn. Inb. Time Inf. | |
| C_LoadingPointVH | view | from | CONSUMPTION | Loading Point |
| I_LocationAddressVH | view | from | COMPOSITE | Location Value help with Address Attributes |
| I_LocationAnalytics | view | from | COMPOSITE | Location |
| I_LocationBasicStdVH | view | from | COMPOSITE | Location |
| I_LocationValueHelp | view | from | COMPOSITE | Location |
| I_TransportationLocation | view | from | COMPOSITE | Transportation Location |
| R_LocationAddressTP | view_entity | from | TRANSACTIONAL | Location Address |
| R_LocationTP | view_entity | from | TRANSACTIONAL | Transactional Processing View for Location |
| R_TrOrdStopLocAddrAddlRprstnTP | view_entity | inner | TRANSACTIONAL | Transp Ord Stop Loc Addr Addl Rpn - TP |
| R_TrOrdStopLocAddrDfltRprstnTP | view_entity | inner | TRANSACTIONAL | Transp Ord Stop Loc Addr Dflt Rpn - TP |
Fields (17)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | Location | LoadingPointForDelivery,loc_id002,loc_id002_i,location_id | 5 |
| KEY | LocationUUID | locationGUID22,LocationUUID | 2 |
| _BusinessPartner | _BusinessPartner | 1 | |
| _CollaborationPartner | _CollaborationPartner | 1 | |
| _Text | _Text | 1 | |
| AddressID | AddressID | 1 | |
| AuthorizationGroup | AuthorizationGroup | 6 | |
| BusinessPartnerUUID | BusinessPartnerUUID | 1 | |
| CollaborationPartner | CollaborationPartner | 1 | |
| InboundCalendarResourceUUID | uuid015_c22 | 1 | |
| IsBusinessPurposeCompleted | IsBusinessPurposeCompleted | 6 | |
| LocationAdditionalUUID | location_uuid,locationGUID16 | 2 | |
| LocationIATACode | iatacode | 1 | |
| LocationType | location_type_code,LocationType | 3 | |
| LocationUNCode | unlocode | 1 | |
| OutboundCalendarResourceUUID | uuid015_c22 | 1 | |
| ResourceValidity | resctrl_optcd | 2 |
@AbapCatalog.sqlViewName: 'ILOCATIONBASIC'
@ObjectModel: {representativeKey: 'LocationUUID',
semanticKey: [ 'Location' ]}
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.personalData.blockingIndicator: [ 'IsBusinessPurposeCompleted', '_BusinessPartner.IsBusinessPurposeCompleted', '_CollaborationPartner.IsBusinessPurposeCompleted' ]
@AccessControl.privilegedAssociations: [ '_AddrDfltRprstn' , '_AddrAddlRprstn' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
@VDM.lifecycle.contract.type: #NONE
@VDM.viewType: #BASIC
@EndUserText.label: 'Location'
// value help for this view:
// I_LocationBasicStdVH
define view I_LocationBasic
as select from /sapapo/loc
/* Business Object related Node Associations*/
association [0..1] to I_BusinessPartner as _CollaborationPartner on $projection.CollaborationPartner = _CollaborationPartner.BusinessPartner
association [0..1] to I_AddressDefaultRepresentation as _AddrDfltRprstn on $projection.AddressID = _AddrDfltRprstn.AddressID
association [0..*] to I_Address_2 as _AddrAddlRprstn on $projection.AddressID = _AddrAddlRprstn.AddressID
and _AddrAddlRprstn.AddressRepresentationCode is not initial
/* For given join condition, association cardinality is 0 to 1 only, so hinding cardinality warning message */
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
association [0..1] to I_AddrOrgNamePostalAddress as _PostalAddrDfltRprstn on $projection.AddressID = _PostalAddrDfltRprstn.AddressID
and _PostalAddrDfltRprstn.AddressRepresentationCode is initial
/* we use the view I_TMBusinessPartnerByIntKey instead of I_BusinessPartner here, because we have to resolve the asssociation
via the BusinessPartnerUUID, which is not a key field in I_BusinessPartner */
/*+[hideWarning] { "IDS" : [ "CARDINALITY_CHECK" ] } */
association [0..1] to I_BusinessPartner as _BusinessPartner on $projection.BusinessPartnerUUID = _BusinessPartner.BusinessPartnerUUID
/* Foreign Key and Text Associations */
association [0..*] to I_LocationText as _Text on $projection.LocationUUID = _Text.LocationUUID
/*+[hideWarning] { "IDS" : [ "CALCULATED_FIELD_CHECK" ] } */
association [0..1] to I_LocationType_2 as _LocationType on $projection.LocationType = _LocationType.LocationType
association [1..1] to P_LocationAuthGroupEval as _LocationAuthGroupEval on $projection.LocationUUID = _LocationAuthGroupEval.LocationUUID
{
/* @ObjectModel.text.association: '_Text' ---This annotation is no longer supported in RAP*/
key cast( locid as /sapapo/location_id preserving type ) as LocationUUID,
locno as Location,
@ObjectModel.foreignKey.association: '_LocationType'
loctype as LocationType,
cast( loc_uuid as /sapapo/location_uuid preserving type ) as LocationAdditionalUUID,
unlocode as LocationUNCode,
iatacode as LocationIATACode,
tzone as LocationTimeZone,
osta_flag as LocationIsTemporary,
@ObjectModel.foreignKey.association: '_AddrDfltRprstn'
adrnummer as AddressID,
locprio as LocationProcessingPriority,
@ObjectModel.foreignKey.association: '_CollaborationPartner'
cast( partner as /sapapo/collaboration_partner preserving type ) as CollaborationPartner,
partner_guid as BusinessPartnerUUID,
trailer_handling as LocationTrailerHandling,
locloadprofile as LocationLoadingProfile,
attequiprofile as AttachedEquipmentProfile,
shipper_sec_sts as HandoverPartySecurityStatus,
shipper_code as HandoverParty,
shipper_validity as HandoverPartyExpiryDate,
@Semantics.geoLocation.longitude: true
@DefaultAggregation: #MIN
xpos as Longitude,
@Semantics.geoLocation.latitude: true
@DefaultAggregation: #MIN
ypos as Latitude,
@Semantics.dateTime:true
cast( geo_validity_end as tzntstmps preserving type ) as GeoCoordsValidityEndDateTime,
gc_level as GeoCoordinatesLevel,
strategy as GeoCoordinatesStrategy,
match_gc as GeoCoordinatesMatchPercent,
srcid as GeoCoordinatesDataSource,
gis_zone as GeogrlInformationSystemZone,
precisid as GeoCoordinatesPrecision,
manually_changed_gc as GeoCoordsAreManuallyChanged,
locally_changed_gc as GeoCoordsAreLocallyChanged,
cast( createutc as tzntstmpl ) as CreationDateTime,
createuser as CreatedByUser,
cast( changeutc as tzntstmps ) as ChangedDateTime,
changeuser as LastChangedByUser,
lvorm as LocationIsMarkedForDeletion,
cast( tpres_inb as /sapapo/tpres_inb preserving type ) as InboundLoadingResourceUUID,
cast( tpres_out as /sapapo/tpres_out preserving type ) as OutboundLoadingResourceUUID,
resflag as ResourceValidity,
cast( time_res as /sapapo/time_res_inb preserving type ) as InboundCalendarResourceUUID,
cast( time_res_out as /sapapo/time_res_out preserving type ) as OutboundCalendarResourceUUID,
gln as GlobalLocationNumber,
duns4 as LocationDUNSNumber,
dpcal as SrvcPartsPlanningCalendar,
capparm as NumberOfSTOSendingLocation,
capparm_rcv as NumberOfSTOReceivingLocation,
lgrad as TargetServiceLevelRatio,
bntyp as LocationIsContractPackager,
distr as LocationDeliveryIsSpecial,
loc_xblck as IsBusinessPurposeCompleted,
adv_shp_recv_rlv as LocationAdvncdShipgRcvgRlvnce,
_LocationAuthGroupEval.AuthorizationGroup,
/* Associations */
_AddrDfltRprstn,
_AddrAddlRprstn,
_PostalAddrDfltRprstn,
_CollaborationPartner,
_BusinessPartner,
_LocationType,
_Text
}