I_LEGALTRANSACTIONENTITY

CDS View

Basic View for LCM Legal Transaction Entity

I_LEGALTRANSACTIONENTITY is a CDS View in S/4HANA. Basic View for LCM Legal Transaction Entity. It contains 12 fields. 7 CDS views read from this table.

Used by 7 CDS view(s) 12 fields

CDS Views using this table (7)

ViewTypeJoinVDMDescription
C_LegalTransactionEntity view from CONSUMPTION Legal Transaction Entity (Draft disabled)
I_LegalTransactionEntityMain view from COMPOSITE Composite View for LCM Legal Transaction Entity Main
I_LegalTransactionEntityTP view from TRANSACTIONAL TP View for LCM Legal Transaction Entity
I_LegalTrEntityAggr view from COMPOSITE Aggregation for Legal Transaction Entity
I_LglTransEntityAPI01 view from COMPOSITE Entities of Legal Transaction
P_LegalTrMainEntityAggr view from COMPOSITE Aggreagation View For Legal Transaction main Entity
R_LegalTransEntityTP view_entity from TRANSACTIONAL Legal Transaction Entities

Fields (12)

KeyField CDS FieldsUsed in Views
KEY LegalTransactionEntityUUID LegalTransactionEntityUUID 1
_BusinessPartner _BusinessPartner 1
_Customer _Customer 1
_LegalTransaction _LegalTransaction 1
_Supplier _Supplier 1
LegalTransactionMandatoryFlag LegalTransactionMandatoryFlag 1
LegalTransactionUUID LegalTransactionUUID 3
LglCntntMEntity LglCntntMEntity 1
LglCntntMEntityType LglCntntMEntityType 2
LglCntntMIsMainEntity LglCntntMIsMainEntity 1
LglCntntMRank LglCntntMRank 2
LglCntntMTechEntityType LglCntntMTechEntityType 1 
@AbapCatalog.sqlViewName: 'ILEGALTRENTITY'
@AbapCatalog.compiler.compareFilter:true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ClientHandling.type: #CLIENT_DEPENDENT
@AccessControl.authorizationCheck:#CHECK
@VDM.viewType : #BASIC
@Metadata.ignorePropagatedAnnotations: true

@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel: {
  representativeKey: 'LEGALTRANSACTIONENTITYUUID',
  usageType.serviceQuality: #A,
  usageType.sizeCategory: #L,
  usageType.dataClass: #TRANSACTIONAL
}
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@AbapCatalog.preserveKey:true

@EndUserText.label: 'Basic View for LCM Legal Transaction Entity'

define view I_LegalTransactionEntity
  as select from lcm_lt_entity

  association [1..1] to I_LegalTransaction       as _LegalTransaction       on  $projection.LegalTransactionUUID = _LegalTransaction.LegalTransactionUUID

  // ESH association

  // Annotation to customizing

  association [0..1] to I_LCMEntityTypeText      as _EntityTypeText         on  $projection.LglCntntMEntityType = _EntityTypeText.LglCntntMEntityType
                                                                            and _EntityTypeText.Language        = $session.system_language

  association [0..1] to I_PurchasingOrganization as _PurchasingOrganization on  _PurchasingOrganization.PurchasingOrganization = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType            = '05'

  association [0..1] to I_Supplier               as _Supplier               on  _Supplier.Supplier                  = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '01'

  association [0..1] to I_SalesOrganizationText  as _SalesOrganizationText  on  _SalesOrganizationText.SalesOrganization = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType      = '04'
                                                                            and _SalesOrganizationText.Language          = $session.system_language

  association [0..1] to I_Customer               as _Customer               on  _Customer.Customer                  = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '02'

  association [0..1] to I_CompanyCode            as _CompanyCode            on  _CompanyCode.CompanyCode            = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '03'

  association [0..1] to I_BusinessPartner        as _BusinessPartner        on  _BusinessPartner.BusinessPartner    = $projection.LglCntntMEntity
                                                                            and $projection.LglCntntMTechEntityType = '06'

{
  key lcm_lt_entity.legaltransactionentityuuid    as LegalTransactionEntityUUID,
      lcm_lt_entity.lglcntntmrank                 as LglCntntMRank,
      lcm_lt_entity.lglcntntmentity               as LglCntntMEntity,
      lcm_lt_entity.lglcntntmentitytype           as LglCntntMEntityType,
      _EntityTypeText.LglCntntMEntityTypeName     as LglCntntMEntityTypeName,
      lcm_lt_entity.lglcntntmtechentitytype       as LglCntntMTechEntityType,
      lcm_lt_entity.legaltransactionuuid          as LegalTransactionUUID,
      lcm_lt_entity.legaltransactionmandatoryflag as LegalTransactionMandatoryFlag,
      lcm_lt_entity.lglcntntmismainentity         as LglCntntMIsMainEntity,
      lcm_lt_entity.lglcntntmisintegrelevant      as LglCntntMIsIntegRelevant,
      @Semantics.booleanIndicator: true
      lcm_lt_entity.lglcntntmisaddedbyintegvarbl  as LglCntntMIsAddedByIntegVarbl,

      //Authorization

      _LegalTransaction,

      // _EntityType,

      _EntityTypeText,
      _PurchasingOrganization,
      _Supplier,
      _SalesOrganizationText,
      _Customer,
      _CompanyCode,
      _BusinessPartner

}

Learn More