I_GLACCOUNTFORPUBLICSECTOR

CDS View

FM Settings for GL Accounts

I_GLACCOUNTFORPUBLICSECTOR is a CDS View in S/4HANA. FM Settings for GL Accounts. It contains 19 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 19 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
I_BudgetAccountInChtAccts view from BASIC Budget Account in Chart of Accounts
I_BudgetAccountText view inner BASIC Budget Account - Text
I_GLAccountForPublicSectorTP view_entity from TRANSACTIONAL FM Settings for GL Accounts
I_PubSecInterestAccountVH view from COMPOSITE Interest Accounts
I_PubSecParticipantAccountVH view from COMPOSITE Participating Accounts
I_SpnsrdClassGLAccount view from BASIC GL Account Sponsored Class

Fields (19)

KeyField CDS FieldsUsed in Views
KEY ChartOfAccounts ChartOfAccounts 2
KEY GLAccount GLAccount 1
_CarryForwardBudgetAccount _CarryForwardBudgetAccount 2
_CashLedgerAccount _CashLedgerAccount 2
_ChartOfAccounts _ChartOfAccounts 2
_GLAccountHierarchyNode _GLAccountHierarchyNode 1
_PubSecBdgtAcctCarryFwdTo _PubSecBdgtAcctCarryFwdTo 2
_PubSecBdgtAcctRevnExpnCode _PubSecBdgtAcctRevnExpnCode 2
_PubSecBdgtCnsmpnType _PubSecBdgtCnsmpnType 2
_Text _Text 2
CashLedgerAccount CashLedgerAccount 2
PubSecBdgtAcctCarryFwdTo PubSecBdgtAcctCarryFwdTo 2
PubSecBdgtAcctIsBdgtAllowed PubSecBdgtAcctIsBdgtAllowed 2
PubSecBdgtAcctIsCarryFwd PubSecBdgtAcctIsCarryFwd 2
PubSecBdgtAcctIsPostgAllowed PubSecBdgtAcctIsPostgAllowed 2
PubSecBdgtAcctRevnExpnCode PubSecBdgtAcctRevnExpnCode 2
PubSecBudgetCnsmpnType PubSecBudgetCnsmpnType 2
PubSecBudgetIsRelevant PubSecBudgetIsRelevant 2
SponsoredClass SponsoredClass 1 
@AbapCatalog.sqlViewName: 'IPSMS4CGLACCTX'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'FM Settings for GL Accounts'

@VDM.viewType: #BASIC
@ObjectModel: {
     representativeKey: 'GLAccount',
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #C,
         sizeCategory: #L
     }
}

define view I_GLAccountForPublicSector
  as select from psm_d_glacctx as main 
  association [0..1] to I_PubSecBdgtCnsmpnType       as _PubSecBdgtCnsmpnType       on  $projection.PubSecBudgetCnsmpnType = _PubSecBdgtCnsmpnType.PubSecBudgetCnsmpnType
  association [0..1] to I_PubSecBdgtAcctRevnExpnCode as _PubSecBdgtAcctRevnExpnCode on  $projection.PubSecBdgtAcctRevnExpnCode = _PubSecBdgtAcctRevnExpnCode.PubSecBdgtAcctRevnExpnCode
  // Deprecated: Do not use association _PubSecBdgtAcctCarryFwdTo

  association [0..1] to I_GLAccountInChartOfAccounts as _PubSecBdgtAcctCarryFwdTo   on  $projection.ChartOfAccounts   = _PubSecBdgtAcctCarryFwdTo.ChartOfAccounts
                                                                                    and $projection.PubSecBdgtAcctCarryFwdTo = _PubSecBdgtAcctCarryFwdTo.GLAccount
  association [0..1] to I_CarryForwardBudgetAccount  as _CarryForwardBudgetAccount  on  $projection.ChartOfAccounts          = _CarryForwardBudgetAccount.ChartOfAccounts
                                                                                    and $projection.PubSecBdgtAcctCarryFwdTo = _CarryForwardBudgetAccount.PubSecBdgtAcctCarryFwdTo
  association [0..1] to I_GLAccountInChartOfAccounts as _CashLedgerAccount          on  $projection.ChartOfAccounts   = _CashLedgerAccount.ChartOfAccounts
                                                                                    and $projection.CashLedgerAccount = _CashLedgerAccount.GLAccount
  association [0..1] to I_ChartOfAccounts            as _ChartOfAccounts            on  $projection.ChartOfAccounts = _ChartOfAccounts.ChartOfAccounts
  association [0..*] to I_GLAccountText              as _Text                       on  $projection.ChartOfAccounts = _Text.ChartOfAccounts
                                                                                    and $projection.GLAccount       = _Text.GLAccount
  association [0..*] to I_GLAccountHierarchyNode     as _GLAccountHierarchyNode     on  $projection.GLAccount       = _GLAccountHierarchyNode.GLAccount
                                                                                    and $projection.ChartOfAccounts = _GLAccountHierarchyNode.ChartOfAccounts

