I_FISCALCALYEARPERIODFORLEDGER

CDS View

Fiscal Year Period for Ledger

I_FISCALCALYEARPERIODFORLEDGER is a CDS View in S/4HANA. Fiscal Year Period for Ledger. It contains 7 fields. 5 CDS views read from this table.

Used by 5 CDS view(s) 7 fields

CDS Views using this table (5)

ViewTypeJoinVDMDescription
P_CN_GLAcctPerd view from CONSUMPTION Cartesian Product of G/L Account and Fiscal Period
P_FinStatisticalKeyFigureItem1 view_entity inner COMPOSITE Statistical Keyfigures per period - Union
P_GLAccountBalanceEnd_F0707A view_entity inner CONSUMPTION GL Balances - Endings
P_GLAcctBalance01 view inner COMPOSITE CDS Views for GL Account Line Items in a specific Peirod
P_MaxFiscalPeriod view_entity from COMPOSITE Shifted Fiscal Calendar Date

Fields (7)

KeyField CDS FieldsUsed in Views
KEY CompanyCode CompanyCode 1
KEY FiscalPeriod FiscalPeriod,poper 3
KEY FiscalYear FiscalYear,RYEAR 2
KEY FiscalYearVariant FiscalYearVariant,periv 2
KEY Ledger Ledger,rldnr 2
FiscalYearPeriod FiscalYearPeriod,FISCYEARPER 2
IsSpecialPeriod IsSpecialPeriod 1 
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING

@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'FiscalYearPeriod'
//@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }

@Analytics: { dataCategory: #DIMENSION }
@Analytics.technicalName: 'IFIFCFYPERD4L'
@EndUserText.label: 'Fiscal Year Period for Ledger'

@ObjectModel.modelingPattern: #ANALYTICAL_DIMENSION
@ObjectModel.supportedCapabilities: [#ANALYTICAL_DIMENSION, 
                                     #CDS_MODELING_ASSOCIATION_TARGET, 
                                     #CDS_MODELING_DATA_SOURCE,
                                     #SQL_DATA_SOURCE]
                                     
define view entity I_FiscalCalYearPeriodForLedger as select from I_FiscalYearPeriod as I_FiscalYearPeriod inner join finsc_ld_cmp 
                                                                                                   on   I_FiscalYearPeriod.FiscalYearVariant = finsc_ld_cmp.periv

association [0..1] to I_CompanyCode              as _CompanyCode on  $projection.CompanyCode       = _CompanyCode.CompanyCode
association [0..1] to I_Ledger                   as _Ledger      on  $projection.Ledger            = _Ledger.Ledger
association [0..1] to I_FiscalYearForCompanyCode as _FiscalYear  on  $projection.FiscalYear        = _FiscalYear.FiscalYear
                                                                 and $projection.CompanyCode       = _FiscalYear.CompanyCode  
association [0..*] to I_FiscalYearPeriodText     as _Text        on  $projection.FiscalYearVariant = _Text.FiscalYearVariant
                                                                 and $projection.FiscalYear        = _Text.FiscalYear
                                                                 and $projection.FiscalPeriod      = _Text.FiscalPeriod
association [0..1] to I_FiscalYear               as _FiscalYearForVariant  on  $projection.FiscalYearVariant = _FiscalYearForVariant.FiscalYearVariant
                                                                           and $projection.FiscalYear        = _FiscalYearForVariant.FiscalYear                                                                 

{

@ObjectModel.foreignKey.association: '_CompanyCode'      
key cast( finsc_ld_cmp.bukrs as fis_bukrs preserving type ) as CompanyCode, 
@ObjectModel.foreignKey.association: '_Ledger'      
key cast( finsc_ld_cmp.rldnr as fis_rldnr preserving type ) as Ledger,
key I_FiscalYearPeriod.FiscalYearPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearForVariant'      
    I_FiscalYearPeriod.FiscalYear,
@ObjectModel.text.association: '_Text'
    I_FiscalYearPeriod.FiscalPeriod,

@ObjectModel.foreignKey.association: '_FiscalYearVariant'      
    I_FiscalYearPeriod.FiscalYearVariant,

@ObjectModel.foreignKey.association: '_FiscalPeriodStartDate'      
    I_FiscalYearPeriod.FiscalPeriodStartDate,
    I_FiscalYearPeriod.FiscalPeriodEndDate,
    
    I_FiscalYearPeriod.IsSpecialPeriod,
    
    I_FiscalYearPeriod.FiscalYearStartDate,
    I_FiscalYearPeriod.FiscalYearEndDate,
    
    I_FiscalYearPeriod.NextFiscalPeriod,
    I_FiscalYearPeriod.NextFiscalPeriodFiscalYear,
     
    _CompanyCode,
    _Ledger,
    I_FiscalYearPeriod._FiscalYearVariant,
    _FiscalYearForVariant,
    I_FiscalYearPeriod._FiscalPeriodStartDate,
    _FiscalYear,
    _Text

}

Learn More