I_FISCALYEARPERIODFORCMPNYCODE

CDS View

Fiscal Year Period For Company Code

I_FISCALYEARPERIODFORCMPNYCODE is a CDS View in S/4HANA. Fiscal Year Period For Company Code. It contains 17 fields. 17 CDS views read from this table.

Used by 17 CDS view(s) 17 fields

CDS Views using this table (17)

ViewTypeJoinVDMDescription
C_ActualCostRateTimeline view inner CONSUMPTION Actual Cost Rate Timeline
C_APMinFiscalPeriodStartDate view from CONSUMPTION Minimal Fiscal Period Start Date
C_FiscalYearPeriodForCoCodeVH view_entity from CONSUMPTION Fiscal Year Period For Company Code
C_ServiceCostRateTimeline view inner CONSUMPTION Service Cost Rate Timeline Chart
C_SlsAcctgFsclPerdForCoCodeVH view from CONSUMPTION Fiscal Year Period for Company Code Value Help
I_JVAFiscalYearPeriodForCoCode view from COMPOSITE JVA Fiscal Year Period For Company Code
I_JVAFiscalYearPeriodForCoCode view inner COMPOSITE JVA Fiscal Year Period For Company Code
I_JVAFiscalYrPerdForEquityGrp view inner COMPOSITE JVA Fiscal Year Period For Equity Group
I_PPM_CurrentPeriod view inner COMPOSITE Current period for a project
P_EBWIP_WIPQtyDocument view_entity inner COMPOSITE Event-Based WIP - WIP Quantity Document
P_EntProjActlCostDatesByID view inner CONSUMPTION Project Actual Cost Dates By Project Internal ID
P_FIARCN_TOTAL_PERIODS view from CONSUMPTION Periods of a fiscal year in a company
P_FiscalPeriodLast6Mnths view from COMPOSITE Calendar For Last 6 Fiscal Periods Ovw
P_Matval_Manage_FiscPer_Info view from COMPOSITE Information about current and next period
P_Matval_Manage_Val_Chart view inner COMPOSITE Base View for Mat.Val., Balances
P_PCCOrderOutPutQtyByPeriod view inner COMPOSITE Production Cost Controlling: Order Out Put Qty by Period
P_PH_SalesPurchasesSummaryItem view left_outer COMPOSITE PH Sales Purchase Summary

Fields (17)

KeyField CDS FieldsUsed in Views
KEY CompanyCode CompanyCode 2
KEY FiscalPeriod CurrentFiscalPeriod,FiscalPeriod,PreviousFiscalPeriod 6
KEY FiscalYear CurrentFiscalYear,FiscalYear,PreviousFiscalYear 6
_CompanyCode _CompanyCode 1
_FiscalPeriodStartDate _FiscalPeriodStartDate 1
_FiscalYear _FiscalYear 1
_FiscalYearVariant _FiscalYearVariant 1
_Text _Text 1
FiscalPeriodEndDate FiscalPeriodEndDate 3
FiscalPeriodStartDate FiscalPeriodStartDate 2
FiscalYearEndDate FiscalYearEndDate 1
FiscalYearPeriod FiscalYearPeriod 2
FiscalYearStartDate FiscalYearStartDate 1
FiscalYearVariant FiscalYearVariant 1
IsSpecialPeriod IsSpecialPeriod 1
NextFiscalPeriod NextFiscalPeriod 1
NextFiscalPeriodFiscalYear NextFiscalPeriodFiscalYear 1 
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Fiscal Year Period For Company Code'
@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #B
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'FiscalPeriod'
@Analytics: { dataCategory: #DIMENSION }
@Analytics.technicalName: 'IFIFYEARPERIODCC'

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view entity I_FiscalYearPeriodForCmpnyCode as select from I_FiscalYearPeriod as I_FiscalYearPeriod inner join  I_CompanyCode as I_CompanyCode
                                                       on I_FiscalYearPeriod.FiscalYearVariant = I_CompanyCode.FiscalYearVariant

association [0..1] to I_FiscalYearVariant         as _FiscalYearVariant on  $projection.FiscalYearVariant = _FiscalYearVariant.FiscalYearVariant
association [0..1] to I_CompanyCode               as _CompanyCode       on  $projection.CompanyCode       = _CompanyCode.CompanyCode
association [0..1] to I_FiscalYearForCompanyCode  as _FiscalYear        on  $projection.FiscalYear        = _FiscalYear.FiscalYear
                                                                       and $projection.CompanyCode        = _FiscalYear.CompanyCode  
association [0..*] to I_FiscalPeriodForCoCodeText as _Text              on  $projection.CompanyCode       = _Text.CompanyCode
                                                                       and $projection.FiscalYear         = _Text.FiscalYear
                                                                       and $projection.FiscalPeriod       = _Text.FiscalPeriod

{

      //--[ GENERATED:012:29JlHNUf7jY4ip0dSlCN8W

      @Consumption.valueHelpDefinition: [ 
        { entity:  { name:    'I_CompanyCodeStdVH',
                     element: 'CompanyCode' }
        }]
      // ]--GENERATED

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( I_CompanyCode.CompanyCode as fis_bukrs preserving type ) as CompanyCode,
@ObjectModel.foreignKey.association: '_FiscalYear'      
key I_FiscalYearPeriod.FiscalYear,
@ObjectModel.text.association: '_Text'
key I_FiscalYearPeriod.FiscalPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
    I_FiscalYearPeriod.FiscalYearVariant,

@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      
    I_FiscalYearPeriod.FiscalPeriodStartDate,
    I_FiscalYearPeriod.FiscalPeriodEndDate,
    
    I_FiscalYearPeriod.IsSpecialPeriod,
    
    I_FiscalYearPeriod.FiscalYearStartDate,
    I_FiscalYearPeriod.FiscalYearEndDate,
    
    I_FiscalYearPeriod.NextFiscalPeriod,
    I_FiscalYearPeriod.NextFiscalPeriodFiscalYear,
     
    I_FiscalYearPeriod.FiscalYearPeriod,
    
    _CompanyCode,
    _FiscalYearVariant,
    I_FiscalYearPeriod._FiscalPeriodStartDate,
    _FiscalYear,
    _Text 
           
}

Learn More