I_CREDITLIMITREQUESTATTRIBUTE

CDS View

Credit Limit Request Attribute

I_CREDITLIMITREQUESTATTRIBUTE is a CDS View in S/4HANA. Credit Limit Request Attribute. It contains 7 fields. 1 CDS views read from this table.

Used by 1 CDS view(s) 7 fields

CDS Views using this table (1)

ViewTypeJoinVDMDescription
I_CreditLimitRequest view from COMPOSITE Credit Limit Request

Fields (7)

KeyField CDS FieldsUsed in Views
BusinessPartner BusinessPartner 1
BusinessPartnerRating BusinessPartnerRating 1
CrdtMgmtBusinessPartnerGroup CrdtMgmtBusinessPartnerGroup 1
CreditLimitUtilizationPct CreditLimitUtilizationPct 1
CreditLimitValidityEndDate CreditLimitValidityEndDate 1
CreditRiskClass CreditRiskClass 1
CreditSegment CreditSegment 1 
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.representativeKey: 'CaseUUID'
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@AbapCatalog.sqlViewName: 'ICRDTLMTREQATTR'
@EndUserText.label: 'Credit Limit Request Attribute'
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
//@Analytics: { dataExtraction.enabled: true }

@VDM.viewType: #BASIC
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED
define view I_CreditLimitRequestAttribute
  as select from ukmcaseattr00
  association [0..1] to I_BusinessPartner         as _BusinessPartner      on $projection.BusinessPartner = _BusinessPartner.BusinessPartner
  association [0..1] to I_CreditManagementBP      as _CreditManagementBP   on $projection.BusinessPartner = _CreditManagementBP.BusinessPartner
  association [1..1] to I_CreditManagementSegment as _CreditSegment        on $projection.CreditSegment = _CreditSegment.CreditSegment
  association [1..1] to I_Currency                as _Currency             on $projection.CreditSegmentCurrency = _Currency.Currency
  association [1..1] to I_CreditRiskClass         as _CreditRiskClass      on $projection.CreditRiskClass = _CreditRiskClass.CreditRiskClass
  association [0..1] to I_CrdtMBusPartnerGroup    as _CrdtMBusPartnerGroup on $projection.CrdtMgmtBusinessPartnerGroup = _CrdtMBusPartnerGroup.CrdtMgmtBusinessPartnerGroup
{
  key case_guid                                        as CaseUUID,
      @ObjectModel.foreignKey.association: '_BusinessPartner'
      fcr_partner                                      as BusinessPartner,
      @ObjectModel.foreignKey.association: '_CreditSegment'
      fcr_segment                                      as CreditSegment,
      @Semantics.amount.currencyCode: 'CreditSegmentCurrency'
      fcr_curr_limit                                   as CreditLimitAmount,
      @Semantics.amount.currencyCode: 'CreditSegmentCurrency'
      fcr_req_limit                                    as CreditLimitRequestedAmount,
      @Semantics.amount.currencyCode: 'CreditSegmentCurrency'
      fcr_app_limit                                    as CreditLimitApprovedAmount,
      @Semantics.amount.currencyCode: 'CreditSegmentCurrency'
      fcr_exp_volume                                   as ExpectedSalesAmount,
      @Semantics.amount.currencyCode: 'CreditSegmentCurrency'
      fcr_exposure                                     as CustomerCreditExposureAmount,
      @ObjectModel.foreignKey.association: '_Currency'
      fcr_currency                                     as CreditSegmentCurrency,
      fcr_perc_usage                                   as CreditLimitUtilizationPct,
      fcr_scoring                                      as BusinessPartnerRating,
      @ObjectModel.foreignKey.association: '_CreditRiskClass'
      fcr_risk_class                                   as CreditRiskClass,
      @ObjectModel.foreignKey.association: '_CrdtMBusPartnerGroup'
      _CreditManagementBP.CrdtMgmtBusinessPartnerGroup as CrdtMgmtBusinessPartnerGroup,

      fcr_limit_valid_date                             as CreditLimitValidityEndDate,

      _BusinessPartner,
      _CreditManagementBP,
      _CreditSegment,
      _Currency,
      _CreditRiskClass,
      _CrdtMBusPartnerGroup
}

Learn More