I_CNSLDTNDOCUMENTTYPEENHCD10

CDS View

Consolidation Document Type

I_CNSLDTNDOCUMENTTYPEENHCD10 is a CDS View in S/4HANA. Consolidation Document Type. 1 CDS views read from this table.

Used by 1 CDS view(s)

CDS Views using this table (1)

ViewTypeJoinVDMDescription
A_CnsldtnDocumentType view from BASIC Consolidation Document Type 
@EndUserText.label: 'Consolidation Document Type'
@VDM.viewType: #BASIC
@AbapCatalog.sqlViewName: 'ICCDOCTYPEENH'
@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'ConsolidationDocumentType'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType: {
  dataClass: #CUSTOMIZING,
  serviceQuality: #C,
  sizeCategory: #S
}
@OData.entitySet.name: 'ConsolidationDocumentTypeSet'
@Search.searchable: true
define view I_CnsldtnDocumentTypeEnhcd10
  as select from tf500

  association [0..1] to I_CnsldtnDimension            as _Dimension               on  $projection.ConsolidationDimension = _Dimension.ConsolidationDimension

  association [0..1] to I_CnsldtnPostingLevel         as _PostingLevel            on  $projection.PostingLevel = _PostingLevel.PostingLevel

  association [0..*] to I_CnsldtnDocumentTypeT        as _Text                    on  $projection.ConsolidationDimension    = _Text.ConsolidationDimension
                                                                                  and $projection.ConsolidationDocumentType = _Text.ConsolidationDocumentType
  association [0..*] to I_CnsldtnBusinessApplicationT as _BusinessApplicationText on  $projection.DocumentTypeBusinessAppl = _BusinessApplicationText.DocumentTypeBusinessAppl
  association [0..*] to I_CnsldtnBalanceCheckT        as _BALANCECHECKT           on  $projection.ConsolidationBalanceCheck = _BALANCECHECKT.ConsolidationBalanceCheck

{
      @ObjectModel.foreignKey.association: '_Dimension'
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH}
  key dimen as ConsolidationDimension,

      @ObjectModel.text.association: '_Text'
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH}
  key docty as ConsolidationDocumentType,

      @ObjectModel.foreignKey.association: '_PostingLevel'
      @Search: {defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #HIGH}
      rlevl as PostingLevel,

      @ObjectModel.text.association: '_BALANCECHECKT'
      blchk as ConsolidationBalanceCheck,
      mnpos as ConsolidationPostgItemAutoFlag,

      tcind as IsDocumentPostInTransCurrency,
      lcind as IsDocumentPostInLocalCurrency,
      gcind as IsDocumentPostInGroupCurrency,
      dtaxd as DocHasCreditDeferredTax,
      dtaxc as DocHasDebitDeferredTax,
      @ObjectModel.text.association: '_BusinessApplicationText'
      cacta as DocumentTypeBusinessAppl,
      //_Text.ConsolidationDocumentTypeText as ConsolidationDocumentTypeText,

      _Dimension,
      _PostingLevel,
      _BusinessApplicationText,
      _BALANCECHECKT,
      _Text
}

Learn More