I_INVOICELISTITEM

CDS View

Invoice List Item

I_INVOICELISTITEM is a CDS View in S/4HANA. Invoice List Item. It contains 12 fields. 7 CDS views read from this table.

Used by 7 CDS view(s) 12 fields

CDS Views using this table (7)

ViewTypeJoinVDMDescription
C_InvoiceListItemObjPg view from CONSUMPTION Invoice List Item
I_InvoiceListRemuneration view_entity from COMPOSITE Invoice List Remuneration
I_PT_SAFTBillgInvcListItem view_entity inner COMPOSITE Invoice List Document Item
I_PT_SAFTBillgInvcListTaxDP view_entity inner COMPOSITE Invoice List Item Tax Information Pre
I_PT_SAFTTaxLikeMatInvcList view_entity inner COMPOSITE Tax Like Material Item from Invoice List
P_PT_SAFTBILLINGINVCLISTTAX view_entity inner COMPOSITE Invoice List Item Tax Information Pre
P_SAFT_BillDocOnInvoiceList view from COMPOSITE SAF-T Billing Document On Invoice List

Fields (12)

KeyField CDS FieldsUsed in Views
KEY BillingDocument BillingDocument 4
KEY InvoiceList InvoiceList 3
KEY InvoiceListItem InvoiceListItem 2
_BillingDocument _BillingDocument 1
_SoldToParty _SoldToParty 1
GrossAmount GrossAmount 1
NetAmount NetAmount 2
RemunerationNetAmount RemunerationNetAmount 2
RemunerationTaxAmount RemunerationTaxAmount 1
SoldToParty SoldToParty 1
TaxAmount TaxAmount 1
TransactionCurrency TransactionCurrency 2 
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')

@Analytics.dataCategory: #DIMENSION

@Analytics.dataExtraction: { enabled: true,
                             delta.changeDataCapture.mapping: [ { table: 'vbrl',
                                                                  role: #MAIN,
                                                                  viewElement: [ 'InvoiceList', 'InvoiceListItem' ],
                                                                  tableElement: [ 'vbeln', 'posnr' ] } ] }

@Analytics.internalName: #LOCAL
@Analytics.technicalName: 'ISDINVOICELISTIT'

@EndUserText.label: 'Invoice List Item'

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.representativeKey: 'InvoiceListItem'
@ObjectModel.sapObjectNodeType.name: 'InvoiceListItem'

@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #CDS_MODELING_DATA_SOURCE,
                                      #CDS_MODELING_ASSOCIATION_TARGET,
                                      #SQL_DATA_SOURCE,
                                      #EXTRACTION_DATA_SOURCE ]

@ObjectModel.usageType: { dataClass: #TRANSACTIONAL, serviceQuality: #A, sizeCategory: #L }

@VDM.viewType: #BASIC

define view entity I_InvoiceListItem
  as select from vbrl

  /* start suppress warning calculated_field_check */
  association [1..1] to I_InvoiceList     as _InvoiceList         on $projection.InvoiceList = _InvoiceList.InvoiceList
  /* end suppress warning calculated_field_check */

  association [0..1] to I_BillingDocument as _BillingDocument     on $projection.BillingDocument = _BillingDocument.BillingDocument

  association [0..1] to I_Currency        as _TransactionCurrency on $projection.TransactionCurrency = _TransactionCurrency.Currency
  association [0..1] to I_Customer        as _SoldToParty         on $projection.SoldToParty = _SoldToParty.Customer
  association [0..1] to I_LogicalSystem   as _LogicalSystem       on $projection.LogicalSystem = _LogicalSystem.LogicalSystem

{
      // Key

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_InvoiceListStdVH', element: 'InvoiceList' } } ]
      @ObjectModel.foreignKey.association: '_InvoiceList'
  key vbeln                                                   as InvoiceList,

  key posnr                                                   as InvoiceListItem,

      // Billing

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BillingDocumentStdVH', element: 'BillingDocument' } } ]
      @ObjectModel.foreignKey.association: '_BillingDocument'
      vbeln_vf                                                as BillingDocument,

      // Pricing

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      netwr                                                   as NetAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      mwsbp                                                   as TaxAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast(netwr + mwsbp + kwert_rl + mwsbp_rl as brtwert_rl) as GrossAmount,


      @Semantics.amount.currencyCode: 'TransactionCurrency'
      kwert_rl                                                as RemunerationNetAmount,

      @Semantics.amount.currencyCode: 'TransactionCurrency'
      mwsbp_rl                                                as RemunerationTaxAmount,

      @ObjectModel.foreignKey.association: '_TransactionCurrency'
      _BillingDocument.TransactionCurrency                    as TransactionCurrency,

      uvprs                                                   as PricingIsIncomplete,

      // Sales

      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_Customer_VH', element: 'Customer' } } ]
      @ObjectModel.foreignKey.association: '_SoldToParty'
      kunag                                                   as SoldToParty,

      // Admin

      @ObjectModel.foreignKey.association: '_LogicalSystem'
      logsys                                                  as LogicalSystem,

      // Association

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _InvoiceList,

      _BillingDocument,
      _TransactionCurrency,
      _SoldToParty,
      _LogicalSystem
}

Learn More