I_COLLSINVOICERELATEDPRMS2P

CDS View

Promise To Pay Related to Invoice

I_COLLSINVOICERELATEDPRMS2P is a CDS View in S/4HANA. Promise To Pay Related to Invoice. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
C_CollsInvoiceRelatedPrms2P view_entity projection CONSUMPTION Promise To Pay Related to Invoice 
@AbapCatalog: { sqlViewName: 'ICOLLSINVRELP2P',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@EndUserText.label: 'Promise To Pay Related to Invoice'
@VDM: { viewType: #COMPOSITE,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #X,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                semanticKey: [ 'CaseUniqueID', 'CaseID' ],
                representativeKey: 'CaseUniqueID' }

define root view I_CollsInvoiceRelatedPrms2P
  as select from I_CollsInvoiceRelatedObject

  // VDM Associations

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _CreatedByContactCard on $projection.CaseCreatedBy = _CreatedByContactCard.ContactCardID

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ChangedByContactCard on $projection.CaseLastChangedBy = _ChangedByContactCard.ContactCardID

  // Closed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ClosedByContactCard  on $projection.CaseClosedBy = _ClosedByContactCard.ContactCardID

{

      // VDM Fields

  key LogicalSystem,
  key ObjectType,
  key ObjectKey,
  key RelationToLinkedObject,
  key CaseUniqueID,
      ObjectClassification,
      ObjectIsConfirmed,
      ObjectIsVoided,
      CompanyCode,
      AccountingDocument,
      FiscalYear,
      AccountingDocumentItem,
      CaseID,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      _CollsPromiseToPay.CaseCreatedBy     as CaseCreatedBy,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      _CollsPromiseToPay.CaseLastChangedBy as CaseLastChangedBy,

      @ObjectModel: { foreignKey: { association: '_ClosedByContactCard' } }
      _CollsPromiseToPay.CaseClosedBy      as CaseClosedBy,

      // Exposed Associations

      _CaseAttribute,
      _CollsPromiseToPay,
      _CreatedByContactCard,
      _ChangedByContactCard,
      _ClosedByContactCard

}

where
      RelationToLinkedObject =  'P1'
  and ObjectType             =  'BSEG'
  and ObjectIsVoided         <> 'X'

Learn More