I_DOCUMENTINFORECORDRELATION

CDS View

Document Info Record Relation

I_DOCUMENTINFORECORDRELATION is a CDS View in S/4HANA. Document Info Record Relation. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
R_DocumentInfoRecordRelationTP view_entity from TRANSACTIONAL Document Info Record Relation - TP 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Document Info Record Relation'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{serviceQuality: #C, sizeCategory: #L, dataClass: #TRANSACTIONAL}
@ObjectModel.supportedCapabilities: [ #SQL_DATA_SOURCE, #CDS_MODELING_DATA_SOURCE, #CDS_MODELING_ASSOCIATION_TARGET ]
@ObjectModel.modelingPattern: #NONE  
@VDM.viewType: #BASIC
define view entity I_DocumentInfoRecordRelation as select from P_DocumentInfoRecordObjectLink as ObjLink 

  --Get Linked object description
  association [0..*] to I_DocumentInfoRecordObjLinkT as _Text                   on  $projection.LinkedSAPObject = _Text.LinkedSAPObject
  
  --Get DocumentInfoRecord created user full name
  association [1..1] to I_DocumentInfoRecordUserVH   as _CreatedUser            on  $projection.DocumentInfoRecordDocType    = _CreatedUser.DocumentInfoRecordDocType
                                                                                and $projection.DocumentInfoRecordDocPart    = _CreatedUser.DocumentInfoRecordDocPart
                                                                                and $projection.DocumentInfoRecordDocNumber  = _CreatedUser.DocumentInfoRecordDocNumber
                                                                                and $projection.DocumentInfoRecordDocVersion = _CreatedUser.DocumentInfoRecordDocVersion
                                                                                and $projection.CreatedByUser                = _CreatedUser.ResponsiblePersonName

  --Get DocumentInfoRecord changed user full name
  association [1..1] to I_DocumentInfoRecordUserVH   as _ChangedUser            on  $projection.DocumentInfoRecordDocType    = _ChangedUser.DocumentInfoRecordDocType
                                                                                and $projection.DocumentInfoRecordDocPart    = _ChangedUser.DocumentInfoRecordDocPart
                                                                                and $projection.DocumentInfoRecordDocNumber  = _ChangedUser.DocumentInfoRecordDocNumber
                                                                                and $projection.DocumentInfoRecordDocVersion = _ChangedUser.DocumentInfoRecordDocVersion
                                                                                and $projection.LastChangedByUser            = _ChangedUser.LastChangedByUser
  association [0..*] to I_DocumentInfoRecordDesc     as _DocumentInfoRecordDesc on  $projection.DocumentInfoRecordDocNumber = _DocumentInfoRecordDesc.DocumentInfoRecordDocNumber
{
      /*  Document Info Record key Details */
  key ObjLink.DocumentInfoRecordDocType      as DocumentInfoRecordDocType,
  key ObjLink.DocumentInfoRecordDocNumber    as DocumentInfoRecordDocNumber,
  key ObjLink.DocumentInfoRecordDocVersion   as DocumentInfoRecordDocVersion,
  key ObjLink.DocumentInfoRecordDocPart      as DocumentInfoRecordDocPart,

      /*  Object Type and Object Key Details */
  key ObjLink.LinkedSAPObject                as LinkedSAPObject,
  key ObjLink.LinkedSAPObjectKey             as LinkedSAPObjectKey,
  key ObjLink.DocObjectLinkCounter           as DocObjectLinkCounter,

      /* DIR Administrative Data */
      //@Semantics.businessDate.at: true

      //@Semantics.businessDate.createdAt: true

      ObjLink.CreationDateTime               as CreationDateTime,

      @Consumption.valueHelp: '_CreatedUser'
      @Semantics.user.createdBy: true
      ObjLink.CreatedByUser                  as CreatedByUser,

      //@Semantics.businessDate.at: true

      //@Semantics.businessDate.lastChangedAt: true

      ObjLink.ChangedDateTime                as ChangedDateTime,

      @Consumption.valueHelp: '_ChangedUser'
      @Semantics.user.lastChangedBy: true
      ObjLink.LastChangedByUser              as LastChangedByUser,

      ObjLink.DocInfoRecdLinkStatus          as DocInfoRecdLinkStatus,
      ObjLink.DocInfoRecdObjectLinkStatus    as DocInfoRecdObjectLinkStatus,
      ObjLink.ObjectTypeDatabaseTable        as ObjectTypeDatabaseTable,
      ObjLink.DocInfoRecdAdditionalObjectKey as DocInfoRecdAdditionalObjectKey,
      @Semantics.booleanIndicator: true
      ObjLink.DocLinkDirectionIsActive       as DocLinkDirectionIsActive,
      ObjLink.IsDefaultDocument              as IsDefaultDocument,
      @Semantics.booleanIndicator: true
      ObjLink.DocInfoRecdIsMarkedForDeletion as DocInfoRecdIsMarkedForDeletion,
      @Semantics.uuid: true
      ObjLink.DocInfoRecdLongTextUUID        as DocInfoRecdLongTextUUID,
      @Semantics.booleanIndicator: true
      ObjLink.IsDocInfoRecdCreatedFromCAD    as IsDocInfoRecdCreatedFromCAD,
      ObjLink.DocInfoRecdConfignMgmtFixed    as DocInfoRecdConfignMgmtFixed,
      //ObjLink.DocInfoRecdConfignMgmtIsFixed  as DocInfoRecdConfignMgmtIsFixed,

      ObjLink.IsArchived                     as IsArchived,
      
      //Associations

      _CreatedUser,
      _ChangedUser,
      _Text,
      _DocumentInfoRecordDesc
}

Learn More