I_FINANCIALSTATEMENTITEM

CDS View

Items in Financial Statement Version

I_FINANCIALSTATEMENTITEM is a CDS View in S/4HANA. Items in Financial Statement Version. It contains 8 fields. 10 CDS views read from this table.

Used by 10 CDS view(s) 8 fields

CDS Views using this table (10)

ViewTypeJoinVDMDescription
P_CN_CADEFinStmntItemMapping view from COMPOSITE CADE - Financial Statement Item Mapping Leaf Item
P_CN_CADEFinStmntItemMapping view left_outer COMPOSITE CADE - Financial Statement Item Mapping Leaf Item
P_CN_CADEFSVITMWPrefix view from CONSUMPTION CADE FSV Item with Prefix
P_CN_CADEFSVITMWPrefix2 view from COMPOSITE Financial Statement Item with Prefix for CADE 2
P_CN_CADEGLAccountForBalance view from COMPOSITE CADE GL Account Structure for Balance
P_FinStmtHierarchy view from BASIC Financial Statement Hierarchy (Items +Leaves)
P_FinStmtLeafItem view from BASIC Fin Statement Leaf Item (with Parent/Child info)
P_FinStmtLeafWithFuncArea view left_outer BASIC Financial Statement Leaf with assigned Functional Area
P_FinStmtLeafWithGLAcct view left_outer BASIC Fin Statement Item with G/L Account (assigned & unassigned)
P_FSVHierarchy view_entity from BASIC FSV Hierarchy

Fields (8)

KeyField CDS FieldsUsed in Views
KEY FinancialStatementItem ergsl,FinancialStatementItem,GLAccountWOPrefix 4
KEY FinancialStatementVariant FinancialStatementVariant,versn 4
ChildNode child 2
HierarchyNode id,parent 5
NodeType type 2
OffsettingItem ergs2 1
ParentNode parent 2
SiblingNode nextn 2 
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #BASIC
@EndUserText.label: 'Items in Financial Statement Version'
@AbapCatalog.sqlViewName: 'IFIFSITM'
@Analytics: { dataCategory: #DIMENSION, dataExtraction.enabled: true }
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'HierarchyNode'
@ObjectModel.usageType: {
  serviceQuality: #A,
  sizeCategory: #M,
  dataClass: #ORGANIZATIONAL
}
@AbapCatalog.preserveKey:true 
@Metadata.allowExtensions:true
define view I_FinancialStatementItem
  as select from    fagl_011pc

    left outer join fagl_011vc on  fagl_011pc.versn = fagl_011vc.versn
                               and fagl_011pc.ergsl = fagl_011vc.ergs1

  association [0..*] to I_FinancialStatementItemText as _Text                      on  $projection.FinancialStatementVariant = _Text.FinancialStatementVariant
                                                                                   and $projection.FinancialStatementItem    = _Text.FinancialStatementItem

  association [0..1] to I_FinancialStatementItem     as _OffsettingItem            on  $projection.FinancialStatementVariant = _OffsettingItem.FinancialStatementVariant
                                                                                   and $projection.OffsettingItem            = _OffsettingItem.FinancialStatementItem

  association [0..1] to I_FinancialStatementItem     as _ParentItem                on  $projection.FinancialStatementVariant = _ParentItem.FinancialStatementVariant
                                                                                   and $projection.ParentNode                = _ParentItem.HierarchyNode

  association [0..1] to I_FinancialStatementVersion  as _FinancialStatementVersion on  $projection.FinancialStatementVariant = _FinancialStatementVersion.FinancialStatementVariant

{
      @ObjectModel.text.association: '_Text'
      @ObjectModel.foreignKey.association: '_FinancialStatementVersion'
  key fagl_011pc.versn as FinancialStatementVariant,
  key id               as HierarchyNode,
      type             as NodeType,
      @ObjectModel.text.association: '_Text'
      ergsl            as FinancialStatementItem,
      parent           as ParentNode,
      child            as ChildNode,
      nextn            as SiblingNode,
      stufe            as FinStatementHierarchyLevelVal,
      @Semantics.businessDate.lastChangedAt: true
      aedat            as LastChangeDate,
      @Semantics.user.id: true
      usnam            as ResponsiblePerson,

      fagl_011vc.ergs2 as OffsettingItem,

      /* Associations */
      _Text,
      _OffsettingItem,
      _ParentItem,
      _FinancialStatementVersion
}

Learn More