I_DOCUMENTINFORECORDDESC

CDS View

Document Info Record Description

I_DOCUMENTINFORECORDDESC is a CDS View in S/4HANA. Document Info Record Description. It contains 7 fields. 4 CDS views read from this table.

Used by 4 CDS view(s) 7 fields

CDS Views using this table (4)

ViewTypeJoinVDMDescription
C_DocumentInfoRecordDescVH view from CONSUMPTION Document Info Record Description VH
I_DocInfoRecordDescriptionTP view from TRANSACTIONAL CDS TP View for Doc Info Record Desc
I_DocumentInfoRecordDescTP view from TRANSACTIONAL DocumentInfoRecdDescriptionTransactional
R_DocumentInfoRecordDescTP view_entity from TRANSACTIONAL Document Info Record Description - TP

Fields (7)

KeyField CDS FieldsUsed in Views
KEY DocumentInfoRecordDocNumber DocumentInfoRecordDocNumber 1
KEY DocumentInfoRecordDocPart DocumentInfoRecordDocPart 1
KEY DocumentInfoRecordDocType DocumentInfoRecordDocType 1
KEY DocumentInfoRecordDocVersion DocumentInfoRecordDocVersion 1
KEY Language Language 1
DocumentDescription DocumentDescription 1
LongTextExists LongTextExists 1 
@AbapCatalog.sqlViewName:'ICVDOCDESC'
@AbapCatalog.compiler.compareFilter: true
//@AbapCatalog.preserveKey: true

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.dataCategory: #TEXT
@VDM.viewType: #BASIC
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey:'DocumentInfoRecordDocType'
@ObjectModel.usageType: { serviceQuality: #A, sizeCategory: #L, dataClass: #TRANSACTIONAL }
@EndUserText.label: 'Document Info Record Description'
@Metadata.ignorePropagatedAnnotations: true
@VDM.lifecycle: {
  contract: {
    type:#PUBLIC_LOCAL_API
  }
}
@ObjectModel.supportedCapabilities: [ #LANGUAGE_DEPENDENT_TEXT , #SQL_DATA_SOURCE , #CDS_MODELING_DATA_SOURCE , #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #LANGUAGE_DEPENDENT_TEXT
define view I_DocumentInfoRecordDesc
  as select from drat as documentdesc

  --Get Document Type Association
  association [1..1] to I_DocumentInfoRecordDocType    as _DocType    on  $projection.DocumentInfoRecordDocType = _DocType.DocumentInfoRecordDocType

  --Get Document Number Association
  association [0..1] to I_DocumentInfoRecordDocNumber  as _DocNumber  on  $projection.DocumentInfoRecordDocType   = _DocNumber.DocumentInfoRecordDocType
                                                                      and $projection.DocumentInfoRecordDocNumber = _DocNumber.DocumentInfoRecordDocNumber
  --Get Document Part Association
  association [0..1] to I_DocumentInfoRecordDocPrt     as _DocPart    on  $projection.DocumentInfoRecordDocType    = _DocPart.DocumentInfoRecordDocType
                                                                      and $projection.DocumentInfoRecordDocPart    = _DocPart.DocumentInfoRecordDocPart
                                                                      and $projection.DocumentInfoRecordDocNumber  = _DocPart.DocumentInfoRecordDocNumber
                                                                      and $projection.DocumentInfoRecordDocVersion = _DocPart.DocumentInfoRecordDocVersion

  --Get Document Version Association
  association [0..1] to I_DocumentInfoRecordDocVersion as _DocVersion on  $projection.DocumentInfoRecordDocType    = _DocVersion.DocumentInfoRecordDocType
                                                                      and $projection.DocumentInfoRecordDocNumber  = _DocVersion.DocumentInfoRecordDocNumber
                                                                      and $projection.DocumentInfoRecordDocVersion = _DocVersion.DocumentInfoRecordDocVersion

  association [0..1] to I_Language                     as _Language   on  $projection.Language = _Language.Language

{
            @Consumption.valueHelpDefinition: [ 
              { entity:  { name:    'I_DocInfoRecdDocTypeStdVH',
                           element: 'DocumentInfoRecordDocType' }
              }]
            @ObjectModel.foreignKey.association: '_DocType'
  key       documentdesc.dokar    as DocumentInfoRecordDocType,
            
            @Consumption.valueHelpDefinition: [ 
              { entity:  { name:    'I_DocInfoRecdDocNmbrStdVH',
                           element: 'DocumentInfoRecordDocNumber' },
                additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
                                      element: 'DocumentInfoRecordDocType' }]
              }]
            @ObjectModel.foreignKey.association: '_DocNumber'
  key       documentdesc.doknr    as DocumentInfoRecordDocNumber,
  
            @Consumption.valueHelpDefinition: [ 
              { entity:  { name:    'I_DocInfoRecdDocVersStdVH',
                           element: 'DocumentInfoRecordDocVersion' },
                additionalBinding: [{ localElement: 'DocumentInfoRecordDocType',
                                      element: 'DocumentInfoRecordDocType' },
                                    { localElement: 'DocumentInfoRecordDocNumber',
                                      element: 'DocumentInfoRecordDocNumber' }]
              }]
            @ObjectModel.foreignKey.association: '_DocVersion'
  key       documentdesc.dokvr    as DocumentInfoRecordDocVersion,

            @ObjectModel.foreignKey.association: '_DocPart'
  key       documentdesc.doktl    as DocumentInfoRecordDocPart,

            @Semantics.language: true
            @ObjectModel.foreignKey.association: '_Language'
  key       documentdesc.langu    as Language,

            @Semantics.text: true
            @EndUserText.label:'Document Description'
            documentdesc.dktxt    as DocumentDescription,

            documentdesc.ltxin    as LongTextExists,

            // DMS: short texts in capital letters

            @EndUserText.label:'Document Short Description'
            documentdesc.dktxt_uc as DocInfoRecdShortText,

            // Associations

            @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
            _Language,
            @ObjectModel.association.type: [#TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT]
            _DocType,
            _DocVersion,
            _DocPart,
            _DocNumber

}

Learn More