I_INSURPLCYEXTPREMIUMLEVEL

CDS View

Ext Premium Level in Plcy

I_INSURPLCYEXTPREMIUMLEVEL is a CDS View in S/4HANA. Ext Premium Level in Plcy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InsurPlcyExtPremiumLevelLink view_entity from BASIC Link to Ext Premium Level in Plcy 
@EndUserText.label: 'Ext Premium Level in Plcy'
@ObjectModel:{
    representativeKey: 'InsurPlcyExtPremiumLevel',
    usageType: {
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
    },
    modelingPattern: #ANALYTICAL_DIMENSION,
    resultSet.sizeCategory: #XS,
    supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #SEARCHABLE_ENTITY,
                            #SQL_DATA_SOURCE]
}
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck:#NOT_REQUIRED
@Analytics: {
  technicalName: 'IPExtPremLvl',
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true,
  internalName: #LOCAL
}
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true
define root view entity I_InsurPlcyExtPremiumLevel 
  as select from /pm0/abucibctcha as Characteristics
  inner join /mva/amuprmstex on /mva/amuprmstex.list_id = Characteristics.list_id
                             and Characteristics.application_id = 'POLICY'
                             and Characteristics.state_cd       = '3' // Released

                             and Characteristics.markname       = '/MVA/PRSTEXT_ID'

    composition [0..*] of I_InsurPlcyExtPremiumLevelT    as _Text
    
    association [0..1] to I_InsurPlcyTemplate            as _InsurPlcyTemplate            on  $projection.InsurPlcyBonusMalusTemplate = _InsurPlcyTemplate.InsurPlcyTemplate                     
    association [0..1] to I_InsurPlcyExtPremiumLevelList as _InsurPlcyExtPremiumLevelList on  $projection.InsurPlcyTemplateCharcsList = _InsurPlcyExtPremiumLevelList.InsurPlcyTemplateCharcsList
{
    
      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
    key /mva/amuprmstex./mva/prstext_id   as InsurPlcyExtPremiumLevel,
      @ObjectModel.foreignKey.association: '_InsurPlcyExtPremiumLevelList'
    key /mva/amuprmstex.list_id           as InsurPlcyTemplateCharcsList,
      @ObjectModel.foreignKey.association: '_InsurPlcyTemplate'
    key Characteristics.template_id       as InsurPlcyBonusMalusTemplate,
    
    _Text,
    _InsurPlcyTemplate,
    _InsurPlcyExtPremiumLevelList
  
}

Learn More