I_EXISTENCECHECKONMATLDOCITEM

CDS View

Existence Check on Material Doc Item

I_EXISTENCECHECKONMATLDOCITEM is a CDS View in S/4HANA. Existence Check on Material Doc Item. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_ExistenceCheckOnMaterialDoc view_entity from COMPOSITE Existence Check on Material Document 
//-- This CDS View is intended to check if Material Document Item consists specific fields              --

//-- At the moment based on Material Document Number, Material Document Item and Material Document Year --

//-- existence of Serial Number is being check, this is open for any further improvements/additions     --


@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl: { authorizationCheck: #NOT_REQUIRED,
                  personalData.blocking: #NOT_REQUIRED }
@EndUserText.label: 'Existence Check on Material Doc Item'
@Metadata.ignorePropagatedAnnotations: true
@VDM.viewType: #COMPOSITE
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #TRANSACTIONAL
}
define view entity I_ExistenceCheckOnMatlDocItem
  as select from I_MaterialDocumentRecord
  association [0..*] to I_MaintObjListMaterialDocument as _SerialNo   on  $projection.MaterialDocument     = _SerialNo.MaterialDocument
                                                                      and $projection.MaterialDocumentYear = _SerialNo.MaterialDocumentYear
                                                                      and $projection.MaterialDocumentItem = _SerialNo.MaterialDocumentItem
  association [0..1] to I_SrlzdMatlDocItmsFromPInv     as _SerialNoPI on  $projection.MaterialDocument     = _SerialNoPI.MaterialDocument
                                                                      and $projection.MaterialDocumentYear = _SerialNoPI.MaterialDocumentYear
                                                                      and $projection.MaterialDocumentItem = _SerialNoPI.MaterialDocumentItem
{
  key MaterialDocument,
  key MaterialDocumentItem,
  key MaterialDocumentYear,
      @Semantics.booleanIndicator: true
      case when _SerialNo.MaterialDocument is null then '' else 'X' end    as MatlDocItmHasMatlDocSrlNmbr,
      @Semantics.booleanIndicator: true
      case when _SerialNoPI.MaterialDocument is null  then '' else 'X' end as MatlDocItmHasPhysInvtrySrlNmbr
}
group by
  MaterialDocument,
  MaterialDocumentItem,
  MaterialDocumentYear,
  _SerialNo.MaterialDocument,
  _SerialNoPI.MaterialDocument

Learn More