{
      @Consumption.valueHelpDefinition: [{
        entity:  { 
          name:    'I_ChartOfAccountsStdVH',
          element: 'ChartOfAccounts' }
      }]
      @ObjectModel.foreignKey.association: '_ChartOfAccounts'
  key cast( main.chrt_accts as fis_ktopl preserving type )      as ChartOfAccounts,
      @ObjectModel.text.association: '_Text'
      @ObjectModel.hierarchy.association: '_GLAccountHierarchyNode'
  key cast( main.gl_account as fis_racct preserving type )      as GLAccount,
      @ObjectModel.foreignKey.association: '_PubSecBdgtCnsmpnType'
      main.bdgt_cnsmpn_type                                     as PubSecBudgetCnsmpnType,
      @ObjectModel.foreignKey.association: '_PubSecBdgtAcctRevnExpnCode'
      main.bdgt_acct_rev_or_exp                                 as PubSecBdgtAcctRevnExpnCode,
      main.bdgt_relevant                                        as PubSecBudgetIsRelevant,
      main.bdgt_acct_postg_allwd                                as PubSecBdgtAcctIsPostgAllowed,
      main.bdgt_acct_bdgtg_allwd                                as PubSecBdgtAcctIsBdgtAllowed,
      main.bdgt_acct_cf_use                                     as PubSecBdgtAcctIsCarryFwd,
      @Consumption.valueHelpDefinition: [{
        entity: {
          name: 'I_CarryForwardBudgetAccountVH',
          element: 'PubSecBdgtAcctCarryFwdTo'
        },
        additionalBinding: [{ 
          localElement: 'ChartOfAccounts',
          element: 'ChartOfAccounts' }]
      }]
      @ObjectModel.foreignKey.association: '_CarryForwardBudgetAccount'
      main.bdgt_acct_cf_to                                      as PubSecBdgtAcctCarryFwdTo,
//      @Consumption.valueHelpDefinition: [{

//        entity: { 

//          name:    'I_CashOriginBudgetAccountVH',

//          element: 'PubSecBdgtAcctCashOrigin' 

//        },

//        additionalBinding: [{ 

//          localElement: 'ChartOfAccounts',

//          element: 'ChartOfAccounts' }]

//      }]

//      @ObjectModel.foreignKey.association: '_CashLedgerAccount'

 //     cast( main.re_account as fis_re_account preserving type ) as PubSecBdgtAcctCashOrigin,

      @Consumption.valueHelpDefinition: [{
        entity: { 
          name:    'I_CashOriginBudgetAccountVH',
          element: 'CashLedgerAccount' 
        },
        additionalBinding: [{ 
          localElement: 'ChartOfAccounts',
          element: 'ChartOfAccounts' }]
      }]
      @ObjectModel.foreignKey.association: '_CashLedgerAccount'
      cast( main.re_account as fis_re_account preserving type ) as CashLedgerAccount,
      @Consumption.valueHelpDefinition: [{
        entity:  { 
          name:    'I_SponsoredClassStdVH',
          element: 'SponsoredClass' }
      }]
      main.sponsored_class                                      as SponsoredClass,

      _PubSecBdgtCnsmpnType,
      _PubSecBdgtAcctRevnExpnCode,
      @VDM.lifecycle.status: #DEPRECATED
      @VDM.lifecycle.successor: '_CarryForwardBudgetAccount'
      _PubSecBdgtAcctCarryFwdTo,
      _CarryForwardBudgetAccount,
      _CashLedgerAccount,
      _ChartOfAccounts,
      _GLAccountHierarchyNode,
      _Text

}

Learn More