I_FINTRANSOVERALLVIEW

CDS View

Financial Transaction Overall

I_FINTRANSOVERALLVIEW is a CDS View in S/4HANA. Financial Transaction Overall. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_FinancialTransactionTP view_entity from TRANSACTIONAL Financial Transaction - TP 
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AbapCatalog.compiler.compareFilter:true
@AbapCatalog.sqlViewName: 'IFINTRANOVALL'
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Financial Transaction Overall'
@ObjectModel.representativeKey: 'FinancialTransaction'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@VDM.viewType: #COMPOSITE

define view I_FinTransOverallView
  as select from           I_FinancialTransaction        as FinancialTransaction
    inner join             I_FinTransActivity            as CurrentActivity on  FinancialTransaction.CompanyCode                = CurrentActivity.CompanyCode
                                                                            and FinancialTransaction.FinancialTransaction       = CurrentActivity.FinancialTransaction
                                                                            and FinancialTransaction.FinInstrLastActiveActivity = CurrentActivity.FinancialInstrumentActivity
    left outer to one join P_FinTransSglExtTrdIdentifier as TradeIdentifier on  FinancialTransaction.CompanyCode          = TradeIdentifier.CompanyCode
                                                                            and FinancialTransaction.FinancialTransaction = TradeIdentifier.FinancialTransaction

  association [1..1] to I_FinTransAttribute           as _Attribute             on  $projection.CompanyCode          = _Attribute.CompanyCode
                                                                                and $projection.FinancialTransaction = _Attribute.FinancialTransaction
  association [1..1] to I_FinTransAdditionalAttribute as _AdditionalAttribute   on  $projection.CompanyCode          = _AdditionalAttribute.CompanyCode
                                                                                and $projection.FinancialTransaction = _AdditionalAttribute.FinancialTransaction
  association [1..*] to I_FinTransMainFlow            as _MainFlow              on  $projection.CompanyCode          = _MainFlow.CompanyCode
                                                                                and $projection.FinancialTransaction = _MainFlow.FinancialTransaction
  association [0..*] to I_FinTransAdditionalFlow      as _AdditionalFlow        on  $projection.CompanyCode          = _AdditionalFlow.CompanyCode
                                                                                and $projection.FinancialTransaction = _AdditionalFlow.FinancialTransaction
  association [1..*] to I_FinTransInterestCondition   as _InterestCondition     on  $projection.CompanyCode          = _InterestCondition.CompanyCode
                                                                                and $projection.FinancialTransaction = _InterestCondition.FinancialTransaction
  association [0..*] to I_FinTransInterestAdjmtCndn   as _AdjustmentCondition   on  $projection.CompanyCode          = _AdjustmentCondition.CompanyCode
                                                                                and $projection.FinancialTransaction = _AdjustmentCondition.FinancialTransaction
  association [0..*] to I_FinTransRepaymentCndn       as _RepaymentCondition    on  $projection.CompanyCode          = _RepaymentCondition.CompanyCode
                                                                                and $projection.FinancialTransaction = _RepaymentCondition.FinancialTransaction
  association [0..*] to I_FinTransAccumulatingCndn    as _AccumulatingCondition on  $projection.CompanyCode          = _AccumulatingCondition.CompanyCode
                                                                                and $projection.FinancialTransaction = _AccumulatingCondition.FinancialTransaction
  association [0..*] to I_FinTransAccruedIntrstCndn   as _AccruedCondition      on  $projection.CompanyCode          = _AccruedCondition.CompanyCode
                                                                                and $projection.FinancialTransaction = _AccruedCondition.FinancialTransaction

{
  key  FinancialTransaction.CompanyCode,
  key  FinancialTransaction.FinancialTransaction,
       FinancialTransaction.FinancialInstrProductCategory,
       CurrentActivity.FinancialInstrumentActivity,
       FinancialTransaction.FinancialInstrumentStatus,
       FinancialTransaction.Counterparty,
       CurrentActivity.FinTransActyConclusionDate,
       CurrentActivity.FinTransActyConclusionTime,
       CurrentActivity.FinTransActyConclusionTimeZone,
       CurrentActivity.FinInstrExternalReference,
       FinancialTransaction.MarketIdentifierCode,
       CurrentActivity.Trader,
       CurrentActivity.FinancialInstrContactPerson,
       FinancialTransaction.CreatedByUser,
       FinancialTransaction.FinTransCreationDate,
       FinancialTransaction.FinTransCreationTime,
       FinancialTransaction.LastChangedByUser,
       FinancialTransaction.LastChangeDate,
       FinancialTransaction.FinInstrumentLastChangedTime,
       FinancialTransaction.FinancialInstrumentProductType,
       FinancialTransaction.FinancialInstrTransactionType,
       TradeIdentifier.TradeLegalBasis,
       TradeIdentifier.ExternalTradeIdentifier,
       FinancialTransaction.ClassificationOfFinInstr,
       FinancialTransaction.TreasuryFinancialObject, 

       _Attribute,
       _AdditionalAttribute,
       _MainFlow,
       _AdditionalFlow,
       _InterestCondition,
       _AdjustmentCondition,
       _RepaymentCondition,
       _AccumulatingCondition,
       _AccruedCondition
}

Learn More