I_INSURANCEPOLICYCHARGETYPET

CDS View

Charge Type in Insurance Policy - Text

I_INSURANCEPOLICYCHARGETYPET is a CDS View in S/4HANA. Charge Type in Insurance Policy - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_InsurancePolicyChargeTypeT view_entity projection CONSUMPTION Charge Type in Insurance Policy-Text 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Charge Type in Insurance Policy - Text'
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@Analytics.dataExtraction.enabled: true
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel: {
  dataCategory: #TEXT,
  modelingPattern: #LANGUAGE_DEPENDENT_TEXT,
  representativeKey: 'InsurPlcyChrgsPyrChargeType',
  usageType.serviceQuality: #A,
  usageType.dataClass: #CUSTOMIZING,
  usageType.sizeCategory: #S,
  supportedCapabilities: [#CDS_MODELING_ASSOCIATION_TARGET,
                          #CDS_MODELING_DATA_SOURCE,
                          #EXTRACTION_DATA_SOURCE,
                          #LANGUAGE_DEPENDENT_TEXT,
                          #SEARCHABLE_ENTITY,
                          #SQL_DATA_SOURCE]
}
@Search.searchable: true

define view entity I_InsurancePolicyChargeTypeT
  as select from dd07t
  association        to parent I_InsurancePolicyChargeType as _InsurPlcyChargeType on $projection.InsurPlcyChrgsPyrChargeType = _InsurPlcyChargeType.InsurPlcyChrgsPyrChargeType
  association [0..1] to I_Language                         as _Language            on $projection.Language = _Language.Language
{
      @ObjectModel.foreignKey.association: '_Language'
      @Semantics.language: true
  key cast( dd07t.ddlanguage as spras preserving type )  as Language,
      @ObjectModel.foreignKey.association: '_InsurPlcyChargeType'
      @ObjectModel.text.element: ['InsurPlcyChrgsPyrChrgTypeName']
  key cast( dd07t.domvalue_l as /pm0/abd_chargecat_cd ) as InsurPlcyChrgsPyrChargeType,
      @Analytics.hidden: true
      @Consumption.hidden: true
      dd07t.domvalue_l                                   as DomainValue,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #LOW
      @Semantics.text: true
      dd07t.ddtext                                       as InsurPlcyChrgsPyrChrgTypeName,
      _InsurPlcyChargeType,
      _Language
}
where
      dd07t.domname  = '/PM0/ABD_CHARGECAT_CD'
  and dd07t.as4local = 'A'
  and dd07t.as4vers  = '0000'

Learn More