I_EXCHANGERATEFACTORSRAWDATA

CDS View

Exchange Rate Factors Raw Data

I_EXCHANGERATEFACTORSRAWDATA is a CDS View in S/4HANA. Exchange Rate Factors Raw Data. It contains 5 fields. 6 CDS views read from this table.

Used by 6 CDS view(s) 5 fields

CDS Views using this table (6)

ViewTypeJoinVDMDescription
P_AR_ConversionFactors view_entity from CONSUMPTION Argentina Exchange Rate Conversion Factors
P_ExchangeRateFactorsByDate view_entity from COMPOSITE Get rate factors by date
P_ID_ExchangeRateFactors view_entity from COMPOSITE Exchange Rate Factors for IDR
P_ID_ExchangeRateFactorsByDate view_entity from COMPOSITE Exchange Rate Factors by Date for IDR
P_PE_PurLdgrAltExchRateType view_entity from CONSUMPTION Purchase Ledger Alternative Exchange Rate Type
P_RO_SAFTExchRateFactorDate view_entity from CONSUMPTION Non RO TaxCodes

Fields (5)

KeyField CDS FieldsUsed in Views
KEY ExchangeRateType ExchangeRateType 4
KEY SourceCurrency SourceCurrency 4
KEY TargetCurrency TargetCurrency 4
AlternativeExchangeRateType AlternativeExchangeRateType 1
ValidityStartDate ValidityStartDate 1 
@AbapCatalog.sqlViewName: 'ICURRCONVFACTRAW'
@EndUserText.label: 'Exchange Rate Factors Raw Data'

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #NOT_REQUIRED
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@Metadata.ignorePropagatedAnnotations: true 
@ClientHandling.type: #INHERITED 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #CUSTOMIZING 

@AbapCatalog.buffering.status: #ACTIVE        
@AbapCatalog.buffering.type: #GENERIC
@AbapCatalog.buffering.numberOfKeyFields: 1
@Analytics.internalName: #LOCAL  

//@ObjectModel.representativeKey: ['ValidityStartDate']

@Analytics:{
//    dataCategory: #DIMENSION,

    dataExtraction: { enabled: true } }

define view I_ExchangeRateFactorsRawData as select from tcurf 
association [0..1] to I_ExchangeRateType as _ExchangeRateType on $projection.ExchangeRateType = _ExchangeRateType.ExchangeRateType
association [0..1] to I_Currency  as _SourceCurrency on $projection.SourceCurrency = _SourceCurrency.Currency
association [0..1] to I_Currency  as _TargetCurrency on $projection.TargetCurrency = _TargetCurrency.Currency
{
    //TCURF 

   @ObjectModel.foreignKey.association:'_ExchangeRateType'
    key kurst as ExchangeRateType, 
    @ObjectModel.foreignKey.association:'_SourceCurrency'    
    key fcurr as SourceCurrency, 
    @ObjectModel.foreignKey.association:'_TargetCurrency'    
    key tcurr as TargetCurrency, 
//    key cast ( gdatu as fis_datbi ) as ValidityStartDate, 

  key case gdatu
  when '' then cast('00000000' as abap.dats) 
  else cast(substring(cast(99999999 - cast(cast(gdatu as abap.numc(8)) as abap.int4) as abap.char(20)), 1, 8) as abap.dats)  
  end as ValidityStartDate,
    ffact as NumberOfSourceCurrencyUnits, 
    tfact as NumberOfTargetCurrencyUnits , 
    abwct as AlternativeExchangeRateType, 
    abwga as AltvExchangeRateTypeValdtyDate,
    _ExchangeRateType, _SourceCurrency, _TargetCurrency
        
}

Learn More