I_INSURPLCYLIMITBASIC

@EndUserText.label: 'Limit in Insurance Policy'
@VDM: {
  viewType: #BASIC,
  lifecycle.contract.type: #SAP_INTERNAL_API
}
@AccessControl: {
  authorizationCheck: #PRIVILEGED_ONLY,
  personalData.blocking: #('TRANSACTIONAL_DATA')
}
@ObjectModel: {
   representativeKey: 'InsurPlcyLimitID',
   semanticKey: [ 'InsurPlcyLimitID' ],
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #XL
   },
   supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE ]
}
@Analytics: {
  technicalName: 'IPLimitBsc'
}

define view entity I_InsurPlcyLimitBasic
  as select from /pm0/abdalimit as Limit

  association [1..1] to I_Currency as _Currency on $projection.InsurPlcyLimitCurrency = _Currency.Currency

{

  key cast( Limit.policy_id as /pm0/vdm_policy_uuid preserving type )          as InsurPlcyUUID,
  key Limit.policyproduct_id                                                   as InsurPlcyInsurContr,
  key cast( Limit.journalno_id as /pm0/vdm_journal_number_id preserving type ) as InsurPlcyJrnlNmbr,
  key Limit.journalendno_id                                                    as InsurPlcyJrnlEndNmbr,
  key Limit.covpac_id                                                          as InsurPlcyCoveragePackageID,
  key Limit.coverage_id                                                        as InsurPlcyCoverageID,
  key Limit.covcpco_id                                                         as InsurPlcySubCvrgID,
  key Limit.limit_id                                                           as InsurPlcyLimitID,
      Limit.ppdpac_id                                                          as InsurPlcyProductPackageID,
      @Semantics.booleanIndicator: true
      Limit.cancel_fg                                                          as InsurPlcyLimitIsCanceled,
      Limit.pm_id                                                              as InsurPlcyLimitTemplate,
      Limit.limittype_cd                                                       as InsurPlcyLimitLimitCategory,
      Limit.reference_cd                                                       as InsurPlcyLmtRefValForRltvLmt,
      @Semantics.amount.currencyCode: 'InsurPlcyLimitCurrency'
      Limit.limit_am                                                           as InsurPlcyLimitAmount,
      Limit.limit_vl                                                           as InsurPlcyLimitRltvAmtInPct,
      @Semantics.amount.currencyCode: 'InsurPlcyLimitCurrency'
      Limit.maxlimit_am                                                        as InsurPlcyLimitAbsltMaxRltvAmt,
      @Semantics.booleanIndicator: true
      Limit.pml_fg                                                             as InsurPlcyLimitIsPMLEffctvn,
      @ObjectModel.foreignKey.association: '_Currency'
      Limit.currency_id                                                        as InsurPlcyLimitCurrency,
      Limit.limitamdef_cd                                                      as InsurPlcyLimitEntrDetnOfLmt,
      Limit.limitkft_tt                                                        as InsurPlcyLimitShortText,
      Limit.limitft_tt                                                         as InsurPlcyLimitFreeText,
      @Semantics.booleanIndicator: true
      Limit.def_mp_drv_fg                                                      as InsurPlcyLimitDrvtnIsDefaulted,
      @Consumption.hidden: true
      Limit.bo_cd                                                              as InsurPlcyBusinessObject,
      @Semantics.systemDateTime.lastChangedAt: true
      Limit.change_ts                                                          as LastChangeDateTime,
      
      _Currency

}