I_EQUIPMENTPRTBYINTERNALKEY

CDS View

Equipment PRT by internal key

I_EQUIPMENTPRTBYINTERNALKEY is a CDS View in S/4HANA. Equipment PRT by internal key. It contains 7 fields. 7 CDS views read from this table.

Used by 7 CDS view(s) 7 fields

CDS Views using this table (7)

ViewTypeJoinVDMDescription
I_BOOOpEquipmentPRTChangeState view inner COMPOSITE BOO Operation Equipment Prod. Resource/Tool Change State
I_EquipmentProdnRsceTool view from BASIC Equipment Production Resource Tool
P_MstrRcpOpEquipPRTAssgmt view_entity inner COMPOSITE Equipment PRT Assignment
P_TrackToolUsageOAPRT view from COMPOSITE PRT NAMES ASSIGNED TO OA
P_TrackToolUsageTTUCLAIMED view from COMPOSITE CLAIMED tools
R_ProdnRtgOpEquipPRTAssgmtTP view_entity inner TRANSACTIONAL Equipment PRT Assignment
R_ProdnRtgOpEquipPRTAssgmtTP_2 view_entity inner TRANSACTIONAL Equipment PRT Assignment

Fields (7)

KeyField CDS FieldsUsed in Views
KEY Equipment Equipment 4
ChangeNumber ChangeNumber 1
ProductionResourceInternalID ProductionResourceInternalID 1
ProductionResourceToolGroup1 ProductionResourceToolGroup1 1
ProductionResourceToolGroup2 ProductionResourceToolGroup2 1
ProductionResourceType ProductionResourceType 1
ProductionResourceUsage ProductionResourceUsage 1 
@AbapCatalog.sqlViewName: 'IPPEQUIPRTIK'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true 
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'ProductionResourceInternalID'
@ObjectModel.semanticKey: 'Equipment'
@Analytics.dataCategory: #DIMENSION
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Equipment PRT by internal key'
@Search.searchable: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType: { serviceQuality: #B, sizeCategory: #M, dataClass: #MASTER }
@Metadata.allowExtensions:true

define view I_EquipmentPRTByInternalKey
  as select from I_ProdnRsceToolMasterData as PRT
    inner join   crve_a on  crve_a.objty = PRT.ProductionResourceType
                        and crve_a.objid = PRT.ProductionResourceInternalID

  association [1..1] to I_Equipment              as _Equipment              on $projection.Equipment = _Equipment.Equipment

  association [1..1] to I_EquipmentProdnRsceTool as _EquipmentProdnRsceTool on $projection.Equipment = _EquipmentProdnRsceTool.Equipment

{
      @ObjectModel.foreignKey.association: '_ProductionResourceType'
  key PRT.ProductionResourceType,
  key PRT.ProductionResourceInternalID,
      @ObjectModel.foreignKey.association: '_EquipmentProdnRsceTool'
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      crve_a.equnr as Equipment,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      PRT.ProductionResourceToolGroup1,
      @Search: {defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.8}
      PRT.ProductionResourceToolGroup2,
      PRT.ProductionResourceUsage,
      PRT.ShopFloorRtgPRTIsRegistrable,
      ProdnRsceToolControlProfile,
      @ObjectModel.foreignKey.association: '_ChangeMaster'
      PRT.ChangeNumber,      
      ProdnRsceToolStandardTextCode,
      ProdnRsceToolTotQtyCalcFormula,
      ProdnRsceToolUsageQtyCalcFmla,
      StartDateOffsetReferenceCode,
      EndDateOffsetReferenceCode,
      ProdPRTLoadRecordsAreCreated,
      // Reference Indicators

      EndDateOffsetDurnIsReferenced,
      StartDateOffstDurnIsReferenced,
      EndDteOffstRefCodeIsReferenced,
      StartDateOffsetRefCodeIsRefcd,
      PRTTotQtyCalcFmlaIsReferenced,
      PRTUsgeQtyCalcFmlaIsReferenced,
      PRTControlProfileIsReferenced,
      PRTStdTextCodeIsReferenced,

      @Semantics.quantity.unitOfMeasure: 'StartDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      StartDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      StartDateOffsetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'EndDateOffsetDurationUnit'
      @DefaultAggregation: #SUM
      EndDateOffsetDuration,
      @Semantics.unitOfMeasure: true
      EndDateOffsetDurationUnit,

      // Admin

      @Semantics.systemDate.createdAt: true
      CreationDate,
      @Semantics.user.createdBy: true
      CreatedByUser,
      @Semantics.systemDate.lastChangedAt: true
      LastChangeDate,
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,

      _ProductionResourceType,
      _Equipment,
      _EquipmentProdnRsceTool,
      _ProdnRsceToolGroup1,
      _ProdnRsceToolGroup2,
      _ProductionResourceUsage,
      _ProdnRsceToolControlProfile,
      _ProdnRsceToolStandardText,
      _ProdnRsceToolTotQtyCalcFmla,
      _ProdnRsceToolUsageQtyCalcFmla,
      _StartDateOffsetReferenceCode,
      _EndDateOffsetReferenceCode,
      _StartDateOffsetDurationUnit,
      _EndDateOffsetDurationUnit,

      _CreatedByUser,
      _LastChangedByUser,
      _ChangeMaster
}
where
  PRT.ProdnRsceToolCategory = 'E' // Equipment

Learn More