I_COMPLAINTINSPECTION

CDS View

Inspection Detail

I_COMPLAINTINSPECTION is a CDS View in S/4HANA. Inspection Detail. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_ComplaintInspection view_entity from CONSUMPTION Inspection Detail 
@VDM.viewType: #BASIC
@VDM.lifecycle.contract.type: #PUBLIC_LOCAL_API
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Inspection Detail'
@ObjectModel: {
   compositionRoot: true,
   usageType: {
     dataClass:      #TRANSACTIONAL,
     serviceQuality: #A,
     sizeCategory:   #L
   }
}
define view entity I_ComplaintInspection
  as select from /spe/inspecresh

    inner join   /spe/inspecresp as _Item on /spe/inspecresh.inspec_no = _Item.inspec_no
  association [0..1] to I_ReturnsInspectionStatusText as _InspectionStatusText on  $projection.ReturnsInspectionStatus = _InspectionStatusText.ReturnsInspectionStatus
                                                                               and _InspectionStatusText.Language      = $session.system_language
  association [0..1] to I_CustomerReturn              as _CustomerReturn       on  $projection.ReferenceDocument = _CustomerReturn.CustomerReturn
{
  key    /spe/inspecresh.deliv_numb                                       as PrecedingDocument,
  key    /spe/inspecresh.deliv_item                                       as PrecedingDocumentItem,
  key    cast(/spe/inspecresh.inspec_no as /spe/inspec_no_routine)        as InspectionDocument,
  key    _Item.item_no                                                    as ReturnsInspectionItem,

         @ObjectModel.text.association: '_InspectionStatusText'
         cast(
            case
               when _Item.dec_code <> ''
                and _Item.quan <> 0
                 then '2'
                 else '1'
             end as msr_insp_insp_status)                                 as ReturnsInspectionStatus,
         'INSP'                                                           as SubsequentDocumentCategory,
         ''                                                               as DocumentTypeDescription,
         _InspectionStatusText,
         cast( ( /spe/inspecresh.ref_doc )  as awref     )               as ReferenceDocument,
         cast (right(/spe/inspecresh.ref_doc_item, 6)    as  fins_awitem) as ReferenceDocumentItem,
         _CustomerReturn
}
where
      /spe/inspecresh.delflag    = ''
  and /spe/inspecresh.publstatus = 'P'

Learn More