I_FUNDHIERARCHYNODETEXT

CDS View

Fund Hierarchy Node Text

I_FUNDHIERARCHYNODETEXT is a CDS View in S/4HANA. Fund Hierarchy Node Text. 2 CDS views read from this table.

Used by 2 CDS view(s)

CDS Views using this table (2)

ViewTypeJoinVDMDescription
A_FundCoreHierarchyNodeText view from COMPOSITE Fund Hierarchy Node Text
A_FundHierNodeText view from COMPOSITE Fund Hierarchy Node Text 
@AbapCatalog.sqlViewName: 'IFUNDHNTXT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Fund Hierarchy Node Text'

@VDM.viewType: #BASIC
//@Analytics.dataExtraction: {enabled:true}

@ObjectModel: {
     dataCategory: #TEXT,
     representativeKey: 'HierarchyNode',
     usageType: {
         dataClass: #MASTER,
         serviceQuality: #A,
         sizeCategory: #XL
     }
}

define view I_FundHierarchyNodeText
  as select from hrrp_nodet
    inner join   I_FundHierarchy on  I_FundHierarchy.FundHierarchy   = hrrp_nodet.hryid
                                 and I_FundHierarchy.ValidityEndDate = hrrp_nodet.hryvalto

  association [0..1] to I_Language      as _Language  on $projection.Language = _Language.Language

  association [1..*] to I_FundHierarchy as _Hierarchy on $projection.FundHierarchy = _Hierarchy.FundHierarchy

{
      @ObjectModel.foreignKey.association: '_Hierarchy'
  key cast( hrrp_nodet.hryid as fmis_hryid_fund preserving type ) as FundHierarchy,
  key hrrp_nodet.hrynode                                          as HierarchyNode,
      @Semantics.businessDate.to: true
  key cast( hrrp_nodet.hryvalto as fis_datbi preserving type )    as ValidityEndDate,
      @Semantics.language: true
  key hrrp_nodet.spras                                            as Language,
      @Semantics.text: true
      hrrp_nodet.nodetxt                                          as HierarchyNodeText,
      @Semantics.text: true
      substring(hrrp_nodet.nodetxt, 1, 20)                        as HierarchyNodeShortText,

      @Semantics.businessDate.from: true
      cast( hrrp_nodet.hryvalfrom as fis_datab preserving type )  as ValidityStartDate,
      I_FundHierarchy.FinancialManagementArea                     as FinancialManagementArea,
      _Language,
      _Hierarchy

}

Learn More