I_EHSCONTROL

CDS View

EHS Control

I_EHSCONTROL is a CDS View in S/4HANA. EHS Control. It contains 2 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 2 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_EHSRskAssmt2ControlCatalog view_entity from CONSUMPTION Risk Assessment V2 Control Catalog
I_EHSControlStdVH view from COMPOSITE EHS Control
I_EHSControlValueHelp view from COMPOSITE Value Help for Controls
I_HazardControl view from COMPOSITE Hazard Control

Fields (2)

KeyField CDS FieldsUsed in Views
KEY EHSControlUUID EHSControlUUID 1
EHSControlImageURL EHSControlImageURL 1 
@EndUserText.label: 'EHS Control'
@VDM.viewType: #BASIC
@ObjectModel.representativeKey: 'EHSControlUUID'
@AccessControl.authorizationCheck: #CHECK

@AbapCatalog.sqlViewName: 'IEHSCTRL'
@AbapCatalog.compiler.compareFilter: true


// Client handling by session

@ClientHandling.algorithm: #SESSION_VARIABLE

// used for BOBF Master Data Object

@ObjectModel.usageType:{ serviceQuality: #C,        // < 15 msec

                         sizeCategory:  #L,         // < 10.000.000

                         dataClass: #MIXED }

define view I_EHSControl
  as select from ehfndd_ctrl_root as EHSControlRoot
  //join I_EHSControlImageURL as _EHSControlImageURL on EHSControlRoot.db_key = _EHSControlImageURL.EHSControlUUID  

 
    association [0..1] to I_User            as _CreatedByUser     on $projection.CreatedByUser = _CreatedByUser.UserID
    association [0..1] to I_User            as _LastChangedByUser on $projection.LastChangedByUser = _LastChangedByUser.UserID
   
    association [1..*] to I_EHSCtrlTitleText as _EHSCtrlTitleTxt on $projection.EHSControlUUID = _EHSCtrlTitleTxt.EHSControlUUID
    association [1..1] to I_EHSCtrlEffect as _EHSCtrlEffect on $projection.DesiredEHSControlEffect = _EHSCtrlEffect.DesiredEHSControlEffect
    association [1..1] to I_EHSCtrlCatalog as _EHSCatalog on $projection.EHSControlCatalog = _EHSCatalog.EHSControlCatalog
    association [1..1] to I_EHSCtrlGoalTar as _EHSGoalTarget on $projection.EHSControlTarget = _EHSGoalTarget.EHSControlTarget
    association [0..*] to I_EHSControlAttachment as _EHSControlAttachment on $projection.EHSControlUUID = _EHSControlAttachment.EHSControlUUID
    association [0..*] to I_EHSTextCollectionText as _EHSControlRemarkText        on $projection.EHSControlRemarkUUID = _EHSControlRemarkText.TextCollectionUUID //see I_EHSRiskControl

{
    @ObjectModel.text.association: '_EHSCtrlTitleTxt'
key cast( db_key as ehfnd_ctrl_uuid_ref preserving type ) as EHSControlUUID,
      id                                                        as EHSControlId,
      migration_src                                             as ControlMigrationSource,

      catalog_code                                              as EHSControlCatalog,
      goal_target_code                                          as EHSControlTarget,
      goal_object_code                                          as EHSControlObjective,
      goal_ctrl_effect                                          as DesiredEHSControlEffect,
      _EHSCtrlTitleTxt,
      _EHSCtrlEffect,
      _EHSCatalog,
      _EHSGoalTarget,
      
      image_key_ref                               as EHSControlImageUUID,
      _EHSCatalog.EHSControlSymbolFileName,
      @Semantics.imageUrl      
      //_EHSControlImageURL.EHSControlImageURL,

      @ObjectModel: {
        readOnly: true,
        virtualElement: true,
        virtualElementCalculatedBy: 'ABAP:CL_EHFND_CTRL_IMAGE_EXIT'
      }
      cast('' as text1024)                   as EHSControlImageURL,
  
      // Admin data

      datetime_cr                                    as CreationDateTime,
      user_id_cr                                     as CreatedByUser,
      _CreatedByUser,
      datetime_ch                                    as LastChangeDateTime,
      user_id_ch                                     as LastChangedByUser,
      _LastChangedByUser,
      rem_desc_key_ref                               as EHSControlRemarkUUID, //see I_EHSRiskControl

      _EHSControlAttachment,
      _EHSControlRemarkText //see I_EHSRiskControl

      
}

Learn More