I_FIXEDASSETVALUEHELP

CDS View

Fixed Asset Value Help

I_FIXEDASSETVALUEHELP is a CDS View in S/4HANA. Fixed Asset Value Help. It contains 7 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 7 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
I_MM_FixedAssetValueHelp view from COMPOSITE Purchasing Fixed Asset Value Help
I_REFixedAssetVH view from COMPOSITE Real Estate Fixed Asset Value Help

Fields (7)

KeyField CDS FieldsUsed in Views
KEY CompanyCode CompanyCode 2
KEY FixedAsset FixedAsset 2
KEY MasterFixedAsset MasterFixedAsset 2
AssetAuthorizationContext AssetAuthorizationContext 2
AssetCapitalizationDate AssetCapitalizationDate 2
AssetClass AssetClass 2
FixedAssetDescription FixedAssetDescription 2 
@AbapCatalog: {sqlViewName: 'IFIXASSETVH', preserveKey: true}
@AbapCatalog.compiler.compareFilter: true
@VDM.viewType: #COMPOSITE
@ObjectModel: { representativeKey: 'FixedAsset',
                dataCategory: #VALUE_HELP,
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #XXL,
                usageType.dataClass: #MASTER }
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fixed Asset Value Help'

define view I_FixedAssetValueHelp
  as select from           I_FixedAsset
    left outer to one join P_FixedAssetVH1 on  I_FixedAsset.CompanyCode      = P_FixedAssetVH1.CompanyCode
                                           and I_FixedAsset.MasterFixedAsset = P_FixedAssetVH1.MasterFixedAsset
                                           and I_FixedAsset.FixedAsset       = P_FixedAssetVH1.FixedAsset

  association [0..1] to I_CompanyCode      as _CompanyCode      on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_MasterFixedAsset as _MasterFixedAsset on  $projection.CompanyCode      = _MasterFixedAsset.CompanyCode
                                                                and $projection.MasterFixedAsset = _MasterFixedAsset.MasterFixedAsset
{
      @ObjectModel.foreignKey.association: '_CompanyCode'
  key I_FixedAsset.CompanyCode as CompanyCode,
      @ObjectModel.foreignKey.association: '_MasterFixedAsset'
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key I_FixedAsset.MasterFixedAsset as MasterFixedAsset,
      @ObjectModel.text.element: 'FixedAssetDescription'
  key I_FixedAsset.FixedAsset as FixedAsset,

      @Semantics.text:true
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      I_FixedAsset.FixedAssetDescription as FixedAssetDescription,

      I_FixedAsset.AssetClass as AssetClass,
      cast(P_FixedAssetVH1.AssetCapitalizationDate as aktivd preserving type) as AssetCapitalizationDate,
      @Consumption.hidden: true
      I_FixedAsset.AssetAuthorizationContext, //Needed for DCL


      _CompanyCode,
      _MasterFixedAsset
}

Learn More