I_FMEANODETP

CDS View

Transactional Processing for FMEA Node

I_FMEANODETP is a CDS View in S/4HANA. Transactional Processing for FMEA Node. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_FMEAMngNode view_entity projection CONSUMPTION FMEA Node Projection 
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Transactional Processing for FMEA Node'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
@AccessControl.privilegedAssociations:  [ '_FMEANodeDescription' ]
define view entity I_FMEANodeTP
  as select from I_FMEANode
  association        to parent I_FailureModeEffectAnalysisTP as _FailureModeEffectAnalysisTP on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysisTP.FMEAHeaderUUID
  composition [0..*] of I_FMEATaskTP                         as _FMEATask
  composition [0..*] of I_FMEANodeTextTP                     as _FMEANodeText
  composition [0..*] of I_FMEANodeDescriptionTextTP          as _FMEANodeDescription
  // Associations

  association [0..1] to I_FMEAValnProfileValuation           as _FMEAValnProfileValuation    on  $projection.FMEAValuationProfile     = _FMEAValnProfileValuation.FMEAValuationProfile
                                                                                             and $projection.FMEAValnProfileValuation = _FMEAValnProfileValuation.FMEAValnProfileValuation
  association [0..1] to I_FMEANodeTextTP                     as _FMEANodeTextCurrent         on  $projection.FMEANodeUUID      = _FMEANodeTextCurrent.FMEANodeUUID
                                                                                             and _FMEANodeTextCurrent.Language = $session.system_language
  association [0..1] to I_FMEANodeTextTP                     as _FMEANodeTextOriginal        on  $projection.FMEANodeUUID     = _FMEANodeTextOriginal.FMEANodeUUID
                                                                                             and $projection.OriginalLanguage = _FMEANodeTextOriginal.Language

  //  association [0..1] to I_FMEANodeDescriptionTextTP as _FMEANodeLangDepdntDescription on  $projection.FMEANodeUUID = _FMEANodeLangDepdntDescription.FMEANodeUUID

  //                                                                                      and _FMEANodeLangDepdntDescription.Language  = $session.system_language

{
  key FMEANodeUUID,
      _FMEANodeAssignment.FMEANode,
      FMEAHeaderUUID,
      _FMEAHeader.FMEAHeader,
      FMEAHierarchyProfile,
      FMEANodeType,
      FMEANodeListType,
      FMEAItemType,
      _FMEANodeHierarchy.FMEAParentNodeUUID,
      FMEANodeReferenceUUID,
      FMEANodeReferenceObjectType,
      FMEAValuationProfile,
      FMEAHasValuation,
      FMEAValnProfileValuation,
      FMEAValuationScoreValue,
      FMEAValuationResultValue,
      InspectionCatalog,
      InspectionCodeGroup,
      InspectionCode,
      DefectCodeCatalog,
      DefectCauseCodeCatalog,
      FMEAFunctionCodeCatalog,
      FMEAEffectCodeCatalog,
      QualityTaskCodeCatalog,
      InspectionSpecification,
      InspectionSpecificationPlant,
      InspSpecImportanceCode,
      FMEACharacteristicType,
      ChangedDateTime,
      OriginalLanguage,
      case when _FMEANodeTextCurrent.FMEANodeDescription is not null then _FMEANodeTextCurrent.FMEANodeDescription
      else _FMEANodeTextOriginal.FMEANodeDescription
      end as FMEANodeDescription,
      //Associations

      _FailureModeEffectAnalysisTP,
      _FailureModeEffectAnalysis,
      _FMEANodeHierarchy,
      _FMEANodeChild,
      _FMEAValuationProfile,
      _FMEAValnProfileValuation,
      _FMEAReferenceAssignment,
      _InspectionCodeGroup,
      _InspectionCode,
      _FMEATask,
      _FMEANodeText,
      _FMEANodeTextCurrent,
      _FMEANodeTextOriginal,
      _FMEANodeDescription //,

      //  _FMEANodeLangDepdntDescription

}

Learn More