I_ENGMNTPROJASSGMTTOSESSIONUSR

@AbapCatalog.sqlViewName: 'IEPASSGTOSESNUSR'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #COMPOSITE
@AbapCatalog:{ compiler.compareFilter: true,
               preserveKey: true }
@ObjectModel: {
    usageType: { serviceQuality: #C,
                 sizeCategory: #L,
                 dataClass: #TRANSACTIONAL },
    modelingPattern: #TRANSACTIONAL_ENTITY,
    supportedCapabilities: [#CDS_MODELING_DATA_SOURCE,
                            #SQL_DATA_SOURCE]
}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData: { blocking: #REQUIRED,
                    blockingIndicator: ['_Customer.IsBusinessPurposeCompleted',
                                        '_ProjectManager.IsBusinessPurposeCompleted',
                                        '_ProjectAccountant.IsBusinessPurposeCompleted',
                                        '_ProjectController.IsBusinessPurposeCompleted',
                                        '_ProjectPartner.IsBusinessPurposeCompleted' ] }
}
@EndUserText.label: 'Engagement Project Assignment To User'
define view I_EngmntProjAssgmtToSessionUsr
  as select from P_EngmntProjWthRolesAsAttrib  as Project
    inner join   I_EngagementProjFinancialPlan as FinancialPlan on Project.EngagementProjectUUID = FinancialPlan.EngagementProjectUUID

  association [1..1] to I_Customer          as _Customer          on $projection.Customer = _Customer.Customer
  association [1..1] to I_BusinessUserBasic as _ProjectManager    on $projection.ProjectManagerExternalID = _ProjectManager.UserID
  association [0..1] to I_BusinessUserBasic as _ProjectAccountant on $projection.ProjectAccountantExternalID = _ProjectAccountant.UserID
  association [0..1] to I_BusinessUserBasic as _ProjectController on $projection.ProjectControllerExternalID = _ProjectController.UserID
  association [0..1] to I_BusinessUserBasic as _ProjectPartner    on $projection.ProjectPartnerExternalID = _ProjectPartner.UserID
{

  key Project.EngagementProjectUUID,
      Project.EngagementProject,
      EngagementProjectName,
      ProjectStartDate,
      ProjectEndDate,
      Customer,
      EngagementProjectServiceOrg,
      EngagementProjectType,
      EngagementProjectCategory,
      EngagementProjectStage,
      ProjectVisibility,
      IsMyProject,
      Currency,
      EngagementProjFinPlanUUID,
      EngmntProjReviewYearPeriod,
      EngagementProjectReviewStatus,
      @Semantics.dateTime:true
      @Semantics.systemDate.lastChangedAt: true
      Project.LastChangeDateTime,

      // For all the records where External id is null or blank {Possible for Controller, Accountant and Partner} we are setting as 'A'.

      // This is required because External id is used on join condition of the Union view.

      // If these fields have null values join condition will fail.

      ProjectManager                                                                                                       as ProjManagerUserID,
      ProjectManagerName,
      ProjectManagerExternalID,

      ProjectAccountant                                                                                                    as ProjAccountantUserID,
      ProjectAccountantName,
      case
      when ProjectAccountantExternalID is null
      then 'A'
      else ProjectAccountantExternalID
      end                                                                                                                  as ProjectAccountantExternalID,

      ProjectController                                                                                                    as ProjControllerUserID,
      ProjectControllerName,
      case
      when ProjectControllerExternalID is null
      then 'A'
      else ProjectControllerExternalID
      end                                                                                                                  as ProjectControllerExternalID,

      Projectpartner                                                                                                       as ProjPartnerUserID,
      ProjectpartnerName                                                                                                   as ProjectPartnerName,
      case
      when ProjectpartnerExternalID is null
      then 'A'
      else ProjectpartnerExternalID
      end                                                                                                                  as ProjectPartnerExternalID,

      cast(concat(substring(CurrentDate, 1, 4), concat('0', substring(CurrentDate, 5, 2))) as /cpd/ss_current_year_period) as CurrentYearPeriod,

      ProjectProfileCode,
      ControllingArea,
      CompanyCode                                                                                                          as EngmntProjectHeaderCompanyCode,
      CostCenter                                                                                                           as EngagementProjectCostCenter,
      ProfitCenter,

      _Customer,
      _ProjectManager,
      _ProjectAccountant,
      _ProjectController,
      _ProjectPartner
}