I_INSURPLCYDISCOUNTPROTECTION

CDS View

Discount Protection in Insurance Policy

I_INSURPLCYDISCOUNTPROTECTION is a CDS View in S/4HANA. Discount Protection in Insurance Policy. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_InsurPlcyDiscProtectionLink view_entity from BASIC Link to Disc Protection in Insur Plcy 
@EndUserText.label: 'Discount Protection in Insurance Policy'
@ObjectModel:{
    representativeKey: 'InsurPlcyDiscountProtection',
    usageType: {
    serviceQuality: #A,
    sizeCategory: #S,
    dataClass: #CUSTOMIZING
    },
    modelingPattern: #ANALYTICAL_DIMENSION,
    resultSet.sizeCategory: #XS,
    supportedCapabilities: [#ANALYTICAL_DIMENSION,
                            #CDS_MODELING_ASSOCIATION_TARGET,
                            #CDS_MODELING_DATA_SOURCE,
                            #EXTRACTION_DATA_SOURCE,
                            #SEARCHABLE_ENTITY,
                            #SQL_DATA_SOURCE]
}
@VDM: {
  viewType:#BASIC,
  lifecycle.contract.type:#PUBLIC_LOCAL_API
}
@AccessControl.authorizationCheck:#NOT_REQUIRED
@Analytics: {
  technicalName: 'IPDiscProtection',
  dataCategory: #DIMENSION,
  dataExtraction.enabled: true,
  internalName: #LOCAL
}
@Metadata.ignorePropagatedAnnotations: true
@Search.searchable: true

define root view entity I_InsurPlcyDiscountProtection
  as select from /pm0/abucibctcha as Characteristics
    inner join   /mva/amudispro on  /mva/amudispro.list_id         = Characteristics.list_id
                                and Characteristics.application_id = 'POLICY'
                                and Characteristics.state_cd       = '3' // Released

                                and Characteristics.markname       = '/MVA/NCMDPTYP_CD'

  composition [0..*] of I_InsurPlcyDiscountProtectionT as _Text

  association [0..1] to I_InsurPlcyTemplate            as _InsurPlcyTemplate           on  $projection.InsurPlcyProductTemplate = _InsurPlcyTemplate.InsurPlcyTemplate
  association [0..1] to I_InsurPlcyDiscProtectionList  as _InsurPlcyDiscProtectionList on  $projection.InsurPlcyTemplateCharcsList = _InsurPlcyDiscProtectionList.InsurPlcyTemplateCharcsList

{

      @Search.defaultSearchElement: true
      @Search.ranking: #HIGH
      @ObjectModel.text.association: '_Text'
  key /mva/amudispro.nocmdp_cd          as InsurPlcyDiscountProtection,
      @ObjectModel.foreignKey.association: '_InsurPlcyDiscProtectionList'
  key /mva/amudispro.list_id            as InsurPlcyTemplateCharcsList,
      @ObjectModel.foreignKey.association: '_InsurPlcyTemplate'
  key Characteristics.template_id       as InsurPlcyProductTemplate,

      _Text,
      _InsurPlcyTemplate,
      _InsurPlcyDiscProtectionList

}

Learn More