I_INSURANCEPOLICYCLAUSETYPET

CDS View

Clause Type in Insurance Policy - Text

I_INSURANCEPOLICYCLAUSETYPET is a CDS View in S/4HANA. Clause Type in Insurance Policy - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InsurPolicyClauseTypeLinkT view_entity from BASIC Insurance Policy Clause Type Link - Text 
@EndUserText.label: 'Clause Type in Insurance Policy - Text'
@ObjectModel:{
    representativeKey: 'InsurPlcyClauseType',
    dataCategory: #TEXT,
    usageType: {
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
    },
    modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
    supportedCapabilities: [
                            #LANGUAGE_DEPENDENT_TEXT,
                            #CDS_MODELING_DATA_SOURCE,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #SQL_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #SEARCHABLE_ENTITY
                           ]
}
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck:#NOT_REQUIRED
@Analytics.dataExtraction.enabled: true
@Analytics.technicalName: 'IPClsTypeT'
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true

define view entity I_InsurancePolicyClauseTypeT
  as select from /pm0/abucibctcha as Characteristics
    inner join   /pm0/abupclauset on  /pm0/abupclauset.list_id       = Characteristics.list_id
                                  and Characteristics.application_id = 'POLICY'
                                  and Characteristics.state_cd       = '3' // Released

                                  and Characteristics.markname       = 'CLAUSE_CD'

  association        to parent I_InsurancePolicyClauseType as _InsurancePolicyClauseType on  $projection.InsurPlcyClauseType         = _InsurancePolicyClauseType.InsurPlcyClauseType
                                                                                         and $projection.InsurPlcyTemplateCharcsList = _InsurancePolicyClauseType.InsurPlcyTemplateCharcsList
                                                                                         and $projection.InsurPlcyClauseTemplate     = _InsurancePolicyClauseType.InsurPlcyClauseTemplate
  association [0..1] to I_InsurPlcyTemplate                as _InsurPlcyTemplate         on  $projection.InsurPlcyClauseTemplate = _InsurPlcyTemplate.InsurPlcyTemplate
  association [0..1] to I_Language                         as _Language                  on  $projection.Language = _Language.Language
  association [0..1] to I_InsurPlcyClauseTypeList          as _InsurPlcyClauseTypeList   on  $projection.InsurPlcyTemplateCharcsList = _InsurPlcyClauseTypeList.InsurPlcyTemplateCharcsList

{

      @Semantics.language: true
      @ObjectModel.foreignKey.association: '_Language'
  key /pm0/abupclauset.langu      as Language,
      @ObjectModel.foreignKey.association: '_InsurancePolicyClauseType'
      @ObjectModel.text.element: ['InsurPlcyClauseTypeName']
  key /pm0/abupclauset.clause_cd  as InsurPlcyClauseType,
      @ObjectModel.foreignKey.association: '_InsurPlcyClauseTypeList'
  key /pm0/abupclauset.list_id    as InsurPlcyTemplateCharcsList,
      @ObjectModel.foreignKey.association: '_InsurPlcyTemplate'
  key Characteristics.template_id as InsurPlcyClauseTemplate,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      /pm0/abupclauset.clause_tt  as InsurPlcyClauseTypeName,

      //Associations

      _InsurancePolicyClauseType,
      _InsurPlcyClauseTypeList,
      _InsurPlcyTemplate,
      _Language

}

Learn More