I_INSPSUBSETRESULT
Insp Result for an Inspection Point
I_INSPSUBSETRESULT is a CDS View in S/4HANA. Insp Result for an Inspection Point. It contains 63 fields. 10 CDS views read from this table.
CDS Views using this table (10)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_QM_InspCharInfo | view | left_outer | CONSUMPTION | Characteristic details- More information |
| I_InspCharacteristicAggregate | view | left_outer | COMPOSITE | Aggregation on inspection characteristic level |
| I_InspectionCharacteristicFact | view | left_outer | COMPOSITE | Inspection Characteristic Fact |
| I_InspSampleResultTP | view | from | TRANSACTIONAL | Inspection Result for Inspection Point |
| I_MfgInspCharcHistory | view | inner | COMPOSITE | Inspection Characteristic History |
| I_MfgOrdInspPointRsltAggrg | view | from | BASIC | Interface view for char aggrg rslts on Insp Pt |
| I_MfgOrdPlanInspCharInfo | view | left_outer | COMPOSITE | Order PIC Info |
| P_Inspcharresultdet_With_Smpl | view | inner | COMPOSITE | Inspection characteristic result details for sample lots |
| P_InspectionPartialSampleSize | view_entity | from | COMPOSITE | Number of Samples for Insp. Charac. |
| P_InspMatlSmplCharAggregate | view | left_outer | COMPOSITE | Inspection Material Sample Characteristic Aggregate |
Fields (63)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | InspectionCharacteristic | InspectionCharacteristic | 4 |
| KEY | InspectionLot | InspectionLot | 3 |
| KEY | InspectionSubsetInternalID | InspectionSubsetInternalID | 4 |
| KEY | InspPlanOperationInternalID | InspPlanOperationInternalID | 4 |
| ChangedTime | ChangedTime | 1 | |
| CharacteristicAttributeCatalog | CharacteristicAttributeCatalog | 1 | |
| CharacteristicAttributeCode | CharacteristicAttributeCode | 2 | |
| CharacteristicAttributeCodeGrp | CharacteristicAttributeCodeGrp | 2 | |
| CharcAttributeCodeVers | CharcAttributeCodeVers | 1 | |
| CreatedByUser | CreatedByUser | 2 | |
| CreationDate | CreationDate | 2 | |
| CreationTime | CreationTime | 2 | |
| DefectClass | DefectClass | 1 | |
| InspectionEndDate | InspectionEndDate | 1 | |
| InspectionEndTime | InspectionEndTime | 1 | |
| InspectionNumberOfDefects | InspectionNumberOfDefects | 1 | |
| InspectionResultAttribute | InspectionResultAttribute | 1 | |
| InspectionResultCatalog2 | InspectionResultCatalog2 | 1 | |
| InspectionResultCatalog3 | InspectionResultCatalog3 | 1 | |
| InspectionResultCatalog4 | InspectionResultCatalog4 | 1 | |
| InspectionResultCatalog5 | InspectionResultCatalog5 | 1 | |
| InspectionResultCode2 | InspectionResultCode2 | 1 | |
| InspectionResultCode2Vers | InspectionResultCode2Vers | 1 | |
| InspectionResultCode3 | InspectionResultCode3 | 1 | |
| InspectionResultCode3Vers | InspectionResultCode3Vers | 1 | |
| InspectionResultCode4 | InspectionResultCode4 | 1 | |
| InspectionResultCode4Vers | InspectionResultCode4Vers | 1 | |
| InspectionResultCode5 | InspectionResultCode5 | 1 | |
| InspectionResultCode5Vers | InspectionResultCode5Vers | 1 | |
| InspectionResultCodeGroup2 | InspectionResultCodeGroup2 | 1 | |
| InspectionResultCodeGroup3 | InspectionResultCodeGroup3 | 1 | |
| InspectionResultCodeGroup4 | InspectionResultCodeGroup4 | 1 | |
| InspectionResultCodeGroup5 | InspectionResultCodeGroup5 | 1 | |
| InspectionResultHasLongText | InspectionResultHasLongText | 1 | |
| InspectionResultHasMeanValue | InspectionResultHasMeanValue | 1 | |
| InspectionResultMaximumValue | InspectionResultMaximumValue | 1 | |
| InspectionResultMeanValue | InspectionResultMeanValue | 3 | |
| InspectionResultMinimumValue | InspectionResultMinimumValue | 1 | |
| InspectionResultOrigin | InspectionResultOrigin | 1 | |
| InspectionResultOriginalValue | InspectionResultOriginalValue | 1 | |
| InspectionResultStatus | InspectionResultStatus | 1 | |
| InspectionResultText | InspectionResultText | 1 | |
| InspectionStartDate | InspectionStartDate | 1 | |
| InspectionStartTime | InspectionStartTime | 1 | |
| InspectionValuationResult | InspectionValuationResult | 2 | |
| Inspector | Inspector | 2 | |
| InspResultDynModifValuation | InspResultDynModifValuation | 1 | |
| InspResultHasMaximumValue | InspResultHasMaximumValue | 1 | |
| InspResultHasMinimumValue | InspResultHasMinimumValue | 1 | |
| InspResultHasVariance | InspResultHasVariance | 1 | |
| InspResultNmbrOfRecordedRslts | InspResultNmbrOfRecordedRslts | 1 | |
| InspResultValidValuesNumber | InspResultValidValuesNumber | 3 | |
| InspResultVariance | InspResultVariance | 1 | |
| InspRsltAboveToleranceFraction | InspRsltAboveToleranceFraction | 1 | |
| InspRsltAboveToleranceValsNmbr | InspRsltAboveToleranceValsNmbr | 1 | |
| InspRsltBelowToleranceFraction | InspRsltBelowToleranceFraction | 1 | |
| InspRsltBelowToleranceValsNmbr | InspRsltBelowToleranceValsNmbr | 1 | |
| InspRsltFreeDefinedTestEquip | InspRsltFreeDefinedTestEquip | 1 | |
| InspRsltNonconformingValsNmbr | InspRsltNonconformingValsNmbr | 1 | |
| InspSpecIsChgDocRequired | InspSpecIsChgDocRequired | 1 | |
| Language | Language | 1 | |
| LastChangeDate | LastChangeDate | 1 | |
| LastChangedByUser | LastChangedByUser | 1 |
@AbapCatalog.sqlViewName: 'IINSPSUBSETRSLT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Insp Result for an Inspection Point'
@VDM: {
viewType: #BASIC,
lifecycle.contract.type: #PUBLIC_LOCAL_API
}
@ObjectModel.supportedCapabilities:
[ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.usageType: {
dataClass: #TRANSACTIONAL,
sizeCategory: #L,
serviceQuality: #B
}
@ObjectModel.representativeKey: 'InspectionCharacteristic'
@Metadata.ignorePropagatedAnnotations: true
define view I_InspSubsetResult
as select from qasr
association [1..1] to I_InspectionLot as _InspectionLot on $projection.InspectionLot = _InspectionLot.InspectionLot
association [1..1] to I_InspectionOperation as _InspectionOperation on $projection.InspectionLot = _InspectionOperation.InspectionLot
and $projection.InspPlanOperationInternalID = _InspectionOperation.InspPlanOperationInternalID
association [1..1] to I_InspectionCharacteristic as _InspectionCharacteristic on $projection.InspectionLot = _InspectionCharacteristic.InspectionLot
and $projection.InspPlanOperationInternalID = _InspectionCharacteristic.InspPlanOperationInternalID
and $projection.InspectionCharacteristic = _InspectionCharacteristic.InspectionCharacteristic
association [1..1] to I_InspSubsetCharacteristic as _InspectionSubsetInternalID on $projection.InspectionLot = _InspectionSubsetInternalID.InspectionLot
and $projection.InspPlanOperationInternalID = _InspectionSubsetInternalID.InspPlanOperationInternalID
and $projection.InspectionSubsetInternalID = _InspectionSubsetInternalID.InspectionSubsetInternalID
and $projection.InspectionCharacteristic = _InspectionSubsetInternalID.InspectionCharacteristic
association [0..1] to I_CharcAttributeCode as _CharcAttributeCode on $projection.CharacteristicAttributeCodeGrp = _CharcAttributeCode.CharacteristicAttributeCodeGrp
and $projection.CharacteristicAttributeCode = _CharcAttributeCode.CharacteristicAttributeCode
association [0..1] to I_InspectionResultStatus as _InspectionResultStatus on $projection.InspectionResultStatus = _InspectionResultStatus.InspectionResultStatus
association [0..1] to I_InspectionResultAttribute as _InspectionResultAttribute on $projection.InspectionResultAttribute = _InspectionResultAttribute.InspectionResultAttribute
association [0..1] to I_InspectionResultOrigin as _InspectionResultOrigin on $projection.InspectionResultOrigin = _InspectionResultOrigin.InspectionResultOrigin
association [0..1] to I_InspectionValuationResult as _InspectionValuationResult on $projection.InspectionValuationResult = _InspectionValuationResult.InspectionValuationResult
association [0..1] to I_InspectionValuationResult as _InspResultDynModifValuation on $projection.InspResultDynModifValuation = _InspResultDynModifValuation.InspectionValuationResult
association [0..*] to I_InspectionValuationRsltText as _InspectionValuationRsltTxt on $projection.InspectionValuationResult = _InspectionValuationRsltTxt.InspectionValuationResult
association [0..*] to I_InspSubsetResultLongText as _InspSubsetResultLongText on $projection.InspectionLot = _InspSubsetResultLongText.InspectionLot
and $projection.InspPlanOperationInternalID = _InspSubsetResultLongText.InspPlanOperationInternalID
and $projection.InspectionCharacteristic = _InspSubsetResultLongText.InspectionCharacteristic
and $projection.InspectionSubsetInternalID = _InspSubsetResultLongText.InspectionSubsetInternalID
//Extension
association [1..1] to E_Inspsubsetresult as _Extension //Ignore "_Extension is not used because of Guideline !
on $projection.InspectionLot = _Extension.InspectionLot
and $projection.InspPlanOperationInternalID = _Extension.InspPlanOperationInternalID
and $projection.InspectionCharacteristic = _Extension.InspectionCharacteristic
and $projection.InspectionSubsetInternalID = _Extension.InspectionSubsetInternalID
{
@ObjectModel.foreignKey.association: '_InspectionLot'
key qasr.prueflos as InspectionLot,
@ObjectModel.foreignKey.association: '_InspectionOperation'
key qasr.vorglfnr as InspPlanOperationInternalID,
@ObjectModel.foreignKey.association: '_InspectionCharacteristic'
key qasr.merknr as InspectionCharacteristic,
@ObjectModel.foreignKey.association: '_InspectionSubsetInternalID'
key qasr.probenr as InspectionSubsetInternalID,
qasr.pruefer as Inspector,
qasr.satzstatus as InspectionResultStatus,
qasr.qergdath as InspectionResultOrigin,
qasr.pruefdatuv as InspectionStartDate,
qasr.pruefzeitv as InspectionStartTime,
qasr.pruefdatub as InspectionEndDate,
qasr.pruefzeitb as InspectionEndTime,
qasr.attribut as InspectionResultAttribute,
@ObjectModel.foreignKey.association: '_InspectionValuationResult'
qasr.mbewertg as InspectionValuationResult,
@ObjectModel.foreignKey.association: '_InspResultDynModifValuation'
qasr.dbewertg as InspResultDynModifValuation,
qasr.mittelwert as InspectionResultMeanValue,
cast(case qasr.mittelwni when '*' then 'X' else qasr.mittelwni end as qninitial preserving type ) as InspectionResultHasMeanValue,
qasr.maxwert as InspectionResultMaximumValue, //Maximum value, single/Summary at header level
cast(case qasr.maxwertni when '*' then 'X' else qasr.maxwertni end as qninitial preserving type ) as InspResultHasMaximumValue,
qasr.minwert as InspectionResultMinimumValue, //Minimum value, single/Summary at header level
cast(case qasr.minwertni when '*' then 'X' else qasr.minwertni end as qninitial preserving type ) as InspResultHasMinimumValue,
qasr.original_input as InspectionResultOriginalValue,
qasr.anzwertg as InspResultValidValuesNumber,
cast( qasr.pruefbemkt as vdm_qinspectionsamplresultdesc preserving type ) as InspectionResultText,
qasr.prltextkz as InspectionResultHasLongText,
qasr.ltextspr as Language,
qasr.maschine as InspRsltFreeDefinedTestEquip,
qasr.anzwertu as InspRsltBelowToleranceValsNmbr,
qasr.anzwerto as InspRsltAboveToleranceValsNmbr,
qasr.iststpumf as InspResultNmbrOfRecordedRslts,
qasr.anzfehleh as InspRsltNonconformingValsNmbr,
qasr.anzfehler as InspectionNumberOfDefects,
qasr.anteilo as InspRsltAboveToleranceFraction,
qasr.anteilu as InspRsltBelowToleranceFraction,
qasr.varianz as InspResultVariance,
cast(case qasr.varianzni when '*' then 'X' else qasr.varianzni end as vdm_varianzni preserving type ) as InspResultHasVariance,
qasr.version1 as CharcAttributeCodeVers,
qasr.version2 as InspectionResultCode2Vers,
qasr.version3 as InspectionResultCode3Vers,
qasr.version4 as InspectionResultCode4Vers,
qasr.version5 as InspectionResultCode5Vers,
qasr.gruppe1 as CharacteristicAttributeCodeGrp,
qasr.gruppe2 as InspectionResultCodeGroup2,
qasr.gruppe3 as InspectionResultCodeGroup3,
qasr.gruppe4 as InspectionResultCodeGroup4,
qasr.gruppe5 as InspectionResultCodeGroup5,
qasr.code1 as CharacteristicAttributeCode,
qasr.code2 as InspectionResultCode2,
qasr.code3 as InspectionResultCode3,
qasr.code4 as InspectionResultCode4,
qasr.code5 as InspectionResultCode5,
qasr.katalgart1 as CharacteristicAttributeCatalog,
qasr.katalgart2 as InspectionResultCatalog2,
qasr.katalgart3 as InspectionResultCatalog3,
qasr.katalgart4 as InspectionResultCatalog4,
qasr.katalgart5 as InspectionResultCatalog5,
qasr.fehlklas as DefectClass,
@Semantics.user.createdBy: true
qasr.ersteller as CreatedByUser,
@Semantics.systemDate.createdAt: true
qasr.erstelldat as CreationDate,
@Semantics.user.lastChangedBy: true
qasr.aenderer as LastChangedByUser,
@Semantics.systemDate.lastChangedAt: true
qasr.aenderdat as LastChangeDate,
case qasr.changeddatetime
when 0 then cast( '19000101010101' as tzntstmps )
else qasr.changeddatetime end as ChangedDateTime,
qasr.zeitaend as ChangedTime,
qasr.zeiterstl as CreationTime,
qasr.diff_dec_places as InspResultNrOfAddlDcmlsPlaces,
@Semantics.booleanIndicator
qasr.aendbeleg as InspSpecIsChgDocRequired,
// Associations
_InspectionLot,
_InspectionOperation,
_InspectionCharacteristic,
_InspectionSubsetInternalID,
_CharcAttributeCode,
_InspectionResultStatus,
_InspectionResultAttribute,
_InspectionResultOrigin,
_InspectionValuationResult,
_InspResultDynModifValuation,
_InspectionValuationRsltTxt,
_InspSubsetResultLongText
}