I_FINANCIALTRANSACTIONRATING

@AbapCatalog.viewEnhancementCategory: [ #NONE ]

@AccessControl.authorizationCheck: #MANDATORY

@EndUserText.label: 'Financial Transaction Rating'

@Metadata.ignorePropagatedAnnotations: true

@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #L, dataClass: #MASTER }

@VDM.viewType: #BASIC

define view entity I_FinancialTransactionRating

  as select from rtgt_fin_trans as FinTransRating

  association [0..1] to I_CompanyCode            as _CompanyCode     on  $projection.CompanyCode = _CompanyCode.CompanyCode
  association [0..1] to I_FinancialTransaction   as _FinTrans        on  $projection.CompanyCode          = _FinTrans.CompanyCode
                                                                     and $projection.FinancialTransaction = _FinTrans.FinancialTransaction

  association [1..1] to I_BPRatingProcedureGrade as _Rating          on  $projection.FinancialTransactionRating = _Rating.BusinessPartnerRatingGrade
                                                                     and $projection.FinTransRatingProcedure    = _Rating.BusinessPartnerRatingProcedure
  association [1..1] to I_BPRatingProcedure      as _RatingProcedure on  $projection.FinTransRatingProcedure = _RatingProcedure.BusinessPartnerRatingProcedure

{
  key FinTransRating.company_code                                                    as CompanyCode,
  key FinTransRating.fin_trans                                                       as FinancialTransaction,
      @ObjectModel.foreignKey.association: '_RatingProcedure'
  key cast(FinTransRating.grade_method as ftr_rating_procedure preserving type)      as FinTransRatingProcedure,
  key cast(FinTransRating.valid_from as ftr_rating_valid_from_date preserving type ) as FinTransRatgValidityFromDate,
      cast(FinTransRating.valid_to as ftr_rating_valid_to_date preserving type)      as FinTransRatingValidityToDate,
      cast(FinTransRating.entered_on as ftr_rating_entered_on_date preserving type ) as FinTransRatingEnteredOnDate,
      @ObjectModel.foreignKey.association: '_Rating'
      cast(FinTransRating.grade as ftr_rating preserving type )                      as FinancialTransactionRating,
      cast(FinTransRating.tendency as ftr_rating_trend preserving type )             as FinTransRatingTrend,
      cast(FinTransRating.text as ftr_rating_description preserving type )           as FinTransRatingDescription,

      _Rating,
      _RatingProcedure,
      _CompanyCode,
      _FinTrans
}