I_FINTRANSACTIVITY
Financial Transaction Activity
I_FINTRANSACTIVITY is a CDS View in S/4HANA. Financial Transaction Activity. It contains 57 fields. 9 CDS views read from this table.
CDS Views using this table (9)
| View | Type | Join | VDM | Description |
|---|---|---|---|---|
| I_CmmdtyHdgFinTransaction | view | inner | COMPOSITE | Basic for Financial Transaction |
| I_CmmdtyHedgeTransFlowActivity | view | inner | COMPOSITE | Financial Transaction Flow |
| I_FinTransAttribute | view | inner | COMPOSITE | Financial Transaction Attribute |
| I_FinTransContractActivity | view | from | COMPOSITE | Financial Transaction Contract Activity |
| I_FinTransCurrentActivity | view | from | COMPOSITE | Financial Transaction Current Activity |
| I_FinTransOverallView | view | inner | COMPOSITE | Financial Transaction Overall |
| P_CmmdtyFinancialTransaction | view | inner | COMPOSITE | Commodity Financial Transaction |
| P_FinTransOpenFlowBusVol | view | inner | COMPOSITE | The Business Volume for Open Trans Flow |
| P_FXOptionTransBusVol | view | inner | COMPOSITE | Business Vol for FX Option Transaction |
Fields (57)
| Key | Field | CDS Fields | Used in Views |
|---|---|---|---|
| KEY | CompanyCode | CompanyCode | 2 |
| KEY | FinancialInstrumentActivity | FinancialInstrumentActivity | 3 |
| KEY | FinancialTransaction | FinancialTransaction | 2 |
| _ActivityCategory | _ActivityCategory | 1 | |
| _AdvisingBankBP | _AdvisingBankBP | 1 | |
| _ApplicantBP | _ApplicantBP | 1 | |
| _BeneficiaryBP | _BeneficiaryBP | 1 | |
| _CntrconfStatus | _CntrconfStatus | 1 | |
| _CompanyCode | _CompanyCode | 2 | |
| _ConfStatus | _ConfStatus | 1 | |
| _FinTrans | _FinTrans | 2 | |
| _FixRef | _FixRef | 1 | |
| _FollowingCurrency | _FollowingCurrency | 1 | |
| _IssuingBankBP | _IssuingBankBP | 1 | |
| _LeadingCurrency | _LeadingCurrency | 1 | |
| _RevReason | _RevReason | 1 | |
| _TimeZone | _TimeZone | 3 | |
| EffectiveInterestMethod | EffectiveInterestMethod | 1 | |
| EffectiveInterestRate | EffectiveInterestRate | 1 | |
| ExchangeRate | ExchangeRate | 2 | |
| FinancialInstrActivityCategory | FinancialInstrActivityCategory | 2 | |
| FinancialInstrContactPerson | FinancialInstrContactPerson | 2 | |
| FinInstrExternalReference | FinInstrExternalReference | 2 | |
| FinTransActyConclusionDate | FinTransActyConclusionDate,FinTransContractDate,FinTransContractStartDate | 5 | |
| FinTransActyConclusionTime | FinTransActyConclusionTime,FinTransContractStartTime | 5 | |
| FinTransActyConclusionTimeZone | FinTransActyConclusionTimeZone | 4 | |
| FinTransCntrconfCreatedByUser | FinTransCntrconfCreatedByUser | 1 | |
| FinTransCntrconfDate | FinTransCntrconfDate | 1 | |
| FinTransCntrconfStatus | FinTransCntrconfStatus | 1 | |
| FinTransConfirmationDate | FinTransConfirmationDate | 1 | |
| FinTransConfirmationStatus | FinTransConfirmationStatus | 1 | |
| FinTransConfirmedByUser | FinTransConfirmedByUser | 1 | |
| FinTransExerciseDate | FinTransExerciseDate | 1 | |
| FinTransFixingDate | FinTransFixingDate | 1 | |
| FinTransIntrstHndlgAtRollover | FinTransIntrstHndlgAtRollover | 1 | |
| FinTransNoticeDate | FinTransNoticeDate | 2 | |
| FinTransOrderValidityEndDate | FinTransOrderValidityEndDate | 1 | |
| FinTransRolloverDate | FinTransRolloverDate | 2 | |
| FinTransTermCategory | FinTransTermCategory | 1 | |
| FinTransTermStartEndInclusive | FinTransTermStartEndInclusive | 1 | |
| FollowingCurrency | FollowingCurrency | 1 | |
| ForeignExchangeFixingReference | ForeignExchangeFixingReference | 1 | |
| LeadingCurrency | LeadingCurrency | 1 | |
| LetterOfCredit | LetterOfCredit | 1 | |
| RolloverDfrrdIntrstPyoutDte | RolloverDfrrdIntrstPyoutDte | 1 | |
| SpotExchangeRate | SpotExchangeRate | 1 | |
| SwapExchangeRate | SwapExchangeRate | 1 | |
| TermEndDate | TermEndDate | 2 | |
| TermEndDateIsInclusive | TermEndDateIsInclusive | 1 | |
| Trader | Trader | 2 | |
| TreasuryAdvisingBank | TreasuryAdvisingBank | 1 | |
| TreasuryApplicant | TreasuryApplicant | 1 | |
| TreasuryBeneficiary | TreasuryBeneficiary | 1 | |
| TreasuryIssuingBank | TreasuryIssuingBank | 1 | |
| TreasuryReversalReason | TreasuryReversalReason | 1 | |
| TrsyMnllyEnteredApplcntName | TrsyMnllyEnteredApplcntName | 1 | |
| TrsyMnllyEnteredBnfcyName | TrsyMnllyEnteredBnfcyName | 1 |
@AbapCatalog.sqlViewName: 'IFINTRANSACTY'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.buffering.status: #NOT_ALLOWED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Financial Transaction Activity'
@ObjectModel.representativeKey: 'FinancialInstrumentActivity'
@ObjectModel.usageType.dataClass: #MIXED
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@Metadata.allowExtensions:false
@Metadata.ignorePropagatedAnnotations: true // For C1-Release
@ObjectModel.supportedCapabilities: [#SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@VDM.viewType: #BASIC
define view I_FinTransActivity
as select from vtbfhazu as Activity
inner join at10 as TransactionType on Activity.sgsart = TransactionType.sgsart
and Activity.sfhaart = TransactionType.sfhaart
inner join tzpa as ProductType on Activity.sgsart = ProductType.gsart
left outer join tlct_activity as LetterOfCredit on Activity.bukrs = LetterOfCredit.bukrs
and Activity.rfha = LetterOfCredit.rfha
and Activity.rfhazu = LetterOfCredit.rfhazu
// dimensions, containing for example text fields
association [0..1] to I_CompanyCode as _CompanyCode on $projection.CompanyCode = _CompanyCode.CompanyCode
association [0..1] to I_FinancialTransaction as _FinTrans on $projection.CompanyCode = _FinTrans.CompanyCode
and $projection.FinancialTransaction = _FinTrans.FinancialTransaction
association [0..1] to I_FinTransActivityCategory as _ActivityCategory on $projection.CompanyCode = _ActivityCategory.CompanyCode
and $projection.FinancialTransaction = _ActivityCategory.FinancialTransaction
and $projection.FinancialInstrActivityCategory = _ActivityCategory.FinancialInstrActivityCategory
association [0..1] to I_TimeZone as _TimeZone on $projection.FinTransActyConclusionTimeZone = _TimeZone.TimeZoneID
association [0..1] to I_FXFixingReference as _FixRef on $projection.ForeignExchangeFixingReference = _FixRef.ForeignExchangeFixingReference
association [0..1] to I_TreasuryReversalReason as _RevReason on $projection.TreasuryReversalReason = _RevReason.TreasuryReversalReason
association [0..1] to I_FinTransConfStatus as _ConfStatus on $projection.FinTransConfirmationStatus = _ConfStatus.FinTransConfirmationStatus
association [0..1] to I_FinTransCntrconfStatus as _CntrconfStatus on $projection.FinTransCntrconfStatus = _CntrconfStatus.FinTransCntrconfStatus
association [0..1] to I_Currency as _LeadingCurrency on $projection.LeadingCurrency = _LeadingCurrency.Currency
association [0..1] to I_Currency as _FollowingCurrency on $projection.FollowingCurrency = _FollowingCurrency.Currency
association [0..1] to I_BusinessPartner as _ApplicantBP on $projection.TreasuryApplicant = _ApplicantBP.BusinessPartner
association [0..1] to I_BusinessPartner as _BeneficiaryBP on $projection.TreasuryBeneficiary = _BeneficiaryBP.BusinessPartner
association [0..1] to I_BusinessPartner as _AdvisingBankBP on $projection.TreasuryAdvisingBank = _AdvisingBankBP.BusinessPartner
association [0..1] to I_BusinessPartner as _IssuingBankBP on $projection.TreasuryIssuingBank = _IssuingBankBP.BusinessPartner
association [0..1] to I_FinInstrActivityCategory as _ActivityCategory2 on $projection.FinancialInstrProductCategory = _ActivityCategory2.FinancialInstrProductCategory
and $projection.FinInstrTransactionCategory = _ActivityCategory2.FinInstrTransactionCategory
and $projection.FinancialInstrActivityCategory = _ActivityCategory2.FinancialInstrActivityCategory
{
// Exposed fields
@ObjectModel.foreignKey.association: '_CompanyCode'
key Activity.bukrs as CompanyCode,
@ObjectModel.foreignKey.association: '_FinTrans'
key Activity.rfha as FinancialTransaction,
key Activity.rfhazu as FinancialInstrumentActivity,
@ObjectModel.foreignKey.association: '_ActivityCategory'
Activity.sfgzustt as FinancialInstrActivityCategory,
Activity.delfz as TermEndDate,
cast( case when Activity.delfz is initial
then 'X'
else ''
end as ftr_term_category ) as FinTransTermCategory,
Activity.sincle as TermEndDateIsInclusive,
// Because of the legacy GFN TermEndDateIsInclusive is not accurate, the sincle will not store a boolean value, but a char1 data.
// To aviod the C1 release incompatible change, a new field FinTransTermStartEndInclusive is added here
cast( Activity.sincle as ftr_term_start_end_inclusive preserving type ) as FinTransTermStartEndInclusive,
Activity.notice_date as FinTransNoticeDate,
cast(Activity.dvtrab as ftr_acty_conclusion_dte preserving type ) as FinTransActyConclusionDate,
Activity.tvtrab as FinTransActyConclusionTime,
@ObjectModel.foreignKey.association: '_TimeZone'
Activity.zvtrab as FinTransActyConclusionTimeZone,
case when Activity.sfgzustt = '11'
or Activity.sfgzustt = '21'
then Activity.dblfz
else cast('00000000' as tb_dblfz)
end as FinTransRolloverDate,
@EndUserText.label: 'Exercise Date'
@EndUserText.quickInfo: 'Exercise Date'
case when Activity.sfgzustt = '41'
or Activity.sfgzustt = '51'
or Activity.sfgzustt = '61'
or Activity.sfgzustt = '71'
or Activity.sfgzustt = '42'
or Activity.sfgzustt = '52'
or Activity.sfgzustt = '62'
or Activity.sfgzustt = '72'
then Activity.delfz
else cast('00000000' as tb_delfz)
end as FinTransExerciseDate,
Activity.limitdat as FinTransOrderValidityEndDate,
Activity.dfix as FinTransFixingDate,
@ObjectModel.foreignKey.association: '_FixRef'
Activity.fixing_ref_id as ForeignExchangeFixingReference,
Activity.rdealer as Trader,
Activity.gsppart as FinancialInstrContactPerson,
Activity.nordext as FinInstrExternalReference,
@ObjectModel.foreignKey.association: '_RevReason'
Activity.sstogrd as TreasuryReversalReason,
@ObjectModel.foreignKey.association: '_ConfStatus'
Activity.sconfirm as FinTransConfirmationStatus,
Activity.dexdat as FinTransConfirmationDate,
@EndUserText.label: 'Confirmed By User'
Activity.uexnam as FinTransConfirmedByUser,
@ObjectModel.foreignKey.association: '_CntrconfStatus'
Activity.sreconfirm as FinTransCntrconfStatus,
Activity.dredat as FinTransCntrconfDate,
@EndUserText.label: 'Conterconfirmed By User'
Activity.urenam as FinTransCntrconfCreatedByUser,
@ObjectModel.foreignKey.association: '_LeadingCurrency'
@Semantics.currencyCode: true
Activity.wlwaers as LeadingCurrency,
@ObjectModel.foreignKey.association: '_FollowingCurrency'
@Semantics.currencyCode: true
Activity.wfwaers as FollowingCurrency,
Activity.kkurs as ExchangeRate,
Activity.kkassa as SpotExchangeRate,
Activity.kswap as SwapExchangeRate,
Activity.kwliqui as LiquidityEffectValue,
case
when (Activity.wlwaers is not initial and Activity.wfwaers is not initial)
then cast( concat(concat(Activity.wlwaers, '/'), Activity.wfwaers) as ftr_curr_pair)
end as CurrencyPair,
Activity.peffzins as EffectiveInterestRate,
Activity.seffmeth as EffectiveInterestMethod,
Activity.sznspro as FinTransIntrstHndlgAtRollover,
Activity.dznsstd as RolloverDfrrdIntrstPyoutDte,
LetterOfCredit.lc_number as LetterOfCredit,
@ObjectModel.foreignKey.association: '_ApplicantBP'
LetterOfCredit.applicant as TreasuryApplicant,
@ObjectModel.foreignKey.association: '_BeneficiaryBP'
LetterOfCredit.benficiary as TreasuryBeneficiary,
cast( case when ( LetterOfCredit.man_benficiary is initial
and TransactionType.sfgtyp = '100' )
then LetterOfCredit.man_comp_name
else ''
end as ftr_man_bene_name ) as TrsyMnllyEnteredBnfcyName,
cast( case when ( LetterOfCredit.man_applicant is initial
and TransactionType.sfgtyp = '200' )
then LetterOfCredit.man_comp_name
else ''
end as ftr_man_appl_name ) as TrsyMnllyEnteredApplcntName,
@ObjectModel.foreignKey.association: '_AdvisingBankBP'
LetterOfCredit.advising_bank as TreasuryAdvisingBank,
@ObjectModel.foreignKey.association: '_IssuingBankBP'
LetterOfCredit.issuing_bank as TreasuryIssuingBank,
LetterOfCredit.bg_number as BankGuaranteeNumber,
LetterOfCredit.bg_type as BankGuaranteeType,
TransactionType.sfgtyp as FinInstrTransactionCategory,
ProductType.sanlf as FinancialInstrProductCategory,
//exposed dimensions, containing for example text fields
_CompanyCode,
_FinTrans,
_ActivityCategory,
_TimeZone,
_FixRef,
_RevReason,
_ConfStatus,
_CntrconfStatus,
_LeadingCurrency,
_FollowingCurrency,
_ApplicantBP,
_BeneficiaryBP,
_AdvisingBankBP,
_IssuingBankBP,
_ActivityCategory2
}
//restriction: do not provide interest rate adjustment activities
where
Activity.sfgzustt <> '70'