I_EXCHANGERATE

CDS View

Exchange Rate

I_EXCHANGERATE is a CDS View in S/4HANA. Exchange Rate. It contains 5 fields. 12 CDS views read from this table.

Used by 12 CDS view(s) 5 fields

CDS Views using this table (12)

ViewTypeJoinVDMDescription
A_MMPurgExchangeRate view from CONSUMPTION Exchange Rate
C_COExchangeRate view from CONSUMPTION CO Exchange Rate
I_COExchangeRateEffectiveDate view from COMPOSITE CO Exchange Rate Effective Date
I_ExternalTaxExchangeRateVH view_entity from BASIC Exchange rate
I_FXSpotRate view inner COMPOSITE FX Spot Rate Values
I_MktDataFXRateCube view from COMPOSITE Market Data FX Rate - Cube
P_COExchangeRate view from BASIC CO Exchange Rate
P_COExchangeRateEffectiveDate view from BASIC CO Exchange Rate Effective Date
P_FXSpotRate view inner COMPOSITE FX Spot Rates Refined
P_FXSpotRateFavorite view inner COMPOSITE FX Spot Rates Refined
P_MMPurExchangeRate view from COMPOSITE Material Management Purchasing ExchangeRate
P_PE_PurLdgrAltExchRateType view_entity inner CONSUMPTION Purchase Ledger Alternative Exchange Rate Type

Fields (5)

KeyField CDS FieldsUsed in Views
KEY ExchangeRateEffectiveDate EffectiveDate,ExchangeRateEffectiveDate 2
KEY ExchangeRateType ExchangeRateType 4
KEY SourceCurrency LeadingCurrency,SourceCurrency 5
KEY TargetCurrency FollowingCurrency,TargetCurrency 5
EffectiveExchangeRate EffectiveExchangeRate,SpotExchangeRate 2 
@EndUserText.label: 'Exchange Rate'
@Analytics: {dataCategory: #DIMENSION, dataExtraction.enabled: true}
@VDM.viewType: #BASIC 
@AbapCatalog.sqlViewName: 'IFIEXCHRATE'
@AccessControl.authorizationCheck: #NOT_REQUIRED
@ObjectModel.representativeKey: 'ExchangeRateEffectiveDate'
@ObjectModel.sapObjectNodeType.name: 'ExchangeRate'
@AbapCatalog.buffering.status: #NOT_ALLOWED        
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass:  #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.supportedCapabilities: [ #ANALYTICAL_DIMENSION,
                                      #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #EXTRACTION_DATA_SOURCE ]
@ObjectModel.modelingPattern: #NONE                                      
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true  


define view I_ExchangeRate
as select from tcurv inner join P_ExchangeRate3 as Union_1 
                 on  tcurv.kurst = Union_1.kurst
left outer join  tcurx
                 on  Union_1.fcurr = tcurx.currkey
left outer join  tcurx as Join_10
                 on  Union_1.tcurr = Join_10.currkey
association [0..*] to I_ExchangeRateTypeText as _Text on $projection.ExchangeRateType = _Text.ExchangeRateType
association [0..1] to I_ExchangeRateType as _ExchangeRateType on $projection.ExchangeRateType = _ExchangeRateType.ExchangeRateType
association [0..1] to I_Currency             as _SourceCurrency on $projection.SourceCurrency = _SourceCurrency.Currency
association [0..1] to I_Currency             as _TargetCurrency on $projection.TargetCurrency = _TargetCurrency.Currency
{
  @ObjectModel.text.association: '_Text'
  @ObjectModel.foreignKey.association: '_ExchangeRateType'
  key tcurv.kurst as ExchangeRateType,
  @ObjectModel.foreignKey.association: '_SourceCurrency'
  key Union_1.fcurr as SourceCurrency,
  @ObjectModel.foreignKey.association: '_TargetCurrency'
  key Union_1.tcurr as TargetCurrency,
  key cast(case Union_1.gdatu
  when '' then cast('00000000' as abap.dats) 
  else cast(substring(cast(99999999 - cast(Union_1.gdatu as abap.int4) as abap.char(20)), 1, 8) as abap.dats) 
  end as gdatu_date preserving type) as ExchangeRateEffectiveDate,
  
  Union_1.ukurs as ExchangeRate,

  Union_1.ffact as NumberOfSourceCurrencyUnits,

  Union_1.tfact as NumberOfTargetCurrencyUnits,

  Union_1.abwct as AlternativeExchangeRateType,

  Union_1.abwga as AltvExchangeRateTypeValdtyDate,

  tcurv.xinvr as InvertedExchangeRateIsAllowed,

  tcurv.bwaer as ReferenceCurrency,

  tcurv.gkuzu as BuyingRateAvgExchangeRateType,

  tcurv.bkuzu as SellingRateAvgExchangeRateType,

  tcurv.xfixd as FixedExchangeRateIsUsed,

  tcurv.xeuro as SpecialConversionIsUsed,

  tcurx.currdec as SourceCurrencyDecimals,

  Join_10.currdec as TargetCurrencyDecimals,
  
  Union_1.ExchRateIsIndirectQuotation,
  
  Union_1.AbsoluteExchangeRate,
  
  Union_1.EffectiveExchangeRate,
  
  Union_1.DirectQuotedEffectiveExchRate,
  
  Union_1.IndirectQuotedEffctvExchRate,
  
  _Text,
  _ExchangeRateType,
  _SourceCurrency,
  _TargetCurrency
};

Learn More