I_COLLSINVOICERELATEDDSPUTCASE

CDS View

Dispute Case Related to Invoice

I_COLLSINVOICERELATEDDSPUTCASE is a CDS View in S/4HANA. Dispute Case Related to Invoice. It contains 4 fields. 2 CDS views read from this table.

Used by 2 CDS view(s) 4 fields

CDS Views using this table (2)

ViewTypeJoinVDMDescription
C_CollsInvoiceRelatedDsputCase view_entity projection CONSUMPTION Dispute Case Related to Invoice
P_CollsInvoiceRelDCCounter view from COMPOSITE Related Dispute Case Counter

Fields (4)

KeyField CDS FieldsUsed in Views
KEY AccountingDocument AccountingDocument 1
KEY AccountingDocumentItem AccountingDocumentItem 1
KEY CompanyCode CompanyCode 1
KEY FiscalYear FiscalYear 1 
@AbapCatalog: { sqlViewName: 'ICOLLSINVRELDC',
                compiler: { compareFilter: true },
                preserveKey: true }
@AccessControl: { authorizationCheck: #CHECK }
@EndUserText.label: 'Dispute Case Related to Invoice'
@VDM: { viewType: #BASIC,
        lifecycle: { contract: { type: #SAP_INTERNAL_API } } }
@ClientHandling: { algorithm: #SESSION_VARIABLE }
@ObjectModel: { usageType: { serviceQuality: #C,
                             sizeCategory: #L,
                             dataClass: #TRANSACTIONAL },
                semanticKey: [ 'CaseUniqueID', 'CaseID' ],
                representativeKey: 'CaseUniqueID' }

define root view I_CollsInvoiceRelatedDsputCase
  as select distinct from I_CollsInvoiceRelatedObject

  // BO Associations

  // Created By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _CreatedByContactCard       on $projection.casecreatedby = _CreatedByContactCard.ContactCardID

  // Changed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ChangedByContactCard       on $projection.caselastchangedby = _ChangedByContactCard.ContactCardID

  // Closed By Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ClosedByContactCard        on $projection.caseclosedby = _ClosedByContactCard.ContactCardID

  // Coordinator Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _DisputeCaseCoordinatorCard on $projection.disputecasecoordinator = _DisputeCaseCoordinatorCard.ContactCardID

  // Processor Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ProcessorContactCard       on $projection.caseprocessor = _ProcessorContactCard.ContactCardID

  // Person Responsible Contact Card

  association [0..1] to R_RblsMgmtUserContactCard as _ResponsibleContactCard     on $projection.caseresponsible = _ResponsibleContactCard.ContactCardID

{

      // VDM Fields

  key LogicalSystem,
  key ObjectType,
  key ObjectKey,
  key CaseUniqueID,
      CompanyCode,
      AccountingDocument,
      FiscalYear,
      AccountingDocumentItem,
      CaseID,

      @ObjectModel: { foreignKey: { association: '_DisputeCaseCoordinatorCard' } }
      _DisputeCase.DisputeCaseCoordinator,

      @ObjectModel: { foreignKey: { association: '_CreatedByContactCard' } }
      _DisputeCase.CaseCreatedBy,

      @ObjectModel: { foreignKey: { association: '_ChangedByContactCard' } }
      _DisputeCase.CaseLastChangedBy,

      @ObjectModel: { foreignKey: { association: '_ClosedByContactCard' } }
      _DisputeCase.CaseClosedBy,

      @ObjectModel: { foreignKey: { association: '_ProcessorContactCard' } }
      _DisputeCase.CaseProcessor,

      @ObjectModel: { foreignKey: { association: '_ResponsibleContactCard' } }
      _DisputeCase.CaseResponsible,

      cast ( 1 as int4 ) as NumberOfDisputeCases,

      // Exposed Associations

      _CaseAttribute,
      _DisputeCase,
      _ChangedByContactCard,
      _ClosedByContactCard,
      _CreatedByContactCard,
      _DisputeCaseCoordinatorCard,
      _ProcessorContactCard,
      _ResponsibleContactCard

}

where
  (
       RelationToLinkedObject    =  'F1'
    or RelationToLinkedObject    =  'F2'
    or RelationToLinkedObject    =  'F3'
    or RelationToLinkedObject    =  'F4'
    or RelationToLinkedObject    =  'F5'
    or RelationToLinkedObject    =  'F6'
  )
  and  ObjectIsVoided            <> 'X'
  and  ObjectType                =  'BSEG'
  and  _DisputeCase.CaseClosedBy =  ''

Learn More