I_GLACCTWITHGRPCHARTOFACCOUNTS
gl account with group chart of account
I_GLACCTWITHGRPCHARTOFACCOUNTS is a CDS View in S/4HANA. gl account with group chart of account. It contains 4 fields. 4 CDS views read from this table.
CDS Views using this table (4)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| C_AllocationSenderGLAcctVH | view | inner | CONSUMPTION | Account Number |
| C_GLAccountInchartOfAccount | view | from | CONSUMPTION | GL Accounts in Chart of Account |
| C_InventoryGLAcctBalCube | view | left_outer | CONSUMPTION | Turkey Inventory CDS cube view |
| P_GLAccountTypeVH | view | inner | CONSUMPTION | gl account vh |
Fields (4)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | ChartOfAccounts | ChartOfAccounts,CorporateGroupChartOfAccounts | 2 |
| KEY | GLAccountExternal | GLAccountExternal | 1 |
| GLAccountGroup | GLAccountGroup | 1 | |
| GLAccountType | GLAccountType | 2 |
@AbapCatalog.entityBuffer.definitionAllowed: false
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@Analytics.technicalName: 'IFIGLGRPCOA'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'GLAccount'
@ObjectModel.usageType.sizeCategory: #M
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #B
@Metadata.ignorePropagatedAnnotations: true
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions:true
@EndUserText.label: 'gl account with group chart of account'
define view entity I_GLAcctWithGrpChartOfAccounts
as select distinct from ska1
left outer join t004 on ska1.ktopl = t004.ktopl
association [0..1] to I_ChartOfAccounts as _GroupChartOfAccounts on $projection.CorporateGroupChartOfAccounts = _GroupChartOfAccounts.ChartOfAccounts
association [0..*] to I_GLAccountText as _CorporateGroupAccountText on $projection.CorporateGroupChartOfAccounts = _CorporateGroupAccountText.ChartOfAccounts
and $projection.CorporateGroupAccount = _CorporateGroupAccountText.GLAccount
association [0..1] to I_ChartOfAccounts as _ChartOfAccounts on $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
association [0..*] to I_GLAccountText as _Text on $projection.ChartOfAccounts = _Text.ChartOfAccounts
and $projection.GLAccount = _Text.GLAccount
association [0..1] to I_GLAccountType as _GLAccountType on $projection.GLAccountType = _GLAccountType.GLAccountType
association [0..1] to I_RetainedEarningsGLAccount as _RetainedEarningsGLAccount on $projection.ChartOfAccounts = _RetainedEarningsGLAccount.ChartOfAccounts
and $projection.ProfitLossAccountType = _RetainedEarningsGLAccount.ProfitLossAccountType
association [0..*] to I_GLAccountHierarchyNode as _GLAccountHierarchyNode on $projection.GLAccount = _GLAccountHierarchyNode.GLAccount
and $projection.ChartOfAccounts = _GLAccountHierarchyNode.ChartOfAccounts
association [0..1] to I_FunctionalArea as _FunctionalArea on $projection.FunctionalArea = _FunctionalArea.FunctionalArea
association [1..1] to I_User as _User on $projection.CreatedByUser = _User.UserID
association [1..1] to I_Globalcompany as _GlobalCompany on $projection.PartnerCompany = _GlobalCompany.Company
association [0..1] to I_GLAccountGroup as _GLAccountGroup on $projection.GLAccountGroup = _GLAccountGroup.GLAccountGroup
and $projection.ChartOfAccounts = _GLAccountGroup.ChartOfAccounts
association [0..1] to I_GLAcctInChartOfAcctsProdn as _GLAcctInChartOfAcctsProdn on $projection.ChartOfAccounts = _GLAcctInChartOfAcctsProdn.ChartOfAccounts
and $projection.GLAccount = _GLAcctInChartOfAcctsProdn.GLAccount
association [0..1] to I_GLAcctInCOAImplementStat as _GLAcctInChartOfAcctsStatus on $projection.ChartOfAccounts = _GLAcctInChartOfAcctsStatus.ChartOfAccounts
and $projection.GLAccount = _GLAcctInChartOfAcctsStatus.GLAccount
{
@ObjectModel.foreignKey.association: '_ChartOfAccounts' //Inserted by VDM CDS Suite Plugin
key ska1.ktopl as ChartOfAccounts,
@ObjectModel.text.association: '_Text'
@ObjectModel.hierarchy.association: '_GLAccountHierarchyNode'
key ska1.saknr as GLAccount,
ska1.xbilk as IsBalanceSheetAccount,
@ObjectModel.foreignKey.association: '_Glaccountgroup'
ska1.ktoks as GLAccountGroup,
@ObjectModel.text.association: '_CorporateGroupAccountText'
ska1.bilkt as CorporateGroupAccount,
ska1.gvtyp as ProfitLossAccountType,
ska1.mustr as SampleGLAccount,
ska1.xloev as AccountIsMarkedForDeletion,
ska1.xspea as AccountIsBlockedForCreation,
ska1.xspeb as AccountIsBlockedForPosting,
ska1.xspep as AccountIsBlockedForPlanning,
@ObjectModel.foreignKey.association: '_GlobalCompany'
ska1.vbund as PartnerCompany,
@ObjectModel.foreignKey.association: '_FunctionalArea' //Inserted by VDM CDS Suite Plugin
ska1.func_area as FunctionalArea,
@Semantics.systemDate.createdAt: true
ska1.erdat as CreationDate,
ska1.ernam as CreatedByUser,
@Semantics.systemDateTime.lastChangedAt: true
ska1.last_changed_ts as LastChangeDateTime,
@ObjectModel.foreignKey.association: '_Glaccounttype' //Inserted by VDM CDS Suite Plugin
ska1.glaccount_type as GLAccountType,
ska1.sakan as GLAccountExternal,
ska1.main_saknr as BankReconciliationAccount,
@EndUserText.label: 'Profit Loss Account'
case when ska1.xbilk = 'X' then
' '
else
'X'
end as IsProfitLossAccount,
@ObjectModel.foreignKey.association: '_GroupChartOfAccounts'
t004.kktpl as CorporateGroupChartOfAccounts,
_GLAcctInChartOfAcctsProdn.GLAccountIsNotProdnRelevant,
// _GLAcctInChartOfAcctsImst.GLAcctCOAImplementStatus as GLAcctCOAImplementStatus,
// _GLAcctInChartOfAcctsImst.GLAccountCOAIsDeliveredBySAP as GLAccountCOAIsDeliveredBySAP,
_CorporateGroupAccountText,
_GroupChartOfAccounts,
_User,
_ChartOfAccounts,
_Text,
_GLAccountHierarchyNode,
_FunctionalArea,
_RetainedEarningsGLAccount,
_GLAccountType,
_GLAccountGroup,
_GlobalCompany,
_GLAcctInChartOfAcctsProdn,
_GLAcctInChartOfAcctsStatus
}