I_FUNDEDPROGRAMTEXT

CDS View

Funded Program - Text

I_FUNDEDPROGRAMTEXT is a CDS View in S/4HANA. Funded Program - Text. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_FundedProgramText view_entity from CONSUMPTION Funded Program Text 
@EndUserText.label: 'Funded Program - Text'
@Analytics: { 
              dataExtraction.enabled: true, 
              internalName: #LOCAL 
            }
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'FundedProgram'
@ObjectModel.usageType: {
  dataClass: #MASTER,
  serviceQuality: #A,
  sizeCategory: #M
}
@ObjectModel.supportedCapabilities: [#LANGUAGE_DEPENDENT_TEXT, #EXTRACTION_DATA_SOURCE]
@ObjectModel.dataCategory: #TEXT
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations:true
@AbapCatalog.sqlViewName: 'IFMFUNDEDPROGT'
define view I_FundedProgramText as select from fmmeasuret
association [1..1] to I_FinancialManagementArea as _FinMgmtArea   on $projection.FinancialManagementArea  = _FinMgmtArea.FinancialManagementArea
association [0..1] to I_Language                as _Language      on $projection.Language                 = _Language.Language
association [0..1] to I_FundedProgram           as _FundedProgram on  $projection.FinancialManagementArea = _FundedProgram.FinancialManagementArea  //for authorization check

                                                                  and $projection.FundedProgram           = _FundedProgram.FundedProgram
{

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_FinMgmtAreaStdVH',
                     element: 'FinancialManagementArea' }
        }]
    @ObjectModel.foreignKey.association: '_FinMgmtArea'
    key fmarea                 as FinancialManagementArea,
    key measure                as FundedProgram,
    @Semantics.language: true
    @ObjectModel.foreignKey.association: '_Language'    
    key language               as Language,
    @Semantics.text: true
    cast (short_desc as fmis_fp_name)           as FundedProgramName,  
    @Semantics.text: true
    cast (description as fmis_fp_description)   as FundedProgramDescription,
          
    _FinMgmtArea,
    _Language,
    _FundedProgram
}

//fmmeasuret fields

//LANGUAGE

//FMAREA

//MEASURE

//SHORT_DESC

//DESCRIPTION

Learn More