I_FMEAFUNCTIONNODETP

CDS View

Transactional Processing for FMEA Node

I_FMEAFUNCTIONNODETP is a CDS View in S/4HANA. Transactional Processing for FMEA Node. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_FMEAMngFunction view_entity projection CONSUMPTION FMEA Function Projection 
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_LastChangedByUserContactCard', '_CreatedByUserContactCard']
@EndUserText.label: 'Transactional Processing for FMEA Node'
@VDM.viewType: #TRANSACTIONAL
@VDM.lifecycle.contract.type: #SAP_INTERNAL_API
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view entity I_FMEAFunctionNodeTP
  as select from I_FMEANode
  association        to parent I_FailureModeEffectAnalysisTP as _FailureModeEffectAnalysisTP   on  $projection.FMEAHeaderUUID = _FailureModeEffectAnalysisTP.FMEAHeaderUUID
  association [0..*] to I_FMEANodeText                       as _FMEANodeText                  on  $projection.FMEANodeUUID = _FMEANodeText.FMEANodeUUID
  association [0..*] to I_FMEANodeText                       as _FMEAParentNodeText            on  $projection.fmeaparentnodeuuid = _FMEAParentNodeText.FMEANodeUUID
  association [0..1] to I_FMEANodeTextTP                     as _FMEANodeTextCurrentLangu      on  $projection.FMEANodeUUID           = _FMEANodeTextCurrentLangu.FMEANodeUUID
                                                                                               and _FMEANodeTextCurrentLangu.Language = $session.system_language
  association [0..1] to I_FMEANodeTextTP                     as _FMEANodeTextOriginal          on  $projection.FMEANodeUUID     = _FMEANodeTextOriginal.FMEANodeUUID
                                                                                               and $projection.OriginalLanguage = _FMEANodeTextOriginal.Language
  association [0..1] to I_FMEALongText                       as _FMEANodeLangDepdntDescription on  $projection.FMEANodeUUID                              = _FMEANodeLangDepdntDescription.FMEANodeUUID
                                                                                               and _FMEANodeLangDepdntDescription.LongTextInternalNumber = 1
                                                                                               and _FMEANodeLangDepdntDescription.Language               = $session.system_language
{
  key FMEANodeUUID,
      _FMEANodeAssignment.FMEANode,
      FMEAHeaderUUID,
      FMEANodeType,
      FMEANodeListType,
      FMEAItemType,
      FMEANodeReferenceUUID,
      FMEANodeReferenceObjectType,
      _FMEANodeHierarchy.FMEAParentNodeUUID,
      cast( _FMEANodeAssignment.CreatedByUser as plmt_created_by preserving type )     as CreatedByUser,
      cast( _FMEANodeAssignment.LastChangedByUser as plmt_changed_by preserving type ) as LastChangedByUser,
      ChangedDateTime,
      _FMEANodeLangDepdntDescription.FMEALongText                                      as FMEANodeLongTextDescription,
      OriginalLanguage,
      case when _FMEANodeTextCurrentLangu.FMEANodeDescription is not null then _FMEANodeTextCurrentLangu.FMEANodeDescription
      else _FMEANodeTextOriginal.FMEANodeDescription
      end                                                                              as FMEANodeDescription,
      //Associations

      _FailureModeEffectAnalysisTP,
      _FailureModeEffectAnalysis,
      _FMEANodeAssignment,
      _FMEANodeHierarchy,
      _FMEANodeChild,
      _FMEATask,
      _FMEANodeText,
      _FMEAParentNodeText,
      _FMEAReferenceAssignment,
      _FMEANodeAssignment._CreatedByUserContactCard,
      _FMEANodeAssignment._LastChangedByUserContactCard

}
where
        FMEAItemType                = '801'
  or    FMEAItemType                = '812'
  or    FMEAItemType                = '814'
  or(
        FMEAItemType                = '802'
    and FMEANodeReferenceObjectType = ''
  )

Learn More